ab_admin 0.1.0

data/app/assets/javascripts/ab_admin/core/confirmation.js.coffee

@@ -0,0 +1,45 @@
+# Override Rails handling of confirmation
+
+$.rails.allowAction = (element) ->
+  # The message is something like "Are you sure?"
+  message = element.data('confirm')
+  # If there's no message, there's no data-confirm attribute,
+  # which means there's nothing to confirm
+  return true unless message
+  # Clone the clicked element (probably a delete link) so we can use it in the dialog box.
+  $link = element.clone()
+    # We don't necessarily want the same styling as the original link/button.
+    .removeAttr('class')
+    # We don't want to pop up another confirmation (recursion)
+    .removeAttr('data-confirm')
+    # We want a button
+    .addClass('btn').addClass('btn-danger')
+    # We want it to sound confirmy
+    .html(I18n.t('admin_js.confirm'))
+
+  # Create the modal box with the message
+  modal_html = """
+               <div class="modal" id="confirmation_dialog">
+                 <div class="modal-header">
+                   <a class="close" data-dismiss="modal">×</a>
+                   <h3>#{message}</h3>
+                 </div>
+                 <div class="modal-body">
+                   <p></p>
+                 </div>
+                 <div class="modal-footer">
+                   <a data-dismiss="modal" class="btn">#{I18n.t('admin_js.cancel')}</a>
+                 </div>
+               </div>
+               """
+  $modal_html = $(modal_html)
+  # Add the new button to the modal box
+  $modal_html.find('.modal-footer').append($link)
+  # Pop it up
+  $modal_html.modal()
+  $link.click (e) ->
+    e.preventDefault()
+    $(this).closest('.modal').modal('hide')
+    element.trigger('ajax:complete').trigger('confirm:success')
+  # Prevent the original link from working
+  return false

data/app/assets/javascripts/ab_admin/core/init.js.coffee

@@ -0,0 +1,54 @@
+#= require ab_admin/core/utils
+#= require ab_admin/core/ui_utils
+#= require ab_admin/core/pjax
+#= require ab_admin/core/confirmation
+#= require ab_admin/core/batch_actions
+#= require ab_admin/core/search_form
+#= require ab_admin/core/pagination
+#= require ab_admin/core/columns_hider
+
+$ ->
+  if $('#list')[0]
+    window.viewType = 'list'
+  else if $('form.simple_form')[0]
+    window.viewType = 'form'
+
+  $(document).on 'admin:init', (e) ->
+    return unless window.viewType == 'list'
+    clonePagination()
+    initPopover()
+    initTooltip()
+
+    $('#list tbody tr').dblclick (e) ->
+      e.preventDefault()
+      $el = $(this)
+      window.location.href = $el.find('td a.resource_id_link').prop('href')
+
+    $('.per_page').click ->
+      $.cookie('pp', $(this).data('val'))
+
+
+  $(document).on 'admin:init', (e) ->
+    return unless window.viewType == 'form'
+    window.resource_id = $('form.simple_form').data('id')
+    initEditor()
+    inputSetToggle()
+
+#    $('form .region_ac').regionAc()
+#    new NestedFieldsAdder
+#      region_ac: true
+#      callback: ->
+#        initPickers()
+#        initChosen()
+#        initEditor()
+
+
+  $(document).on 'pjax:end', ->
+    $(document).trigger({type: 'admin:init', pjax: true})
+  $(document).trigger({type: 'admin:init'})
+
+
+  initChosen()
+  #  initAcFileds()
+  if window.gon?.bg_color
+    $('body').css('background-color', "##{window.gon.bg_color.replace(/^#/, '')}")

data/app/assets/javascripts/ab_admin/core/pagination.js.coffee

@@ -0,0 +1,44 @@
+class window.Pagination
+  constructor: ->
+    @from_bottom = 250
+    @per_page = 8
+    @refreshSource()
+    @initHandlers()
+    @initLoad()
+
+  initHandlers: ->
+    $(document).on 'pjax:end', @refreshSource
+
+  initLoad: ->
+    $(window).trigger "scroll" if $(window).height() <= $(document).height()
+
+  refreshSource: =>
+    @cont = $('#content')
+    @url = window.location.href.replace(/page=\d+/, '')
+    @page = 1
+    @initScroll()
+
+  initScroll: ->
+    $(window).scroll @check
+
+  check: =>
+    @load() if @nearBottom()
+
+  nearBottom: ->
+    $(window).scrollTop() > $(document).height() - $(window).height() - @from_bottom
+
+  load: ->
+    @page++
+    $(window).unbind 'scroll', @check
+    $.ajax
+      type: 'GET'
+      url: @url
+      data:
+        page: @page
+      success: @render
+      dataType: 'script'
+      complete: (xhr) => @render(xhr.responseText)
+
+  render: (data) =>
+    @cont.append(data)
+    @initScroll() if $.trim(data)

data/app/assets/javascripts/ab_admin/core/pjax.js.coffee

@@ -0,0 +1,30 @@
+$ ->
+  $('.pjax, .pagination a, .pjax_links a').live 'click', (event) ->
+    if event.which > 1 || event.metaKey || event.ctrlKey
+      return
+    else if $.support.pjax
+      event.preventDefault()
+      $.pjax
+        container: $(this).data('pjax-container') || '[data-pjax-container]'
+        url: $(this).data('href') || $(this).attr('href')
+        timeout: 50000
+    else if $(this).data('href')
+      event.preventDefault()
+      window.location = $(this).data('href')
+
+  unless gon.test
+    $('.pjax-form').live 'submit', (event) ->
+      $el = $(this)
+      if $.support.pjax
+        event.preventDefault()
+        $.pjax
+          type: $el.attr('method')
+          container: $el.data('pjax-container') || '[data-pjax-container]'
+          url: this.action + (if (this.action.indexOf('?') != -1) then '&' else '?') + $el.serialize()
+          timeout: 50000
+
+  $(document)
+    .on 'pjax:start', ->
+      $('#loading').show()
+    .on 'pjax:end', ->
+      $('#loading').hide()

data/app/assets/javascripts/ab_admin/core/search_form.js.coffee

@@ -0,0 +1,15 @@
+$ ->
+  if $('#search_form')[0]
+    $('.predicate-select').change ->
+      $el = $(this)
+      $el.next('input').attr('name', "q[#{$el.val()}]")
+
+    $("#search_form").submit ->
+      $("#search_form [id$='_gteq']").val (i, v) ->
+        v + " 00:00" if v
+      $("#search_form [id$='_lteq']").val (i, v) ->
+        v + " 23:59" if v
+
+    $('#search_cancel').click (e) ->
+      e.preventDefault()
+      window.location.search = ""

data/app/assets/javascripts/ab_admin/core/ui_utils.js.coffee

@@ -0,0 +1,62 @@
+window.initGeoInput = (prefix, autocomplete = true) ->
+  opts =
+    prefix: prefix
+    doom_map: "#{prefix}_map"
+    callback: "#{prefix}_geo_callback"
+    map_options:
+      {scrollwheel: false}
+  gmaps = new GeoInput("#{prefix}_lat", "#{prefix}_lon", "#{prefix}_zoom", opts)
+  gmaps.initAutocomplete("#{prefix}_geo_autocomplete") if autocomplete
+
+window.clonePagination = ->
+  $('.pagination:first').clone().appendTo($('.batch_actions'))
+
+window.initPopover = ->
+  $('.popover').hide()
+  $('a[rel=popover]').popover({trigger: 'hover'})
+
+window.initChosen = ->
+  return if gon.test
+  chosen_options =
+    allow_single_deselect: true
+    no_results_text: I18n.t('admin_js.no_results')
+    placeholder_text_single: ' '
+    placeholder_text_multiple: ' '
+  $('form .do_chosen, .without_form.do_chosen, form .do_chosen_multi').chosen(chosen_options)
+
+window.initAcFileds = ->
+  for el in $('.ac_field')
+    $el = $(el)
+    params = $.extend({class: $el.data('class')}, $el.data('params') || {})
+    $(el).oautocomplete
+      serviceUrl: '/admin/autocomplete'
+      params: params
+      minChars: 2
+      maxHeight: 400
+      width: 220
+
+window.initTooltip = ->
+  $('.do_tooltip').tooltip
+    animation: false
+    placement: 'right'
+
+window.initEditor = ->
+  return if gon.test
+  $('form .do_wysihtml5').each ->
+    $el = $(this)
+    return if $el.hasClass('wysihtml5_done')
+    editor = $el.wysihtml5({html: true, locale: 'ru'}).data('wysihtml5').editor
+    resizeIframe = -> editor.composer.iframe.style.height = editor.composer.element.scrollHeight + "px"
+    editor.on "load", ->
+      if editor.composer
+        editor.composer.element.addEventListener "keyup", resizeIframe, false
+        editor.composer.element.addEventListener "blur", resizeIframe, false
+        editor.composer.element.addEventListener "focus", resizeIframe, false
+    $el.addClass('wysihtml5_done')
+
+window.inputSetToggle = ->
+  $('.label.do_toggle').click ->
+    $(this).siblings().toggle()
+
+window.flash = (type, message) ->
+  $('#wrap').prepend $("<div class='alert alert-#{type}'><a class='close' data-dismiss='alert'>×</a>#{message}</div>")

data/app/assets/javascripts/ab_admin/core/utils.js.coffee

@@ -0,0 +1,154 @@
+window.gon ||= {}
+I18n.locale = window.gon.locale || 'ru'
+window.locale_path = if I18n.locale == 'ru' then '' else "/#{I18n.locale}"
+
+# undescore
+_.sum = (obj) ->
+  return 0  if not $.isArray(obj) or obj.length is 0
+  _.reduce obj, (sum, n) ->
+    sum += n
+
+_.inGroups = (array, number, fill_with=null) ->
+  res = []
+  max_per = to_i(array.length / number)
+  over = to_i(array.length % number)
+  max_per += 1 if over > 0
+  start = 0
+  curr_per = max_per
+  _.times number, (i) ->
+    curr_per -= 1 if over > 0 && over == i
+    end = start + curr_per
+    res.push array.slice(start, end)
+    start = end
+  if fill_with
+    for group in res
+      while group.length != max_per
+        group.push fill_with
+  res
+
+_.inGroupsOf = (array, number, fill_with=null) ->
+  res = []
+  for el, i in array
+    res.push [] if i % number == 0
+    res.last().push el
+  if fill_with && res.last()?.length != number
+    while res.last().length != number
+      res.last().push fill_with
+  res
+
+# jquery
+$.fn.serializeJSON = ->
+  json = {}
+  jQuery.map $(this).serializeArray(), (n) ->
+    json[n["name"]] = n["value"]
+
+  json
+
+$.fn.unescape = ->
+  $(this).html $.unescape($(this).html())
+
+$.unescape = (html) ->
+  htmlNode = document.createElement("div")
+  htmlNode.innerHTML = html
+  return htmlNode.innerText  if htmlNode.innerText
+  htmlNode.textContent
+
+$.fn.emptySelect = ->
+  @each ->
+    @options.length = 0  if @tagName is "SELECT"
+
+$.fn.loadSelect = (optionsDataArray) ->
+  @emptySelect().each ->
+    if @tagName is "SELECT"
+      selectElement = this
+      $.each optionsDataArray, (index, optionData) ->
+        option = new Option(optionData.caption, optionData.value)
+        if $.browser.msie
+          selectElement.add option
+        else
+          selectElement.add option, null
+
+$.parseQuery = ->
+  window.location.search.replace("?", "").parseQuery()
+
+# core types
+String::parseQuery = ->
+  h = {}
+  qs = $.trim(this).match(/([^?#]*)(#.*)?$/)[0]
+  return {}  unless qs
+  pairs = qs.split("&")
+  $.each pairs, (i, v) ->
+    pair = v.split("=")
+    h[pair[0]] = pair[1]
+  h
+
+Array::last = ->
+  if @.length > 0
+    @[@.length - 1]
+
+Array::first = ->
+  @[0]
+
+Array::removeByIndex = (arrayIndex)->
+  @.splice(arrayIndex, 1)
+
+Array::valDetect = (v, prop = 'id') ->
+  res = null
+  for el in @
+    if el[prop] is v
+      res = el
+  res
+
+Array::includes = (obj) ->
+  for el, i in @
+    if el == obj
+      return i
+  return false
+
+Array::remove = ->
+  what = undefined
+  a = arguments
+  L = a.length
+  ax = undefined
+  while L and @length
+    what = a[--L]
+    until (ax = @indexOf(what)) is -1
+      @splice ax, 1
+      break;
+  this
+
+# global
+window.replaceURLWithHTMLLinks = (text) ->
+  exp = /(\b(https?|ftp|file):\/\/[-A-Z0-9+&@#\/%?=~_|!:,.;]*[-A-Z0-9+&@#\/%=~_|])/ig
+  text.replace(exp, "<a href='$1' target='_blank'>$1</a>")
+
+window.to_i = (val) ->
+  unless val
+    return 0
+  val = parseInt val, 10
+  if isNaN(val) then 0 else val
+
+window.to_f = (val) ->
+  unless val
+    return 0.0
+  val = parseFloat val, 10
+  if isNaN(val) then 0.0 else val
+
+window.log = (objects...) ->
+  window.logging = true
+  unless window.gon?.no_log
+    console.log '== debug ==='
+    objects = objects[0] if objects.length == 1
+    console.log objects
+  window.logging = false
+
+window.clone_obj = (obj) ->
+  if notobj? or typeof obj isnt 'object'
+    return obj
+
+  newInstance = new obj.constructor()
+
+  for key of obj
+    newInstance[key] = clone_obj obj[key]
+
+  return newInstance

data/app/assets/javascripts/ab_admin/inputs/datetime_input.js.coffee

@@ -0,0 +1,23 @@
+$ ->
+  window.setInputDateTime = (field) ->
+    date = $("##{field}_date").val()
+    time = $("##{field}_time").val()
+    $('#' + field).val("#{date} #{time}")
+
+  window.initPickers = ->
+    $('input.datepicker')
+      .datepicker({format: 'dd.mm.yyyy', language: 'ru', autoclose: true})
+      .on 'changeDate', (e) ->
+        setInputDateTime($(e.target).data('target'))
+      .on 'show', (e) ->
+        if ($(document).width() - $(e.target).offset().left) < 200
+          $('.datepicker.dropdown-menu:visible').css({left: "#{$(document).width() - 255}px"}).addClass('right_picker')
+          
+    $('input.timepicker').timepicker({showMeridian: false}).bind 'hidden', (e) ->
+      setInputDateTime($(e.target).data('target'))
+
+  initPickers()
+
+  $('.simple_form').bind "nested:fieldAdded", =>
+    initPickers()
+    initChosen()

data/app/assets/javascripts/i18n/translations.js

@@ -0,0 +1 @@
+console.log('Run `rake i18n:js:export` to export your locales');

data/app/assets/stylesheets/ab_admin/application.css.scss

@@ -0,0 +1,9 @@
+//= require ab_admin/bootstrap-datepicker
+//= require ab_admin/bootstrap-timepicker
+//= require bootstrap-wysihtml5
+//= require ab_admin/chosen
+//= require ab_admin/bootstrap_and_overrides
+//= require ab_admin/fileupload
+
+//q= require jquery.fancybox
+//q= require token_input/token-input-facebook