asunit4 4.2.2.pre → 4.2.3.pre

data/vendor/as3injection/org/swiftsuspenders/InjectorError.as

@@ -0,0 +1,17 @@
+/*
+* Copyright (c) 2009 the original author or authors
+* 
+* Permission is hereby granted to use, modify, and distribute this file 
+* in accordance with the terms of the license agreement accompanying it.
+*/
+
+package org.swiftsuspenders
+{
+	public class InjectorError extends Error
+	{
+		public function InjectorError(message:*="", id:*=0)
+		{
+			super(message, id);
+		}
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/Reflector.as

@@ -0,0 +1,95 @@
+/*
+ * Copyright (c) 2009 the original author or authors
+ *
+ * Permission is hereby granted to use, modify, and distribute this file
+ * in accordance with the terms of the license agreement accompanying it.
+ */
+
+package org.swiftsuspenders
+{
+	import flash.system.ApplicationDomain;
+	import flash.utils.describeType;
+	import flash.utils.getDefinitionByName;
+	import flash.utils.getQualifiedClassName;
+
+	/**
+	 * @author tschneidereit
+	 */
+	public class Reflector
+	{
+		/*******************************************************************************************
+		*								public methods											   *
+		*******************************************************************************************/
+		public function Reflector()
+		{
+		}
+
+		public function classExtendsOrImplements(classOrClassName : Object,
+			superclass : Class, application : ApplicationDomain = null) : Boolean
+		{
+            var actualClass : Class;
+			
+            if (classOrClassName is Class)
+            {
+                actualClass = Class(classOrClassName);
+            }
+            else if (classOrClassName is String)
+            {
+                try
+                {
+                    actualClass = Class(getDefinitionByName(classOrClassName as String));
+                }
+                catch (e : Error)
+                {
+                    throw new Error("The class name " + classOrClassName +
+                    	" is not valid because of " + e + "\n" + e.getStackTrace());
+                }
+            }
+
+            if (!actualClass)
+            {
+                throw new Error("The parameter classOrClassName must be a valid Class " +
+                	"instance or fully qualified class name.");
+            }
+
+            if (actualClass == superclass)
+                return true;
+
+            var factoryDescription : XML = describeType(actualClass).factory[0];
+
+			return (factoryDescription.children().(
+            	name() == "implementsInterface" || name() == "extendsClass").(
+            	attribute("type") == getQualifiedClassName(superclass)).length() > 0);
+		}
+
+		public function getClass(value : *, applicationDomain : ApplicationDomain = null) : Class
+		{
+			if (value is Class)
+			{
+				return value;
+			}
+			return getConstructor(value);
+		}
+
+		public function getFQCN(value : *, replaceColons : Boolean = false) : String
+		{
+			var fqcn:String;
+			if (value is String)
+			{
+				fqcn = value;
+				// Add colons if missing and desired.
+				if (!replaceColons && fqcn.indexOf('::') == -1)
+				{
+					var lastDotIndex:int = fqcn.lastIndexOf('.');
+					if (lastDotIndex == -1) return fqcn;
+					return fqcn.substring(0, lastDotIndex) + '::' + fqcn.substring(lastDotIndex + 1);
+				}
+			}
+			else
+			{
+				fqcn = getQualifiedClassName(value);
+			}
+			return replaceColons ? fqcn.replace('::', '.') : fqcn;
+		}
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/getConstructor.as

@@ -0,0 +1,33 @@
+/*
+ * Copyright (c) 2010 the original author or authors
+ *
+ * Permission is hereby granted to use, modify, and distribute this file
+ * in accordance with the terms of the license agreement accompanying it.
+ */
+
+package org.swiftsuspenders
+{
+	import flash.utils.Proxy;
+	import flash.utils.getDefinitionByName;
+	import flash.utils.getQualifiedClassName;
+	
+	internal function getConstructor(value : Object) : Class
+	{
+		/*
+		   There are several types for which the 'constructor' property doesn't work:
+		    - instances of Proxy, XML and XMLList throw exceptions when trying to access 'constructor'
+		    - int and uint return Number as their constructor
+		   For these, we have to fall back to more verbose ways of getting the constructor.
+
+		   Additionally, Vector instances always return Vector.<*> when queried for their constructor.
+		   Ideally, that would also be resolved, but the SwiftSuspenders wouldn't be compatible with
+		   Flash Player < 10, anymore.
+		 */
+		if (value is Proxy || value is Number || value is XML || value is XMLList)
+		{
+			var fqcn : String = getQualifiedClassName(value);
+			return Class(getDefinitionByName(fqcn));
+		}
+		return value.constructor;
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/injectionpoints/ConstructorInjectionPoint.as

@@ -0,0 +1,94 @@
+/*
+ * Copyright (c) 2009 the original author or authors
+ * 
+ * Permission is hereby granted to use, modify, and distribute this file 
+ * in accordance with the terms of the license agreement accompanying it.
+ */
+
+package org.swiftsuspenders.injectionpoints
+{
+	import flash.utils.describeType;
+	
+	import org.swiftsuspenders.Injector;
+	
+	public class ConstructorInjectionPoint extends MethodInjectionPoint
+	{
+		/*******************************************************************************************
+		*								public methods											   *
+		*******************************************************************************************/
+		public function ConstructorInjectionPoint(node : XML, clazz : Class, injector : Injector)
+		{
+			/*
+			  In many cases, the flash player doesn't give us type information for constructors until 
+			  the class has been instantiated at least once. Therefore, we do just that if we don't get 
+			  type information for at least one parameter.
+			 */ 
+			if (node.parameter.(@type == '*').length() == node.parameter.@type.length())
+			{
+				createDummyInstance(node, clazz);
+			}
+			super(node, injector);
+		}
+		
+		override public function applyInjection(target : Object, injector : Injector) : Object
+		{
+			var p : Array = gatherParameterValues(target, injector);
+			//the only way to implement ctor injections, really!
+			switch (p.length)
+			{
+				case 0 : return (new target());
+				case 1 : return (new target(p[0]));
+				case 2 : return (new target(p[0], p[1]));
+				case 3 : return (new target(p[0], p[1], p[2]));
+				case 4 : return (new target(p[0], p[1], p[2], p[3]));
+				case 5 : return (new target(p[0], p[1], p[2], p[3], p[4]));
+				case 6 : return (new target(p[0], p[1], p[2], p[3], p[4], p[5]));
+				case 7 : return (new target(p[0], p[1], p[2], p[3], p[4], p[5], p[6]));
+				case 8 : return (new target(p[0], p[1], p[2], p[3], p[4], p[5], p[6], p[7]));
+				case 9 : return (new target(p[0], p[1], p[2], p[3], p[4], p[5], p[6], p[7], p[8]));
+				case 10 : return (new target(p[0], p[1], p[2], p[3], p[4], p[5], p[6], p[7], p[8], p[9]));
+			}
+			return null;
+		}
+
+		/*******************************************************************************************
+		*								protected methods										   *
+		*******************************************************************************************/
+		override protected function initializeInjection(node : XML, injector : Injector) : void
+		{
+			var nameArgs : XMLList = node.parent().metadata.(@name == 'Inject').arg.(@key == 'name');
+			methodName = 'constructor';
+			
+			gatherParameters(node, nameArgs, injector);
+		}
+		
+		/*******************************************************************************************
+		*								private methods											   *
+		*******************************************************************************************/
+		private function createDummyInstance(constructorNode : XML, clazz : Class) : void
+		{
+			try
+			{
+				switch (constructorNode.children().length())
+				{
+					case 0 : (new clazz()); break;
+					case 1 : (new clazz(null)); break;
+					case 2 : (new clazz(null, null)); break;
+					case 3 : (new clazz(null, null, null)); break;
+					case 4 : (new clazz(null, null, null, null)); break;
+					case 5 : (new clazz(null, null, null, null, null)); break;
+					case 6 : (new clazz(null, null, null, null, null, null)); break;
+					case 7 : (new clazz(null, null, null, null, null, null, null)); break;
+					case 8 : (new clazz(null, null, null, null, null, null, null, null)); break;
+					case 9 : (new clazz(null, null, null, null, null, null, null, null, null)); break;
+					case 10 : (new clazz(null, null, null, null, null, null, null, null, null, null)); break;
+				}
+			}
+			catch (error : Error)
+			{
+				trace(error);
+			}
+			constructorNode.setChildren(describeType(clazz).factory.constructor[0].children());
+		}
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/injectionpoints/InjectionPoint.as

@@ -0,0 +1,35 @@
+/*
+ * Copyright (c) 2009 the original author or authors
+ * 
+ * Permission is hereby granted to use, modify, and distribute this file 
+ * in accordance with the terms of the license agreement accompanying it.
+ */
+
+package org.swiftsuspenders.injectionpoints
+{
+	import org.swiftsuspenders.Injector;
+
+	public class InjectionPoint
+	{
+		/*******************************************************************************************
+		*								public methods											   *
+		*******************************************************************************************/
+		public function InjectionPoint(node : XML, injector : Injector)
+		{
+			initializeInjection(node, injector);
+		}
+		
+		public function applyInjection(target : Object, injector : Injector) : Object
+		{
+			return target;
+		}
+
+
+		/*******************************************************************************************
+		*								protected methods										   *
+		*******************************************************************************************/
+		protected function initializeInjection(node : XML, injector : Injector) : void
+		{
+		}
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/injectionpoints/MethodInjectionPoint.as

@@ -0,0 +1,122 @@
+/*
+ * Copyright (c) 2009 the original author or authors
+ * 
+ * Permission is hereby granted to use, modify, and distribute this file 
+ * in accordance with the terms of the license agreement accompanying it.
+ */
+
+package org.swiftsuspenders.injectionpoints
+{
+	import flash.utils.getDefinitionByName;
+	import flash.utils.getQualifiedClassName;
+	
+	import org.swiftsuspenders.InjectionConfig;
+	import org.swiftsuspenders.Injector;
+	import org.swiftsuspenders.InjectorError;
+
+	public class MethodInjectionPoint extends InjectionPoint
+	{
+		/*******************************************************************************************
+		*								private properties										   *
+		*******************************************************************************************/
+		protected var methodName : String;
+		protected var m_injectionConfigs : Array;
+		protected var requiredParameters : int = 0;
+		
+		
+		/*******************************************************************************************
+		*								public methods											   *
+		*******************************************************************************************/
+		public function MethodInjectionPoint(node : XML, injector : Injector)
+		{
+			super(node, injector);
+		}
+		
+		override public function applyInjection(target : Object, injector : Injector) : Object
+		{
+			var parameters : Array = gatherParameterValues(target, injector);
+			var method : Function = target[methodName];
+			method.apply(target, parameters);
+			return target;
+		}
+
+
+		/*******************************************************************************************
+		*								protected methods										   *
+		*******************************************************************************************/
+		override protected function initializeInjection(node : XML, injector : Injector) : void
+		{
+			var nameArgs : XMLList = node.arg.(@key == 'name');
+			var methodNode : XML = node.parent();
+			methodName = methodNode.@name.toString();
+			
+			gatherParameters(methodNode, nameArgs, injector);
+		}
+		
+		protected function gatherParameters(
+			methodNode : XML, nameArgs : XMLList, injector : Injector) : void
+		{
+			m_injectionConfigs = [];
+			var i : int = 0;
+			for each (var parameter : XML in methodNode.parameter)
+			{
+				var injectionName : String = '';
+				if (nameArgs[i])
+				{
+					injectionName = nameArgs[i].@value.toString();
+				}
+				var parameterTypeName : String = parameter.@type.toString();
+				var parameterType : Class;
+				if (parameterTypeName == '*')
+				{
+					if (parameter.@optional.toString() == 'false')
+					{
+						//TODO: Find a way to trace name of affected class here
+						throw new Error('Error in method definition of injectee. Required ' + 
+							'parameters can\'t have type "*".');
+					}
+					else
+					{
+						parameterTypeName = null;
+					}
+				}
+				else
+				{
+					parameterType = Class(injector.getApplicationDomain().getDefinition(parameterTypeName));
+				}
+				m_injectionConfigs.push(injector.getMapping(parameterType, injectionName));
+				if (parameter.@optional.toString() == 'false')
+				{
+					requiredParameters++;
+				}
+				i++;
+			}
+		}
+		
+		protected function gatherParameterValues(target : Object, injector : Injector) : Array
+		{
+			var parameters : Array = [];
+			var length : int = m_injectionConfigs.length;
+			for (var i : int = 0; i < length; i++)
+			{
+				var config : InjectionConfig = m_injectionConfigs[i];
+				var injection : Object = config.getResponse(injector);
+				if (injection == null)
+				{
+					if (i >= requiredParameters)
+					{
+						break;
+					}
+					throw(new InjectorError(
+						'Injector is missing a rule to handle injection into target ' + target + 
+						'. Target dependency: ' + getQualifiedClassName(config.request) + 
+						', method: ' + methodName + ', parameter: ' + (i + 1)
+					));
+				}
+				
+				parameters[i] = injection;
+			}
+			return parameters;
+		}
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/injectionpoints/NoParamsConstructorInjectionPoint.as

@@ -0,0 +1,24 @@
+/*
+ * Copyright (c) 2009 the original author or authors
+ * 
+ * Permission is hereby granted to use, modify, and distribute this file 
+ * in accordance with the terms of the license agreement accompanying it.
+ */
+
+package org.swiftsuspenders.injectionpoints
+{
+	import org.swiftsuspenders.Injector;
+
+	public class NoParamsConstructorInjectionPoint extends InjectionPoint
+	{
+		public function NoParamsConstructorInjectionPoint()
+		{
+			super(null, null);
+		}
+		
+		override public function applyInjection(target : Object, injector : Injector) : Object
+		{
+			return new target();
+		}
+	}
+}

data/vendor/as3injection/org/swiftsuspenders/injectionpoints/PostConstructInjectionPoint.as

@@ -0,0 +1,52 @@
+/*
+* Copyright (c) 2009 the original author or authors
+* 
+* Permission is hereby granted to use, modify, and distribute this file 
+* in accordance with the terms of the license agreement accompanying it.
+*/
+
+package org.swiftsuspenders.injectionpoints
+{
+	import org.swiftsuspenders.Injector;
+	
+	public class PostConstructInjectionPoint extends InjectionPoint
+	{
+		/*******************************************************************************************
+		 *								private properties										   *
+		 *******************************************************************************************/
+		protected var methodName : String;
+		protected var orderValue:int;
+		
+		
+		/*******************************************************************************************
+		 *								public methods											   *
+		 *******************************************************************************************/
+		public function PostConstructInjectionPoint(node:XML, injector : Injector)
+		{
+			super(node, injector);
+		}
+		
+		public function get order():int
+		{
+			return orderValue;
+		}
+
+		override public function applyInjection(target : Object, injector : Injector) : Object
+		{
+			target[methodName]();
+			return target;
+		}
+		
+		
+		/*******************************************************************************************
+		 *								protected methods										   *
+		 *******************************************************************************************/
+		override protected function initializeInjection(node : XML, injector : Injector) : void
+		{
+			var orderArg : XMLList = node.arg.(@key == 'order');
+			var methodNode : XML = node.parent();
+			orderValue = int(orderArg.@value);
+			methodName = methodNode.@name.toString();
+		}
+	}
+}