actioncable 5.0.0.beta1.1 → 5.0.0.beta2

data/lib/assets/javascripts/action_cable/subscription.coffee

@@ -1,68 +0,0 @@
-# A new subscription is created through the ActionCable.Subscriptions instance available on the consumer. 
-# It provides a number of callbacks and a method for calling remote procedure calls on the corresponding 
-# Channel instance on the server side.
-#
-# An example demonstrates the basic functionality:
-#
-#   App.appearance = App.cable.subscriptions.create "AppearanceChannel",
-#     connected: ->
-#       # Called once the subscription has been successfully completed
-#   
-#     appear: ->
-#       @perform 'appear', appearing_on: @appearingOn()
-#   
-#     away: ->
-#       @perform 'away'
-#   
-#     appearingOn: ->
-#       $('main').data 'appearing-on'
-#
-# The methods #appear and #away forward their intent to the remote AppearanceChannel instance on the server
-# by calling the `@perform` method with the first parameter being the action (which maps to AppearanceChannel#appear/away).
-# The second parameter is a hash that'll get JSON encoded and made available on the server in the data parameter.
-#
-# This is how the server component would look:
-#
-#   class AppearanceChannel < ApplicationActionCable::Channel
-#     def subscribed
-#       current_user.appear
-#     end
-#   
-#     def unsubscribed
-#       current_user.disappear
-#     end
-#   
-#     def appear(data)
-#       current_user.appear on: data['appearing_on']
-#     end
-#   
-#     def away
-#       current_user.away
-#     end
-#   end
-#
-# The "AppearanceChannel" name is automatically mapped between the client-side subscription creation and the server-side Ruby class name.
-# The AppearanceChannel#appear/away public methods are exposed automatically to client-side invocation through the @perform method.
-class ActionCable.Subscription
-  constructor: (@subscriptions, params = {}, mixin) ->
-    @identifier = JSON.stringify(params)
-    extend(this, mixin)
-    @subscriptions.add(this)
-    @consumer = @subscriptions.consumer
-
-  # Perform a channel action with the optional data passed as an attribute
-  perform: (action, data = {}) ->
-    data.action = action
-    @send(data)
-
-  send: (data) ->
-    @consumer.send(command: "message", identifier: @identifier, data: JSON.stringify(data))
-
-  unsubscribe: ->
-    @subscriptions.remove(this)
-
-  extend = (object, properties) ->
-    if properties?
-      for key, value of properties
-        object[key] = value
-    object

data/lib/assets/javascripts/action_cable/subscriptions.coffee

@@ -1,78 +0,0 @@
-# Collection class for creating (and internally managing) channel subscriptions. The only method intended to be triggered by the user
-# us ActionCable.Subscriptions#create, and it should be called through the consumer like so:
-#
-#   @App = {}
-#   App.cable = ActionCable.createConsumer "ws://example.com/accounts/1"
-#   App.appearance = App.cable.subscriptions.create "AppearanceChannel"
-#
-# For more details on how you'd configure an actual channel subscription, see ActionCable.Subscription.
-class ActionCable.Subscriptions
-  constructor: (@consumer) ->
-    @subscriptions = []
-    @history = []
-
-  create: (channelName, mixin) ->
-    channel = channelName
-    params = if typeof channel is "object" then channel else {channel}
-    new ActionCable.Subscription this, params, mixin
-
-  # Private
-
-  add: (subscription) ->
-    @subscriptions.push(subscription)
-    @notify(subscription, "initialized")
-    @sendCommand(subscription, "subscribe")
-
-  remove: (subscription) ->
-    @forget(subscription)
-
-    unless @findAll(subscription.identifier).length
-      @sendCommand(subscription, "unsubscribe")
-
-  reject: (identifier) ->
-    for subscription in @findAll(identifier)
-      @forget(subscription)
-      @notify(subscription, "rejected")
-
-  forget: (subscription) ->
-    @subscriptions = (s for s in @subscriptions when s isnt subscription)
-
-  findAll: (identifier) ->
-    s for s in @subscriptions when s.identifier is identifier
-
-  reload: ->
-    for subscription in @subscriptions
-      @sendCommand(subscription, "subscribe")
-
-  notifyAll: (callbackName, args...) ->
-    for subscription in @subscriptions
-      @notify(subscription, callbackName, args...)
-
-  notify: (subscription, callbackName, args...) ->
-    if typeof subscription is "string"
-      subscriptions = @findAll(subscription)
-    else
-      subscriptions = [subscription]
-
-    for subscription in subscriptions
-      subscription[callbackName]?(args...)
-
-      if callbackName in ["initialized", "connected", "disconnected", "rejected"]
-        {identifier} = subscription
-        @record(notification: {identifier, callbackName, args})
-
-  sendCommand: (subscription, command) ->
-    {identifier} = subscription
-    if identifier is ActionCable.INTERNAL.identifiers.ping
-      @consumer.connection.isOpen()
-    else
-      @consumer.send({command, identifier})
-
-  record: (data) ->
-    data.time = new Date()
-    @history = @history.slice(-19)
-    @history.push(data)
-
-  toJSON: ->
-    history: @history
-    identifiers: (subscription.identifier for subscription in @subscriptions)