activeadministration 0.0.1

data/app/assets/javascripts/active_admin/lib/checkbox-toggler.js.coffee

@@ -0,0 +1,36 @@
+class ActiveAdmin.CheckboxToggler
+  constructor: (@options, @container)->
+    defaults = {}
+    @options = $.extend defaults, options
+    @_init()
+    @_bind()
+
+  _init: ->
+    if not @container
+      throw new Error('Container element not found')
+    else
+      @$container = $(@container)
+
+    if not @$container.find('.toggle_all').length
+      throw new Error('"toggle all" checkbox not found')
+    else
+      @toggle_all_checkbox = @$container.find '.toggle_all'
+
+    @checkboxes = @$container.find(':checkbox').not @toggle_all_checkbox
+
+  _bind: ->
+    @checkboxes.change       (e)=> @_didChangeCheckbox e.target
+    @toggle_all_checkbox.change => @_didChangeToggleAllCheckbox()
+
+  _didChangeCheckbox: (checkbox)->
+    switch @checkboxes.filter(':checked').length
+      when @checkboxes.length - 1 then @toggle_all_checkbox.prop checked: null
+      when @checkboxes.length     then @toggle_all_checkbox.prop checked: true
+
+  _didChangeToggleAllCheckbox: ->
+    setting = if @toggle_all_checkbox.prop 'checked' then true else null
+    @checkboxes.each (index, el)=>
+      $(el).prop checked: setting
+      @_didChangeCheckbox(el)
+
+$.widget.bridge 'checkboxToggler', ActiveAdmin.CheckboxToggler

data/app/assets/javascripts/active_admin/lib/dropdown-menu.js.coffee

@@ -0,0 +1,85 @@
+class ActiveAdmin.DropdownMenu
+
+  constructor: (@options, @element) ->
+    @$element = $(@element)
+
+    defaults = {
+      fadeInDuration: 20,
+      fadeOutDuration: 100,
+      onClickActionItemCallback: null
+    }
+
+    @options = $.extend defaults, options
+    @isOpen  = false
+
+    @$menuButton = @$element.find '.dropdown_menu_button'
+    @$menuList   = @$element.find '.dropdown_menu_list_wrapper'
+
+    @_buildMenuList()
+    @_bind()
+
+  open: ->
+    @isOpen = true
+    @$menuList.fadeIn @options.fadeInDuration
+
+    @_positionMenuList()
+    @_positionNipple()
+    @
+
+
+  close: ->
+    @isOpen = false
+    @$menuList.fadeOut this.options.fadeOutDuration
+    @
+
+  destroy: ->
+    @$element.unbind()
+    @$element = null
+    @
+
+  isDisabled: ->
+    @$menuButton.hasClass 'disabled'
+
+  disable: ->
+    @$menuButton.addClass 'disabled'
+
+  enable: ->
+    @$menuButton.removeClass 'disabled'
+
+  option: (key, value) ->
+    if $.isPlainObject(key)
+      @options = $.extend(true, @options, key)
+    else if key?
+      @options[key]
+    else
+      @options[key] = value
+
+  # Private
+
+  _buildMenuList: ->
+    @$nipple = $('<div class="dropdown_menu_nipple"></div>')
+    @$menuList.prepend @$nipple
+    @$menuList.hide()
+
+  _bind: ->
+    $('body').click =>
+      @close() if @isOpen
+
+    @$menuButton.click =>
+      unless @isDisabled()
+        if @isOpen then @close() else @open()
+      false
+
+  _positionMenuList: ->
+    button_center = @$menuButton.position().left + @$menuButton.outerWidth() / 2
+    menu_center   = @$menuList.outerWidth() / 2
+    @$menuList.css 'left', button_center - menu_center
+
+  _positionNipple: ->
+    @$menuList.css 'top',  @$menuButton.position().top + @$menuButton.outerHeight() + 10
+    @$nipple.css   'left', @$menuList.outerWidth() / 2 - @$nipple.outerWidth() / 2
+
+$.widget.bridge 'aaDropdownMenu', ActiveAdmin.DropdownMenu
+
+$ ->
+  $('.dropdown_menu').aaDropdownMenu()

data/app/assets/javascripts/active_admin/lib/has_many.js.coffee

@@ -0,0 +1,75 @@
+$ ->
+  # Provides a before-removal hook:
+  # $ ->
+  #   # This is a good place to tear down JS plugins to prevent memory leaks.
+  #   $(document).on 'has_many_remove:before', '.has_many_container', (e, fieldset)->
+  #     fieldset.find('.select2').select2 'destroy'
+  #
+  $(document).on 'click', 'a.button.has_many_remove', (e)->
+    e.preventDefault()
+    parent    = $(@).closest '.has_many_container'
+    to_remove = $(@).closest 'fieldset'
+    recompute_positions parent
+
+    parent.trigger 'has_many_remove:before', [ to_remove ]
+    to_remove.remove()
+
+  # Provides before and after creation hooks:
+  # $ ->
+  #   # The before hook allows you to prevent the creation of new records.
+  #   $(document).on 'has_many_add:before', '.has_many_container', (e)->
+  #     if $(@).children('fieldset').length >= 3
+  #       alert "you've reached the maximum number of items"
+  #       e.preventDefault()
+  #
+  #   # The after hook is a good place to initialize JS plugins and the like.
+  #   $(document).on 'has_many_add:after', '.has_many_container', (e, fieldset)->
+  #     fieldset.find('select').chosen()
+  #
+  $(document).on 'click', 'a.button.has_many_add', (e)->
+    e.preventDefault()
+    elem   = $(@)
+    parent = elem.closest '.has_many_container'
+    parent.trigger before_add = $.Event 'has_many_add:before'
+
+    unless before_add.isDefaultPrevented()
+      index = parent.data('has_many_index') || parent.children('fieldset').length - 1
+      parent.data has_many_index: ++index
+
+      regex = new RegExp elem.data('placeholder'), 'g'
+      html  = elem.data('html').replace regex, index
+
+      fieldset = $(html).insertBefore(@)
+      recompute_positions parent
+      parent.trigger 'has_many_add:after', [ fieldset ]
+
+  $(document).on 'change','.has_many_container[data-sortable] :input[name$="[_destroy]"]', ->
+    recompute_positions $(@).closest '.has_many'
+
+  init_sortable()
+  $(document).on 'has_many_add:after', '.has_many_container', init_sortable
+
+
+# Helpers
+init_sortable = ->
+  elems = $('.has_many_container[data-sortable]:not(.ui-sortable)')
+  elems.sortable \
+    items: '> fieldset',
+    handle: '> ol > .handle',
+    stop:    recompute_positions
+  elems.each recompute_positions
+
+recompute_positions = (parent)->
+  parent     = if parent instanceof jQuery then parent else $(@)
+  input_name = parent.data 'sortable'
+  position   = 0
+
+  parent.children('fieldset').each ->
+    fieldset = $(@)
+    # when looking for inputs, we ignore inputs from the possibly nested inputs
+    # so, when defining your has_many, make sure to keep the sortable input at the root of the has_many block
+    destroy_input  = fieldset.find "> ol > .input > :input[name$='[_destroy]']"
+    sortable_input = fieldset.find "> ol > .input > :input[name$='[#{input_name}]']"
+
+    if sortable_input.length
+      sortable_input.val if destroy_input.is ':checked' then '' else position++

data/app/assets/javascripts/active_admin/lib/modal_dialog.js.coffee

@@ -0,0 +1,36 @@
+ActiveAdmin.modal_dialog = (message, inputs, callback)->
+  html = """<form id="dialog_confirm" title="#{message}"><ul>"""
+  for name, type of inputs
+    if /^(datepicker|checkbox|text)$/.test type
+      wrapper = 'input'
+    else if type is 'textarea'
+      wrapper = 'textarea'
+    else if $.isArray type
+      [wrapper, elem, opts, type] = ['select', 'option', type, '']
+    else
+      throw new Error "Unsupported input type: {#{name}: #{type}}"
+
+    klass = if type is 'datepicker' then type else ''
+    html += """<li>
+      <label>#{name.charAt(0).toUpperCase() + name.slice(1)}</label>
+      <#{wrapper} name="#{name}" class="#{klass}" type="#{type}">""" +
+        (if opts then (
+          for v in opts
+            if $.isArray v
+              "<#{elem} value=#{v[1]}>#{v[0]}</#{elem}>"
+            else
+              "<#{elem}>#{v}</#{elem}>"
+        ).join '' else '') +
+      "</#{wrapper}>" +
+    "</li>"
+    [wrapper, elem, opts, type, klass] = [] # unset any temporary variables
+
+  html += "</ul></form>"
+  $(html).appendTo('body').dialog
+    modal: true
+    buttons:
+      OK: ->
+        callback $(@).serializeObject()
+        $(@).dialog('close')
+      Cancel: ->
+        $(@).dialog('close').remove()

data/app/assets/javascripts/active_admin/lib/popover.js.coffee

@@ -0,0 +1,68 @@
+class ActiveAdmin.Popover
+
+  constructor: (@options, @element) ->
+    @$element = $(@element)
+
+    defaults = {
+      fadeInDuration: 20,
+      fadeOutDuration: 100,
+      autoOpen: true,
+      pageWrapperElement: "#wrapper",
+      onClickActionItemCallback: null
+    }
+
+    @options = $.extend defaults, options
+    @isOpen  = false
+
+    unless (@$popover = $ @$element.attr 'href').length
+      @$popover = @$element.next '.popover'
+
+    @_buildPopover()
+    @_bind()
+
+  open: ->
+    @isOpen = true
+    @$popover.fadeIn @options.fadeInDuration
+    @_positionPopover()
+    @_positionNipple()
+    @
+
+  close: ->
+    @isOpen = false
+    @$popover.fadeOut this.options.fadeOutDuration
+    @
+
+  destroy: ->
+    @$element.removeData 'popover'
+    @$element.unbind()
+    @$element = null
+    @
+
+  # Private
+
+  _buildPopover: ->
+    @$nipple = $('<div class="popover_nipple"></div>')
+    @$popover.prepend @$nipple
+    @$popover.hide()
+    @$popover.addClass 'popover'
+
+
+  _bind: ->
+    $(@options.pageWrapperElement).click =>
+      @close() if @isOpen
+
+    if @options.autoOpen
+      @$element.click (e)=>
+        e.stopPropagation()
+        if @isOpen then @close() else @open()
+
+  _positionPopover: ->
+    button_center = @$element.offset().left + @$element.outerWidth() / 2
+    popover_center = @$popover.outerWidth() / 2
+    @$popover.css 'left', button_center - popover_center
+
+  _positionNipple: ->
+    @$popover.css 'top', @$element.offset().top     + @$element.outerHeight() + 10
+    @$nipple.css 'left', @$popover.outerWidth() / 2 - @$nipple.outerWidth() / 2
+
+$.widget.bridge 'popover', ActiveAdmin.Popover

data/app/assets/javascripts/active_admin/lib/table-checkbox-toggler.js.coffee

@@ -0,0 +1,24 @@
+class ActiveAdmin.TableCheckboxToggler extends ActiveAdmin.CheckboxToggler
+  _init: ->
+    super
+
+  _bind: ->
+    super
+
+    @$container.find('tbody td').click (e)=>
+      @_didClickCell(e.target) if e.target.type isnt 'checkbox'
+
+  _didChangeCheckbox: (checkbox) ->
+    super
+
+    $row = $(checkbox).parents 'tr'
+
+    if checkbox.checked
+      $row.addClass 'selected'
+    else
+      $row.removeClass 'selected'
+
+  _didClickCell: (cell) ->
+    $(cell).parent('tr').find(':checkbox').click()
+
+$.widget.bridge 'tableCheckboxToggler', ActiveAdmin.TableCheckboxToggler

data/app/assets/stylesheets/active_admin/_base.css.scss

@@ -0,0 +1,42 @@
+/* Active Admin CSS */
+// Reset Away!
+@include global-reset;
+
+// Partials
+@import "active_admin/typography";
+@import "active_admin/header";
+@import "active_admin/forms";
+@import "active_admin/components/comments";
+@import "active_admin/components/flash_messages";
+@import "active_admin/components/date_picker";
+@import "active_admin/components/popovers";
+@import "active_admin/components/tables";
+@import "active_admin/components/batch_actions";
+@import "active_admin/components/modal_dialog";
+@import "active_admin/components/blank_slates";
+@import "active_admin/components/breadcrumbs";
+@import "active_admin/components/dropdown_menu";
+@import "active_admin/components/buttons";
+@import "active_admin/components/grid";
+@import "active_admin/components/links";
+@import "active_admin/components/pagination";
+@import "active_admin/components/panels";
+@import "active_admin/components/columns";
+@import "active_admin/components/scopes";
+@import "active_admin/components/status_tags";
+@import "active_admin/components/table_tools";
+@import "active_admin/components/index_list";
+@import "active_admin/pages/logged_out";
+@import "active_admin/structure/footer";
+@import "active_admin/structure/main_structure";
+@import "active_admin/structure/title_bar";
+
+body {
+  @include sans-family;
+  line-height: 150%;
+  font-size: 72%;
+  background: $body-background-color;
+  margin: 0;
+  padding: 0;
+  color: $text-color;
+}

data/app/assets/stylesheets/active_admin/_forms.css.scss

@@ -0,0 +1,329 @@
+//= depend_on_asset "active_admin/datepicker/datepicker-input-icon.png"
+// -------------------------------------- Active Admin Forms
+form {
+  /* Reset margins & Padding */
+  ul, ol, li, fieldset, legend, input, textarea, select, p { margin:0; padding:0; }
+  ol, ul { list-style: none }
+
+  fieldset {
+    border: 0;
+    padding: 10px 0;
+    margin-bottom: 20px;
+
+    &.inputs { @include section-background; }
+
+    legend {
+      width: 100%;
+      span { display: block; @include section-header; }
+    }
+
+    ol > li {
+      padding: 10px;
+      label {
+        display: block;
+        width: 20%;
+        float: left;
+        font-size: 1.0em;
+        font-weight: bold;
+        color: $form-label-color;
+        abbr {
+          border: none;
+          color:  $required-field-marker-color;
+        }
+      }
+    }
+
+    ol > li.has_many_container {
+      padding: 20px 10px;
+      h3 {
+        font-size: 12px;
+        font-weight: bold;
+      }
+      .has_many_fields { margin: 10px 0 }
+    }
+
+    ol > li > li label {
+      line-height:100%;
+      padding-top:0;
+      input {
+        line-height:100%;
+        vertical-align:middle;
+        margin-top:-0.1em;
+      }
+    }
+  }
+
+  // relative so the absolutely-positioned handle will fit
+  .has_many_fields { position: relative }
+
+  .has_many_container {
+    .handle {
+      position: absolute;
+      @include icon-size(3em);
+      top: calc(50% - 3em / 2);
+      right: 2px;
+      padding: 0;
+      cursor: move;
+    }
+
+    // If a sortable is nested in a sortable, give the parent handle space!
+    &.ui-sortable .has_many_container {
+      margin-right: 2em;
+    }
+  }
+
+  .ui-sortable {
+    // give the handle space!
+    input[type=text], input[type=password], input[type=email], input[type=number], input[type=url], input[type=tel], textarea {
+      width: calc(80% - #{$text-input-total-padding} - 2em - 1px);
+    }
+  }
+
+  /* Nested Fieldsets and Legends */
+
+  fieldset > ol > li {
+    fieldset {
+      position:relative;
+      padding: 0;
+      margin-bottom: 0;
+
+      legend {
+        position:absolute;
+        width:95%;
+        padding-top:0.1em;
+        left: 0px;
+        font-size: 100%;
+        font-weight: normal;
+        span { position:absolute; }
+        &.label label { position:absolute; }
+      }
+
+      &:not(.has_many_fields) ol {
+        float: left;
+        width: 74%;
+        margin: 0;
+        padding: 0 0 0 20%;
+
+        li {
+          padding: 0;
+          border: 0;
+        }
+      }
+
+      &.has_many_fields ol {
+        float: left;
+        width: 100%;
+        margin: 0;
+        padding: 0;
+      }
+    }
+  }
+
+  /* Text Fields */
+  input[type=text], input[type=password], input[type=email], input[type=number], input[type=url], input[type=tel], textarea {
+    width: calc(80% - #{$text-input-total-padding});
+    border: $border-width solid #c9d0d6;
+    @include rounded;
+    font-size: 0.95em;
+    @include sans-family;
+    outline: none;
+    padding: 8px $text-input-horizontal-padding 7px;
+
+    &:focus {
+      border: $border-width solid #99a2aa;
+      @include shadow(0,0,4px,#99a2aa);
+    }
+  }
+
+  fieldset > ol > li {
+
+    /* Hints */
+    p.inline-hints {
+      font-size: 0.95em;
+      font-style: italic;
+      color:#666;
+      margin: 0.5em 0 0 20%;
+    }
+
+    /* Date and Time Fields */
+    &.date, &.time, &.datetime, &.date_select {
+      fieldset ol li {
+        float:left; width:auto; margin:0 0.5em 0 0;
+        label { display: none; }
+        input { display:inline; margin:0; padding:0;  }
+      }
+    }
+
+    /* Check Boxes or Radio fields */
+    &.check_boxes, &.radio {
+      fieldset ol {
+        margin-bottom:-0.6em;
+        li {
+          margin:0.1em 0 0.5em 0;
+          label {
+            float:none;
+            width:100%;
+            input { margin-right:0.2em; }
+          }
+        }
+      }
+    }
+
+    /* Boolean Field */
+    &.boolean {
+      height: 1.1em;
+      label {
+        width: 80%;
+        padding-left:20%;
+        padding-right: 10px;
+        text-transform: none !important;
+        font-weight: normal;
+        input { margin:0 0.5em 0 0.2em; }
+      }
+    }
+
+    /* Hidden fields */
+    &.hidden {
+      padding: 0;
+    }
+
+    /* Errors */
+    p.inline-errors {
+      color: $error-color;
+      font-weight: bold;
+      margin:0.3em 0 0 20%;
+    }
+    ul.errors {
+      color: $error-color;
+      margin:0.5em 0 0 20%;
+      list-style:square;
+      li { padding:0; border:none; display:list-item; }
+    }
+
+    &.error {
+      input[type=text], input[type=password], input[type=email], input[type=number], input[type=url], input[type=tel], textarea {
+        border: $border-width solid $error-color;
+      }
+    }
+  }
+
+  /* semantic_errors */
+  ul.errors {
+    background: lighten($error-color, 60%);
+    @include rounded(4px);
+    color: $error-color;
+    font-weight: bold;
+    margin-bottom: 10px;
+    padding: 10px;
+    list-style:square;
+    li { margin-left:15px; padding:0; border:none; display:list-item; }
+  }
+
+  /* Buttons */
+
+  input[type=submit] {
+    @include dark-button;
+    cursor: pointer;
+
+  }
+
+  .buttons, .actions {
+    margin-top: 15px;
+    input[type=submit] { margin-right: 10px; }
+  }
+
+  fieldset.buttons li, fieldset.actions li {
+    float:left;
+    padding: 0;
+
+    &.cancel {
+      a {
+        @include light-button; @include icon(#777, 9px);
+      }
+    }
+  }
+
+}
+
+// -------------------------------------- Sidebar Forms
+
+$sidebar-inner-content-width: $sidebar-width - ($section-padding * 2);
+
+.sidebar_section {
+
+  label {
+    display: block;
+    text-transform: uppercase;
+    color:  $form-label-color;
+    font-size: 0.9em;
+    font-weight: bold;
+  }
+
+  select {
+    width: $sidebar-inner-content-width;
+  }
+
+  input[type=text], input[type=password], input[type=email], input[type=url], input[type=tel], textarea {
+    width: $sidebar-inner-content-width - ($text-input-horizontal-padding * 2);
+  }
+
+}
+
+// -------------------------------------- Filter Forms
+
+$filter-field-seperator-width: 12px;
+
+$side-by-side-filter-input-width: ($sidebar-inner-content-width / 2) - ($text-input-horizontal-padding * 2) - $filter-field-seperator-width;
+$side-by-side-filter-select-width: ($sidebar-inner-content-width / 2) - $filter-field-seperator-width;
+
+$date-range-filter-input-right-padding: 27px;
+$date-range-filter-input-horizontal-padding: $date-range-filter-input-right-padding + $text-input-horizontal-padding;
+$date-range-filter-input-width: ($sidebar-inner-content-width / 2) - $filter-field-seperator-width - $date-range-filter-input-horizontal-padding;
+
+form.filter_form {
+  .filter_form_field {
+    margin-bottom: 10px;
+    clear: both;
+
+    &.select_and_search {
+      input[type=text] {
+        margin-left: $filter-field-seperator-width + 4;
+        width: $side-by-side-filter-input-width;
+      }
+      select {
+        width: $side-by-side-filter-select-width;
+      }
+    }
+
+    &.filter_check_boxes {
+      label { margin-bottom: 3px; }
+      fieldset {
+        margin-bottom: 0px;
+        padding-bottom: 0px;
+      }
+      .check_boxes_wrapper label {
+        font-weight: normal;
+        margin-bottom: 3px;
+        text-transform: none;
+        font-size: 1.0em;
+        input { vertical-align: baseline; }
+      }
+    }
+
+    &.filter_date_range {
+      .seperator {
+        display: inline-block;
+        text-align: center;
+        width: $filter-field-seperator-width;
+      }
+
+      input[type=text] {
+        background: #fff image-url('active_admin/datepicker/datepicker-input-icon.png') no-repeat 100% 7px;
+        padding-right: $date-range-filter-input-right-padding;
+        width: $date-range-filter-input-width;
+      }
+    }
+  }
+  a.clear_filters_btn { @include light-button; }
+}
+