as3corelib 0.1.0

data/src/com/adobe/air/filesystem/VolumeMonitor.as

@@ -0,0 +1,184 @@
+/*
+  Copyright (c) 2009, Adobe Systems Incorporated
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without 
+  modification, are permitted provided that the following conditions are
+  met:
+
+  * Redistributions of source code must retain the above copyright notice, 
+    this list of conditions and the following disclaimer.
+  
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the 
+    documentation and/or other materials provided with the distribution.
+  
+  * Neither the name of Adobe Systems Incorporated nor the names of its 
+    contributors may be used to endorse or promote products derived from 
+    this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.air.filesystem
+{
+	import flash.events.EventDispatcher;
+	import flash.utils.Timer;
+	import flash.events.TimerEvent;
+	import flash.filesystem.File;
+	import flash.utils.Dictionary;
+	import com.adobe.air.filesystem.events.FileMonitorEvent;
+	import com.adobe.utils.ArrayUtil;
+
+	/**
+	* Dispatched when a volume is added to the system.
+	*
+	* @eventType com.adobe.air.filesystem.events.FileMonitor.ADD_VOLUME
+	*/
+	[Event(name="ADD_VOLUME", type="com.adobe.air.filesystem.events.FileMonitor")]	
+
+	/**
+	* Dispatched when a volume is removed from the system.
+	*
+	* @eventType com.adobe.air.filesystem.events.FileMonitor.REMOVE_VOLUME
+	*/
+	[Event(name="REMOVE_VOLUME", type="com.adobe.air.filesystem.events.FileMonitor")]	
+
+	/**
+	 * Class that monitors changes to the File volumes attached to the operating
+	 * system.
+	 */ 
+	public class VolumeMonitor extends EventDispatcher
+	{
+		private var timer:Timer;
+		private var _interval:Number;
+		private static const DEFAULT_MONITOR_INTERVAL:Number = 2000;
+		
+		private var volumes:Dictionary;
+		
+		/**
+		 * 	Constructor.
+		 * 
+		 * 	@param interval How often in milliseconds the system is polled for
+		 * 	volume change events. Default value is 2000, minimum value is 1000
+		 */
+		public function VolumeMonitor(interval:Number = -1)
+		{
+			if(interval != -1)
+			{
+				if(interval < 1000)
+				{
+					_interval = 1000;
+				}
+				else
+				{
+					_interval = interval;
+				}
+			}
+			else
+			{
+				_interval = DEFAULT_MONITOR_INTERVAL;
+			}
+		}
+		
+		/**
+		 * 	How often the system is polled for Volume change events.
+		 */
+		public function get interval():Number
+		{
+			return _interval;
+		}
+		
+		/**
+		 * Begins the monitoring of changes to the attached File volumes.
+		 */
+		public function watch():void
+		{
+			if(!timer)
+			{
+				timer = new Timer(_interval);
+				timer.addEventListener(TimerEvent.TIMER, onTimerEvent,false,0, true);
+			}
+			
+			//we reinitialize the hash everytime we start watching
+			volumes = new Dictionary();
+			
+			var v:Array = FileUtil.getRootDirectories();
+			for each(var f:File in v)
+			{
+				//null or undefined
+				if(volumes[f.url] == null)
+				{
+					volumes[f.url] = f;
+				}
+			}			
+			
+			timer.start();
+		}
+		
+		/**
+		 * Stops monitoring for changes to the attached File volumes.
+		 */
+		public function unwatch():void
+		{
+			timer.stop();
+			timer.removeEventListener(TimerEvent.TIMER, onTimerEvent);
+		}
+		
+		private function onTimerEvent(e:TimerEvent):void
+		{
+			var v:Array = FileUtil.getRootDirectories();
+			
+			var outEvent:FileMonitorEvent;
+			var found:Boolean = false;
+			for(var key:String in volumes)
+			{
+				for each(var f:File in v)
+				{
+					//trace("--\n" + key);
+					//trace(f.url);
+					if(f.url == key)
+					{
+						found = true;
+						break;
+					}
+				}
+				
+				if(!found)
+				{
+					outEvent = new FileMonitorEvent(FileMonitorEvent.REMOVE_VOLUME);
+					outEvent.file = volumes[key];
+					dispatchEvent(outEvent);
+					delete volumes[key];
+				}
+				
+				found  = false;
+			}
+			
+			for each(var f2:File in v)
+			{
+				//null or undefined
+				if(volumes[f2.url] == null)
+				{
+					volumes[f2.url] = f2;
+					outEvent = new FileMonitorEvent(FileMonitorEvent.ADD_VOLUME);
+					outEvent.file = f2;
+					
+					dispatchEvent(outEvent);
+				}
+			}
+		}
+		
+
+	}
+}

data/src/com/adobe/air/filesystem/events/FileMonitorEvent.as

@@ -0,0 +1,61 @@
+/*
+  Copyright (c) 2009, Adobe Systems Incorporated
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without 
+  modification, are permitted provided that the following conditions are
+  met:
+
+  * Redistributions of source code must retain the above copyright notice, 
+    this list of conditions and the following disclaimer.
+  
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the 
+    documentation and/or other materials provided with the distribution.
+  
+  * Neither the name of Adobe Systems Incorporated nor the names of its 
+    contributors may be used to endorse or promote products derived from 
+    this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.air.filesystem.events
+{
+	import flash.events.Event;
+	import flash.filesystem.File;
+
+	public class FileMonitorEvent extends Event
+	{
+		public static const CHANGE:String = "onFileChange";
+		public static const MOVE:String = "onFileMove";
+		public static const CREATE:String = "onFileCreate";
+		public static const ADD_VOLUME:String = "onVolumeAdd";
+		public static const REMOVE_VOLUME:String = "onVolumeRemove";
+		
+		public var file:File;
+		public function FileMonitorEvent(type:String, bubbles:Boolean=false, 
+				cancelable:Boolean=false)
+		{
+			super(type, bubbles, cancelable);
+		}
+		
+		public override function clone():Event
+		{
+			var out:FileMonitorEvent = new FileMonitorEvent(type, bubbles, cancelable);
+			out.file = file;
+			
+			return out;
+		}
+	}
+}

data/src/com/adobe/air/logging/FileTarget.as

@@ -0,0 +1,95 @@
+/*
+  Copyright (c) 2008, Adobe Systems Incorporated
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without 
+  modification, are permitted provided that the following conditions are
+  met:
+
+  * Redistributions of source code must retain the above copyright notice, 
+    this list of conditions and the following disclaimer.
+  
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the 
+    documentation and/or other materials provided with the distribution.
+  
+  * Neither the name of Adobe Systems Incorporated nor the names of its 
+    contributors may be used to endorse or promote products derived from 
+    this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.air.logging
+{
+	import flash.filesystem.File;
+	import flash.filesystem.FileMode;
+	import flash.filesystem.FileStream;
+	
+	import mx.core.mx_internal;
+	import mx.logging.targets.LineFormattedTarget;
+	
+	use namespace mx_internal;
+
+	/**
+	 * An Adobe AIR only class that provides a log target for the Flex logging
+	 * framework, that logs files to a file on the user's system.
+	 * 
+	 * This class will only work when running within Adobe AIR>
+	 */
+	public class FileTarget extends LineFormattedTarget
+	{
+		private const DEFAULT_LOG_PATH:String = "app-storage:/application.log";
+		
+		private var log:File;
+		
+		public function FileTarget(logFile:File = null)
+		{
+			if(logFile != null)
+			{
+				log = logFile;
+			}
+			else
+			{
+				log = new File(DEFAULT_LOG_PATH);
+			}
+		}
+		
+		public function get logURI():String
+		{
+			return log.url;
+		}
+		
+		mx_internal override function internalLog(message:String):void
+	    {
+			write(message);
+	    }		
+		
+		private function write(msg:String):void
+		{		
+			var fs:FileStream = new FileStream();
+				fs.open(log, FileMode.APPEND);
+				fs.writeUTFBytes(msg + File.lineEnding);
+				fs.close();
+		}	
+		
+		public function clear():void
+		{
+			var fs:FileStream = new FileStream();
+				fs.open(log, FileMode.WRITE);
+				fs.writeUTFBytes("");
+				fs.close();			
+		}
+		
+	}
+}

data/src/com/adobe/air/net/ResourceCache.as

@@ -0,0 +1,165 @@
+/*
+  Copyright (c) 2009, Adobe Systems Incorporated
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without 
+  modification, are permitted provided that the following conditions are
+  met:
+
+  * Redistributions of source code must retain the above copyright notice, 
+    this list of conditions and the following disclaimer.
+  
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the 
+    documentation and/or other materials provided with the distribution.
+  
+  * Neither the name of Adobe Systems Incorporated nor the names of its 
+    contributors may be used to endorse or promote products derived from 
+    this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.air.net
+{
+	import com.adobe.crypto.MD5;
+	import com.adobe.net.DynamicURLLoader;
+	
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+	import flash.events.IOErrorEvent;
+	import flash.filesystem.File;
+	import flash.filesystem.FileMode;
+	import flash.filesystem.FileStream;
+	import flash.net.URLLoaderDataFormat;
+	import flash.net.URLRequest;
+	import flash.utils.ByteArray;
+	import com.adobe.air.net.events.ResourceCacheEvent;
+
+	//todo: add event metadata
+
+	public class ResourceCache extends EventDispatcher
+	{
+		private var _cacheName:String;
+		//maybe rename to make it clearer it loads data
+		public function ResourceCache(cacheName:String)
+		{
+			_cacheName = cacheName;
+		}
+		
+		public function get cacheName():String
+		{
+			return _cacheName;
+		}
+		
+		private function getStorageDir():File
+		{
+			return File.applicationStorageDirectory.resolvePath(_cacheName);
+		}
+		
+		public function itemExists(key:String):Boolean
+		{
+			return getItemFile(key).exists;
+		}
+		
+		public function clearCache():void
+		{
+			var cacheDir:File = getStorageDir();
+			try
+			{
+				cacheDir.deleteDirectory(true);
+			}
+			catch (e:IOErrorEvent)
+			{
+				// we tried!
+			}
+		}
+		
+		public function getItemFile(key:String):File
+		{
+			var dir:File = getStorageDir();
+			var fName:String = generateKeyHash(key);
+			var file:File = dir.resolvePath(fName);
+			
+			return file;
+		}
+		
+		public function retrieve(url:String):void
+		{
+			
+			var key:String = generateKeyHash(url);
+			var file:File = getItemFile(key);
+			
+			//todo: do we need to check if the dir exists?
+			
+			if(file.exists)
+			{
+				var e:ResourceCacheEvent = new ResourceCacheEvent(ResourceCacheEvent.ITEM_READY);
+					e.key = key;
+					e.file = file;
+					
+				dispatchEvent(e);	
+				return;
+			}
+			
+			
+			var loader:DynamicURLLoader = new DynamicURLLoader();
+				loader.file = file;
+				loader.key = key;
+				
+				loader.addEventListener(Event.COMPLETE, onDataLoad);
+				loader.addEventListener(IOErrorEvent.IO_ERROR, onLoadError);
+				
+				loader.dataFormat = URLLoaderDataFormat.BINARY;
+				
+				loader.load(new URLRequest(url));
+			
+		}
+		
+		private function onLoadError(event:IOErrorEvent):void
+		{
+			trace("onLoadError : could not cache item");
+		}
+		
+		private function onDataLoad(event:Event):void
+		{
+			var loader:DynamicURLLoader = DynamicURLLoader(event.target);
+			
+			var f:File = File(loader.file);
+			var key:String = String(loader.key);
+			
+			var fileStream:FileStream = new FileStream();
+				fileStream.open(f, FileMode.WRITE);
+				fileStream.writeBytes(loader.data as ByteArray);
+				fileStream.close();
+				
+				var g:ResourceCacheEvent = new ResourceCacheEvent(ResourceCacheEvent.ITEM_CACHED);
+					g.key = key;
+					g.file = f;
+					
+				dispatchEvent(g);	
+				
+				var e:ResourceCacheEvent = new ResourceCacheEvent(ResourceCacheEvent.ITEM_READY);
+					e.key = key;
+					e.file = f;
+					
+				dispatchEvent(e);	
+		}
+		
+		
+		private function generateKeyHash(key:String):String
+		{
+			return MD5.hash(key);
+		}
+	}
+}

data/src/com/adobe/air/net/events/ResourceCacheEvent.as

@@ -0,0 +1,70 @@
+/*
+  Copyright (c) 2009, Adobe Systems Incorporated
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without 
+  modification, are permitted provided that the following conditions are
+  met:
+
+  * Redistributions of source code must retain the above copyright notice, 
+    this list of conditions and the following disclaimer.
+  
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the 
+    documentation and/or other materials provided with the distribution.
+  
+  * Neither the name of Adobe Systems Incorporated nor the names of its 
+    contributors may be used to endorse or promote products derived from 
+    this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.air.net.events
+{
+	import flash.events.Event;
+	import flash.filesystem.File;
+
+	public class ResourceCacheEvent extends Event
+	{
+		
+		public static const ITEM_READY:String = "onPathReady";
+		public static const ITEM_CACHED:String = "onItemCached";
+		
+		[Bindable]
+		public var key:String;
+		
+		[Bindable]
+		public var file:File;		
+		
+		public function ResourceCacheEvent(type:String, 
+												bubbles:Boolean=false, 
+												cancelable:Boolean=false)
+		{
+			super(type, bubbles, cancelable);
+		}
+		
+		public override function clone():Event
+		{
+			var out:ResourceCacheEvent = new ResourceCacheEvent(type,
+																bubbles,
+																cancelable);
+																
+			out.key = key;
+			out.file = file;
+			
+			return out;
+		}
+		
+	}
+}

data/src/com/adobe/crypto/HMAC.as

@@ -0,0 +1,127 @@
+/*
+  Copyright (c) 2008, Adobe Systems Incorporated
+  All rights reserved.
+
+  Redistribution and use in source and binary forms, with or without 
+  modification, are permitted provided that the following conditions are
+  met:
+
+  * Redistributions of source code must retain the above copyright notice, 
+    this list of conditions and the following disclaimer.
+  
+  * Redistributions in binary form must reproduce the above copyright
+    notice, this list of conditions and the following disclaimer in the 
+    documentation and/or other materials provided with the distribution.
+  
+  * Neither the name of Adobe Systems Incorporated nor the names of its 
+    contributors may be used to endorse or promote products derived from 
+    this software without specific prior written permission.
+
+  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
+  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
+  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
+  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
+  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
+  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.crypto {
+	import flash.utils.ByteArray;
+	import flash.utils.Endian;
+	import flash.utils.describeType;
+	/**
+	 * Keyed-Hashing for Message Authentication
+	 * Implementation based on algorithm description at 
+	 * http://www.faqs.org/rfcs/rfc2104.html
+	 */
+	public class HMAC 
+	{
+		/**
+		 * Performs the HMAC hash algorithm using byte arrays.
+		 *
+		 * @param secret The secret key
+		 * @param message The message to hash
+		 * @param algorithm Hash object to use
+		 * @return A string containing the hash value of message
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 8.5
+		 * @tiptext
+		 */
+		public static function hash( secret:String, message:String, algorithm:Object = null ):String
+		{
+			var text:ByteArray = new ByteArray();
+			var k_secret:ByteArray = new ByteArray();
+			
+			text.writeUTFBytes(message);
+			k_secret.writeUTFBytes(secret);
+			
+			return hashBytes(k_secret, text, algorithm);
+		}
+		
+		/**
+		 * Performs the HMAC hash algorithm using string.
+		 *
+		 * @param secret The secret key
+		 * @param message The message to hash
+		 * @param algorithm Hash object to use
+		 * @return A string containing the hash value of message
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 8.5
+		 * @tiptext
+		 */
+		public static function hashBytes( secret:ByteArray, message:ByteArray, algorithm:Object = null ):String
+		{
+			var ipad:ByteArray = new ByteArray();
+			var opad:ByteArray = new ByteArray();
+			var endian:String = Endian.BIG_ENDIAN;
+			
+			if(algorithm == null){
+				algorithm = MD5;
+			}
+			
+			if ( describeType(algorithm).@name.toString() == "com.adobe.crypto::MD5" ) {
+				endian = Endian.LITTLE_ENDIAN;
+			}
+			
+			if ( secret.length > 64 ) {
+				algorithm.hashBytes(secret);
+				secret = new ByteArray();
+				secret.endian = endian;
+				
+				while ( algorithm.digest.bytesAvailable != 0 ) {
+					secret.writeInt(algorithm.digest.readInt());
+				}
+			}
+
+			secret.length = 64
+			secret.position = 0;
+			for ( var x:int = 0; x < 64; x++ ) {
+				var byte:int = secret.readByte();
+				ipad.writeByte(0x36 ^ byte);
+				opad.writeByte(0x5c ^ byte);
+			}
+			
+			ipad.writeBytes(message);
+			algorithm.hashBytes(ipad);
+			var tmp:ByteArray = new ByteArray();
+			tmp.endian = endian;	
+			
+			while ( algorithm.digest.bytesAvailable != 0 ) {
+				tmp.writeInt(algorithm.digest.readInt());
+			}
+			tmp.position = 0;
+			
+			while ( tmp.bytesAvailable != 0 ) {
+				opad.writeByte(tmp.readUnsignedByte());
+			}
+			return algorithm.hashBytes( opad );
+		}
+		
+	}
+	
+}