vmtk 1.5.0__tar.gz

vmtk-1.5.0/CMake/CMakeLists.txt

@@ -0,0 +1,27 @@
+set(vtkAddon_version "cf1126568415179fb5b1c16121087bd2494e2e0e")
+
+set(vtkMacroKitPythonWrap.cmake_expected_hash "82abf4ea2c6f153c61dd47bf6f3baf924d0f54dd11fd92a09cb5dc0f82a85e48")
+set(vtkWrapHierarchy.cmake_expected_hash "c9343c54675e8bbde8ceaedf99a3226546b5f7d4cf7d5dac3e33db9093b536f2")
+set(vtkWrapPython.cmake_expected_hash "ac22023ff10c58da33c2a6633fc90fde9863f12bb0f90dd0da51e18796137db3")
+set(vtkWrapperInit.data.in_expected_hash "3e840679603eb4a0d425c1244828729cb271f33a081c5ac2e0547aa747bbec5d")
+
+foreach(filename IN ITEMS
+  vtkMacroKitPythonWrap.cmake
+  vtkWrapHierarchy.cmake
+  vtkWrapPython.cmake
+  vtkWrapperInit.data.in
+  )
+  set(dest_file "${CMAKE_CURRENT_BINARY_DIR}/${filename}")
+  set(expected_hash "${${filename}_expected_hash}")
+  set(url "https://raw.githubusercontent.com/Slicer/vtkAddon/${vtkAddon_version}/CMake/${filename}")
+  if(NOT EXISTS ${dest_file})
+    file(DOWNLOAD ${url} ${dest_file} EXPECTED_HASH SHA256=${expected_hash})
+  else()
+    file(SHA256 ${dest_file} current_hash)
+    if(NOT ${current_hash} STREQUAL ${expected_hash})
+      file(DOWNLOAD ${url} ${dest_file} EXPECTED_HASH SHA256=${expected_hash})
+    endif()
+  endif()
+endforeach()
+
+set(vtkAddon_CMAKE_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH "Path to vtkAddon CMake directory")

vmtk-1.5.0/CMake/CMakeOptions.cmake

@@ -0,0 +1,135 @@
+#
+# Configure output paths for libraries and executables.
+#
+set(LIBRARY_OUTPUT_PATH ${VTK_VMTK_BINARY_DIR}/bin CACHE PATH
+    "Single output directory for building all libraries.")
+set(EXECUTABLE_OUTPUT_PATH ${VTK_VMTK_BINARY_DIR}/bin CACHE PATH
+    "Single output directory for building all executables.")
+mark_as_advanced(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
+
+#
+# Try to find VTK and include its settings (otherwise complain)
+#
+if ( NOT VTK_FOUND )
+  find_package(VTK REQUIRED)
+  include(${VTK_USE_FILE})
+endif ()
+
+#
+# Try to find ITK and include its settings (otherwise complain)
+#
+if ( NOT ITK_FOUND )
+  find_package(ITK REQUIRED)
+  include(${ITK_USE_FILE})
+endif ()
+
+#
+# Build shared libs ?
+#
+# Defaults to the same VTK setting.
+#
+
+# Standard CMake option for building libraries shared or static by default.
+option(BUILD_SHARED_LIBS
+       "Build with shared libraries."
+       ${VTK_BUILD_SHARED_LIBS})
+# Copy the CMake option to a setting with VTK_VMTK_ prefix for use in
+# our project.  This name is used in vtkvmtkConfigure.h.in.
+set(VTK_VMTK_BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS})
+
+# If this is a build tree, provide an option for putting
+# this project's executables and libraries in with VTK's.
+if (EXISTS ${VTK_DIR}/bin)
+  option(USE_VTK_OUTPUT_PATHS
+         "Use VTK's output directory for this project's executables and libraries."
+         OFF)
+  mark_as_advanced (USE_VTK_OUTPUT_PATHS)
+  if (USE_VTK_OUTPUT_PATHS)
+    set (LIBRARY_OUTPUT_PATH ${VTK_DIR}/bin)
+    set (EXECUTABLE_OUTPUT_PATH ${VTK_DIR}/bin)
+  endif ()
+endif ()
+
+
+#
+# Wrap Tcl, Java, Python
+#
+# Rational: even if your VTK was wrapped, it does not mean that you want to
+# wrap your own local classes.
+# Default value is OFF as the VTK cache might have set them to ON but
+# the wrappers might not be present (or yet not found).
+#
+
+#
+# Python
+#
+
+if (VTK_WRAP_PYTHON)
+
+  option(VTK_VMTK_WRAP_PYTHON
+         "Wrap classes into the Python interpreted language."
+         ON)
+
+  if (VTK_VMTK_WRAP_PYTHON)
+    set(VTK_WRAP_PYTHON3_INIT_DIR "${VTK_VMTK_SOURCE_DIR}/Wrapping")
+    #include(${VTK_CMAKE_DIR}/vtkWrapPython.cmake)
+    if (WIN32)
+      if (NOT BUILD_SHARED_LIBS)
+        message(FATAL_ERROR "Python support requires BUILD_SHARED_LIBS to be ON.")
+        set (VTK_VMTK_CAN_BUILD 0)
+      endif ()
+    endif ()
+  endif ()
+
+else ()
+
+  if (VTK_VMTK_WRAP_PYTHON)
+    message("Warning. VTK_VMTK_WRAP_PYTHON is ON but the VTK version you have "
+            "chosen has not support for Python (VTK_WRAP_PYTHON is OFF).  "
+            "Please set VTK_VMTK_WRAP_PYTHON to OFF.")
+    set (VTK_VMTK_WRAP_PYTHON OFF)
+  endif ()
+
+endif ()
+
+#
+# Java
+#
+
+if (VTK_WRAP_JAVA)
+
+  option(VTK_VMTK_WRAP_JAVA
+         "Wrap classes into the Java interpreted language."
+         ON)
+
+  if (VTK_VMTK_WRAP_JAVA)
+    if (VMTK_USE_VTK9)
+      message(FATAL_ERROR "Java wrapping of classes is not supported with VTK 9")
+    endif ()
+    set(VTK_WRAP_JAVA3_INIT_DIR "${VTK_VMTK_SOURCE_DIR}/Wrapping")
+    include(${VTK_CMAKE_DIR}/vtkWrapJava.cmake)
+    if (WIN32)
+      if (NOT BUILD_SHARED_LIBS)
+        message(FATAL_ERROR "Java support requires BUILD_SHARED_LIBS to be ON.")
+        set (VTK_VMTK_CAN_BUILD 0)
+      endif ()
+    endif ()
+
+    # Tell the java wrappers where to go.
+    set(VTK_JAVA_HOME ${VTK_VMTK_BINARY_DIR}/java/vtkvmtk)
+    make_directory(${VTK_JAVA_HOME})
+  endif ()
+
+else ()
+
+  if (VTK_VMTK_WRAP_JAVA)
+    message("Warning. VTK_VMTK_WRAP_JAVA is ON but the VTK version you have "
+            "chosen has not support for Java (VTK_WRAP_JAVA is OFF).  "
+            "Please set VTK_VMTK_WRAP_JAVA to OFF.")
+    set (VTK_VMTK_WRAP_JAVA OFF)
+  endif ()
+
+endif ()
+
+# setup our local hints file in case wrappers need them.
+set(VTK_WRAP_HINTS ${VTK_VMTK_SOURCE_DIR}/Wrapping/hints)

vmtk-1.5.0/CMake/VMTKConfig.cmake.in

@@ -0,0 +1,32 @@
+# Tell the user project where to find headers and libraries
+set(VMTK_CPP_SOURCE_DIRS "@VMTK_SOURCE_DIR@/vtkVmtk")
+
+set(VMTK_INCLUDE_DIRS
+  ${VMTK_CPP_SOURCE_DIRS}
+  ${VMTK_CPP_SOURCE_DIRS}/Common
+  ${VMTK_CPP_SOURCE_DIRS}/ComputationalGeometry
+  ${VMTK_CPP_SOURCE_DIRS}/Contrib
+  ${VMTK_CPP_SOURCE_DIRS}/DifferentialGeometry
+  ${VMTK_CPP_SOURCE_DIRS}/IO
+  ${VMTK_CPP_SOURCE_DIRS}/Misc
+  ${VMTK_CPP_SOURCE_DIRS}/Segmentation
+  "@VMTK_BINARY_DIR@"
+  "@VMTK_BINARY_DIR@/vtkVmtk"
+)
+
+set(VMTK_BUILD_SETTINGS_FILE
+  "@VMTK_BINARY_DIR@/VMTKBuildSettings.cmake"
+)
+
+include(
+  "@VMTK_BINARY_DIR@/VMTK-Targets.cmake"
+)
+
+set(VMTK_LIBRARY_DIRS "@VMTK_BINARY_DIR@/bin")
+
+# VMTK VTK wrap hierarchy files
+@VMTK_WRAP_HIERARCHY_FILES_CONFIG@
+
+set(VMTK_USE_FILE
+  "@VMTK_BINARY_DIR@/VMTKUse.cmake"
+)

vmtk-1.5.0/CMake/VMTKUse.cmake.in

@@ -0,0 +1,9 @@
+include(CMakeImportBuildSettings)
+
+cmake_import_build_settings("${VMTK_BUILD_SETTINGS_FILE}")
+
+include_directories(${VMTK_INCLUDE_DIRS})
+
+link_directories(${VMTK_LIBRARY_DIRS})
+
+link_libraries(vtkvmtkCommon vtkvmtkComputationalGeometry vtkvmtkContrib vtkvmtkDifferentialGeometry vtkvmtkIO vtkvmtkITK vtkvmtkMisc vtkvmtkSegmentation nl tet)

vmtk-1.5.0/CMake/vmtkFunctions.cmake

@@ -0,0 +1,103 @@
+include(CMakeParseArguments)
+
+set(Slicer_VTK_WRAP_HIERARCHY_DIR ${VMTK_BINARY_DIR})
+set(Slicer_VTK_WRAP_MODULE_INSTALL_COMPONENT_IDENTIFIER "PythonRuntimeLibraries")
+set(Slicer_VTK_WRAP_HIERARCHY_TARGETS_PROPERTY_NAME "VMTK_WRAP_HIERARCHY_TARGETS")
+
+include(vtkMacroKitPythonWrap)
+
+function(vmtk_build_library)
+  set(options)
+  set(oneValueArgs NAME)
+  set(multiValueArgs SRCS TARGET_LINK_LIBRARIES INCLUDE_DIRECTORIES)
+  cmake_parse_arguments(VMTK_LIB "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  set(expected_defined_vars NAME SRCS)
+  
+  foreach(var ${expected_defined_vars})
+    if(NOT DEFINED VMTK_LIB_${var})
+      message(FATAL_ERROR "error: ${var} parameter is mandatory !")
+    endif()
+  endforeach()
+
+  if(VMTK_LIB_INCLUDE_DIRECTORIES)
+    include_directories(${VMTK_LIB_INCLUDE_DIRECTORIES})
+  endif()
+
+  set(lib_name ${VMTK_LIB_NAME})
+
+  if(NOT VMTK_LIB_NAME MATCHES "^vtkvmtk")
+    set(lib_name vtkvmtk${VMTK_LIB_NAME})
+  endif()
+
+  add_library(${lib_name} ${VMTK_LIB_SRCS})
+
+  if(VMTK_LIBRARY_PROPERTIES)
+    set_target_properties(${lib_name} PROPERTIES ${VMTK_LIBRARY_PROPERTIES})
+  endif()
+
+  set_target_properties(${lib_name} PROPERTIES LINKER_LANGUAGE CXX)
+  if (APPLE)
+    set_target_properties( ${lib_name} PROPERTIES LINK_FLAGS "-undefined dynamic_lookup" )
+  endif ()
+
+  if(NOT WIN32)
+    set_target_properties(${lib_name} PROPERTIES COMPILE_FLAGS -fPIC)
+  endif()
+
+  if(VMTK_LIB_TARGET_LINK_LIBRARIES)
+    if (APPLE)
+      set(vmtk_target_link_libs )
+      foreach(lib IN LISTS VMTK_LIB_TARGET_LINK_LIBRARIES)
+        if(NOT lib MATCHES "python")
+          list(APPEND vmtk_target_link_libs ${lib})
+        endif()
+      endforeach()
+      target_link_libraries(${lib_name} ${vmtk_target_link_libs})
+    else ()
+      target_link_libraries(${lib_name} ${VMTK_LIB_TARGET_LINK_LIBRARIES})
+    endif ()
+  endif()
+
+  install(TARGETS ${lib_name}
+    EXPORT VMTK-Targets
+    LIBRARY DESTINATION ${VTK_VMTK_INSTALL_LIB_DIR} COMPONENT RuntimeLibraries
+    ARCHIVE DESTINATION ${VTK_VMTK_INSTALL_LIB_DIR} COMPONENT Development ${VMTK_WHEEL_EXCLUDE_FROM_ALL}
+    RUNTIME DESTINATION ${VTK_VMTK_INSTALL_BIN_DIR} COMPONENT RuntimeExecutables
+  )
+
+  # Development files are not shipped in the Python wheel.
+  if(NOT VMTK_WHEEL_BUILD)
+    file(GLOB files "${CMAKE_CURRENT_SOURCE_DIR}/*.h")
+    install(FILES ${files}
+      DESTINATION ${VTK_VMTK_INSTALL_INCLUDE_DIR}
+      COMPONENT Development)
+    install(FILES ${VTK_VMTK_SEGMENTATION_ITK_HEADERS}
+      DESTINATION ${VTK_VMTK_INSTALL_INCLUDE_DIR}
+      COMPONENT Development)
+  endif()
+
+  if (VTK_WRAP_PYTHON AND VTK_VMTK_WRAP_PYTHON)
+
+    set(vmtk_wrapped_libs )
+    foreach(lib IN LISTS VMTK_LIB_TARGET_LINK_LIBRARIES)
+      if(lib MATCHES "^vtkvmtk" AND TARGET ${lib}PythonD)
+        list(APPEND vmtk_wrapped_libs ${lib})
+      endif()
+    endforeach()
+
+    if(NOT DEFINED VTK_VMTK_WRAPPED_MODULE_INSTALL_LIB_DIR)
+      set(VTK_VMTK_WRAPPED_MODULE_INSTALL_LIB_DIR ${VTK_VMTK_MODULE_INSTALL_LIB_DIR})
+    endif()
+
+    vtkMacroKitPythonWrap(
+      KIT_NAME ${lib_name}
+      KIT_SRCS ${VMTK_LIB_SRCS}
+      KIT_PYTHON_LIBRARIES ${vmtk_wrapped_libs}
+      KIT_INSTALL_BIN_DIR ${VTK_VMTK_INSTALL_BIN_DIR}
+      KIT_INSTALL_LIB_DIR ${VTK_VMTK_INSTALL_LIB_DIR}
+      KIT_MODULE_INSTALL_LIB_DIR ${VTK_VMTK_WRAPPED_MODULE_INSTALL_LIB_DIR}
+      )
+  endif ()
+
+endfunction()