vapoursynth-ares 0.4.0__tar.gz

vapoursynth_ares-0.4.0/CMakeLists.txt

@@ -0,0 +1,40 @@
+cmake_minimum_required(VERSION 3.18)
+project(Ares_Package)
+
+# === C++ Standard & Options ===
+set(CMAKE_POSITION_INDEPENDENT_CODE ON)
+
+if(SKBUILD_PROJECT_VERSION)
+  set(VCS_TAG "v${SKBUILD_PROJECT_VERSION}" CACHE STRING "Version from scikit-build-core")
+endif()
+
+# === Dependencies ===
+set(SUBMODULE_SRC_DIR "${CMAKE_CURRENT_SOURCE_DIR}/ares")
+file(READ "${SUBMODULE_SRC_DIR}/CMakeLists.txt" SUBMODULE_CMAKE_CONTENT)
+
+string(REPLACE "\${CMAKE_SOURCE_DIR}" "\${SUBMODULE_SRC_DIR}" MODIFIED_CMAKE_CONTENT "${SUBMODULE_CMAKE_CONTENT}")
+string(REPLACE "\${CMAKE_CURRENT_LIST_DIR}" "\${SUBMODULE_SRC_DIR}" MODIFIED_CMAKE_CONTENT "${MODIFIED_CMAKE_CONTENT}")
+
+file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/ares_generated/CMakeLists.txt" "${MODIFIED_CMAKE_CONTENT}")
+
+set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
+
+# === Target Definition & Configuration ===
+add_subdirectory("${CMAKE_CURRENT_BINARY_DIR}/ares_generated" "${CMAKE_CURRENT_BINARY_DIR}/ares_build" EXCLUDE_FROM_ALL)
+
+# The upstream CMakeLists adds -static for all non-Windows GCC/Clang builds
+# (including inside generator expressions), which is incompatible with building
+# a shared object (.so). Strip "-static" from the raw property string.
+if(NOT WIN32)
+  get_target_property(_ares_link_opts AudioResample LINK_OPTIONS)
+  if(_ares_link_opts)
+    string(REPLACE ";-static;" ";" _ares_link_opts "${_ares_link_opts}")
+    string(REGEX REPLACE "-static[ \t]+" "" _ares_link_opts "${_ares_link_opts}")
+    set_target_properties(AudioResample PROPERTIES LINK_OPTIONS "${_ares_link_opts}")
+  endif()
+endif()
+
+add_custom_target(build_ares ALL DEPENDS AudioResample)
+
+# === Packaging & Installation ===
+install(TARGETS AudioResample RUNTIME DESTINATION . LIBRARY DESTINATION .)

vapoursynth_ares-0.4.0/PKG-INFO

@@ -0,0 +1,188 @@
+Metadata-Version: 2.4
+Name: vapoursynth-ares
+Version: 0.4.0
+Summary: Audio sample rate and sample type converter for VapourSynth utilizing the SoX Resampler library
+Author: ropagr
+Maintainer-Email: =?utf-8?b?VmFyZMOr?= <ichunjo.le.terrible@gmail.com>
+License-Expression: MIT
+License-File: ares/LICENSE
+Project-URL: Source Code, https://github.com/ropagr/VS-AudioResample
+Project-URL: Bug Tracker, https://github.com/ropagr/VS-AudioResample/issues
+Project-URL: Repository, https://github.com/Jaded-Encoding-Thaumaturgy/vs-wheels
+Requires-Python: >=3.12
+Requires-Dist: vapoursynth>=75
+Description-Content-Type: text/markdown
+
+# VapourSynth Ares
+
+This package contains the [VS-AudioResample](https://github.com/ropagr/VS-AudioResample) VapourSynth plugin.
+
+## Installation
+
+```bash
+pip install vapoursynth-ares
+```
+
+## Building from source
+
+```powershell
+uv build --package vapoursynth-ares
+```
+
+---
+
+Detailed parameter information from the parent project follows.
+
+---
+# VS-AudioResample
+This is an audio sample rate and sample type converter for VapourSynth utilizing the [SoX Resampler](https://sourceforge.net/projects/soxr/) library.
+
+## Usage
+```python
+ares.Resample(clip: vs.AudioNode,
+              sample_rate: int = -1,
+              sample_type: str = None,
+              quality: str = 'very_high',
+              overflow: str = 'error',
+              overflow_log: str = 'once'
+              ) -> vs.AudioNode
+```
+
+*clip* - input audio clip (any format)
+
+*sample_rate* - new sample rate (e.g. 16000, 44100, 48000, ...); same as input clip if negative; default: -1
+
+*sample_type* - new sample type; same as input clip if None; default: None
+```text
+    'i16' - integer 16-bit
+    'i24' - integer 24-bit
+    'i32' - integer 32-bit
+    'f32' - float   32-bit
+```
+
+*quality* - resample quality; default: 'very_high'
+```text
+    'quick'     - quick cubic interpolation
+    'low'       - low quality
+    'medium'    - medium quality
+    'high'      - high quality
+    'very_high' - very high quality (default)
+    'max'       - maximum quality
+```
+
+*overflow* - sample overflow handling; default: 'error'
+```text
+    'error'      - raise an error (default)
+    'clip'       - clip overflowing samples (all types)
+    'clip_int'   - clip overflowing samples for integer output sample types
+                   keep overflowing samples for float output sample types
+    'keep_float' - keep overflowing samples for float output sample types
+                   raise an error if output sample type is not float
+```
+
+To properly handle overflows the clip should be converted to a float sample type ('f32'), if not already.
+
+⚠️ Overflowing samples of integer sample types (output) are always clipped (disruptive), or they raise an error
+
+Use `overflow='keep_float'` for float output sample types to leave overflowing samples unchanged.  
+Then call a scaling function like `std.AudioGain` that scales the peak sample value below or to equal 1.0 (see [Example 3](#example-3))
+
+
+*overflow_log* - sample overflow logging; default: 'once'
+```text
+    'all'  - log all sample overflows (not recommended, this can be a lot)
+    'once' - log only the first sample overflow (default)
+    'none' - do not log any sample overflows
+```
+
+**Note**: a summary of all overflowing samples will be logged at the end of each function (if any)
+
+### Example 1
+
+basic usage
+```python
+import vapoursynth as vs
+
+# load audio
+audio = ...
+
+# convert sample rate to 48000 and sample type to 24-bit integer
+audio = vs.core.ares.Resample(audio, sample_rate=48000, sample_type='i24')
+```
+
+### Example 2
+
+change speed of an audio clip (but keep the sample rate)
+```python
+import vapoursynth as vs
+
+# load audio
+audio = ...
+
+# speedup factor
+factor = 2.0
+
+resample_rate = round(audio.sample_rate / factor)
+res_audio = vs.core.ares.Resample(audio, sample_rate=resample_rate)
+audio = vs.core.std.AssumeSampleRate(res_audio, samplerate=audio.sample_rate)
+```
+
+
+### Example 3
+
+handle overflowing samples
+```python
+import vapoursynth as vs
+
+# load audio (integer or float sample type)
+audio = ...
+
+# convert sample rate to 48000 and sample type to 32-bit float
+# leave possible overflowing samples unchanged with 'keep_float'
+audio = vs.core.ares.Resample(audio, sample_rate=48000, sample_type='f32', overflow='keep_float')
+
+# scale audio samples
+# choose a factor that limits the peak value below or to equal 1
+audio = vs.core.std.AudioGain(audio, 0.5)
+
+# optional: convert sample type back to integer if needed (e.g. 24-bit)
+audio = vs.core.ares.Resample(audio, sample_type='i24')
+```
+
+## Dependencies
+This project uses the [SoX Resampler](https://sourceforge.net/projects/soxr/) library (`soxr`), which is licensed under the [GNU Lesser General Public License (LGPL) v2.1](https://www.gnu.org/licenses/old-licenses/lgpl-2.1.html).
+
+The distributed binaries of this plugin statically link to `soxr` for performance and ease of use. If you prefer to use a customized version of `soxr`, or to link dynamically instead, you can build the plugin from source. See the [Build from source](#build-from-source) section for instructions.
+
+
+## Build from source
+To build the plugin, you’ll need CMake and a C++20-compatible compiler. OpenMP support is optional.
+
+Run CMake to configure your preferred build system, then build the project. This process will automatically download and build the `soxr` dependency along with the plugin.
+
+**Note:** You don’t need to download or build `soxr` yourself. However, if you prefer to use a local or customized version of `soxr`, you can provide its source path during configuration (see options below).
+
+e.g. CMake with Ninja:
+```sh
+# EITHER build with statically linked soxr
+cmake -G Ninja -B ./build-ninja -DBUILD_SHARED_LIBS=OFF -DCMAKE_BUILD_TYPE=Release
+
+# OR build with dynamically linked soxr
+cmake -G Ninja -B ./build-ninja -DBUILD_SHARED_LIBS=ON -DCMAKE_BUILD_TYPE=Release
+
+ninja -C ./build-ninja
+```
+
+Custom options for cmake:
+```text
+-DSOXR_SOURCE_DIR=<PATH>     Use a custom soxr source directory
+                             (must contain CMakeLists.txt)
+-DSOXR_USE_PATCHES=<ON|OFF>  Enable patches needed for outdated 
+                             soxr build scripts (default: ON)
+-DWITH_OPENMP=<ON|OFF>       Enable or disable OpenMP support (default: ON)
+```
+
+
+## License
+
+This project is licensed under the MIT License.

vapoursynth_ares-0.4.0/README.md

@@ -0,0 +1,21 @@
+# VapourSynth Ares
+
+This package contains the [VS-AudioResample](https://github.com/ropagr/VS-AudioResample) VapourSynth plugin.
+
+## Installation
+
+```bash
+pip install vapoursynth-ares
+```
+
+## Building from source
+
+```powershell
+uv build --package vapoursynth-ares
+```
+
+---
+
+Detailed parameter information from the parent project follows.
+
+---

vapoursynth_ares-0.4.0/ares/.gitattributes

@@ -0,0 +1 @@
+* text=auto

vapoursynth_ares-0.4.0/ares/.gitignore

@@ -0,0 +1,32 @@
+# Prerequisites
+*.d
+
+# Compiled Object files
+*.slo
+*.lo
+*.o
+*.obj
+
+# Precompiled Headers
+*.gch
+*.pch
+
+# Compiled Dynamic libraries
+*.so
+*.dylib
+*.dll
+
+# Fortran module files
+*.mod
+*.smod
+
+# Compiled Static libraries
+*.lai
+*.la
+*.a
+*.lib
+
+# Executables
+*.exe
+*.out
+*.app

vapoursynth_ares-0.4.0/ares/CMakeLists.txt

@@ -0,0 +1,174 @@
+cmake_minimum_required(VERSION 3.18)
+
+project(
+    VS-AudioResample
+    DESCRIPTION "audio sample rate and sample type converter for VapourSynth"
+    VERSION 0.4.0
+    LANGUAGES C CXX
+)
+
+# original soxr repository on sourceforge
+# set(SOXR_GIT "https://git.code.sf.net/p/soxr/code")
+
+# mirror on github (faster)
+set(SOXR_GIT "https://github.com/chirlu/soxr.git")
+
+# use commit from February 24, 2018
+# commit id is the same for the sourceforge and github repository
+set(SOXR_COMMIT "945b592b70470e29f917f4de89b4281fbbd540c0")
+
+
+# Include modules
+include(FetchContent)
+
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
+include(Clang)
+include(fetch)
+include(soxr)
+
+Clang_GetStyle_CXX(IS_CLANG_GCC IS_CLANG_MSVC)
+
+
+# Custom options
+set(SOXR_SOURCE_DIR "" CACHE PATH "Path to a custom soxr source directory")
+
+option(SOXR_USE_PATCHES "Apply patches to soxr for compatibility" ON)
+
+# OpenMP support
+
+if (DEFINED WITH_OPENMP)
+    set(WITH_OPENMP_SET_BY_USER ON)
+else()
+    set(WITH_OPENMP_SET_BY_USER OFF)
+endif()
+
+
+option(WITH_OPENMP "Enable OpenMP support" ON)
+
+
+if (WITH_OPENMP)
+    if (WITH_OPENMP_SET_BY_USER)
+        find_package(OpenMP)
+        if (NOT OpenMP_C_FOUND)
+            message(FATAL_ERROR "OpenMP requested, but not found.")
+        endif()
+    else()
+        find_package(OpenMP)
+        if (NOT OpenMP_C_FOUND)
+            message(WARNING "OpenMP enabled by default, but not found. Proceeding without it.")
+            set(WITH_OPENMP OFF)
+        endif()
+    endif()
+endif()
+
+
+# Prepare soxr source directory
+
+if (SOXR_SOURCE_DIR)
+    if (NOT EXISTS "${SOXR_SOURCE_DIR}/CMakeLists.txt")
+        message(FATAL_ERROR "Error: Specified soxr source directory does not contain CMakeLists.txt")
+    endif()
+
+    message(STATUS "Using custom soxr from ${SOXR_SOURCE_DIR}")
+    set(SOXR_BINARY_DIR "${CMAKE_BINARY_DIR}/soxr-build")
+else()
+    fetch_FromGit("${SOXR_GIT}" "${SOXR_COMMIT}" SOXR_SOURCE_DIR SOXR_BINARY_DIR)
+endif()
+
+
+# Add soxr source directory to the project
+
+# disable soxr tests and libsamplerate bindings
+set(BUILD_TESTS OFF CACHE INTERNAL "Disable tests")
+set(WITH_LSR_BINDINGS OFF CACHE INTERNAL "Disable LSR bindings")
+
+if (${SOXR_USE_PATCHES})
+    soxr_AddPatched("${SOXR_SOURCE_DIR}" "${SOXR_BINARY_DIR}")
+else()
+    add_subdirectory("${SOXR_SOURCE_DIR}" "${SOXR_BINARY_DIR}")
+endif()
+
+
+add_library(AudioResample SHARED
+    "${CMAKE_SOURCE_DIR}/src/plugin.cpp"
+    "${CMAKE_SOURCE_DIR}/src/resample.cpp"
+    "${CMAKE_SOURCE_DIR}/src/resample.hpp"
+    "${CMAKE_SOURCE_DIR}/src/common/overflow.cpp"
+    "${CMAKE_SOURCE_DIR}/src/common/overflow.hpp"
+    "${CMAKE_SOURCE_DIR}/src/common/resquality.cpp"
+    "${CMAKE_SOURCE_DIR}/src/common/resquality.hpp"
+    "${CMAKE_SOURCE_DIR}/src/common/sampletype.cpp"
+    "${CMAKE_SOURCE_DIR}/src/common/sampletype.hpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/array.hpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/debug.hpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/map.hpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/number.hpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/sample.hpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/string.cpp"
+    "${CMAKE_SOURCE_DIR}/src/utils/string.hpp"
+    "${CMAKE_SOURCE_DIR}/src/vsmap/vsmap.cpp"
+    "${CMAKE_SOURCE_DIR}/src/vsmap/vsmap.hpp"
+    "${CMAKE_SOURCE_DIR}/src/vsmap/vsmap_common.cpp"
+    "${CMAKE_SOURCE_DIR}/src/vsmap/vsmap_common.hpp"
+    "${CMAKE_SOURCE_DIR}/src/vsutils/audio.cpp"
+    "${CMAKE_SOURCE_DIR}/src/vsutils/audio.hpp"
+    "${CMAKE_SOURCE_DIR}/src/vsutils/bitshift.hpp"
+)
+
+target_include_directories(AudioResample
+    PRIVATE
+    "${CMAKE_SOURCE_DIR}/include/vapoursynth"
+    "${CMAKE_SOURCE_DIR}/src"
+)
+
+target_compile_features(AudioResample PRIVATE cxx_std_20)
+
+target_link_libraries(AudioResample PRIVATE soxr)
+
+
+# Linker options for OpenMP support
+if (WITH_OPENMP)
+    if ((CMAKE_SYSTEM_NAME STREQUAL "Windows") AND ((CMAKE_CXX_COMPILER_ID STREQUAL "GNU") OR ${IS_CLANG_GCC}) AND NOT ${BUILD_SHARED_LIBS})
+        # Windows + GCC/Clang(GCC) + static
+        # use -fopenmp as linker argument to let the linker find a static library
+        # because apparently "target_link_libraries(AudioResample PRIVATE OpenMP::OpenMP_CXX)" prefers a dynamically linked library
+        target_link_options(AudioResample PRIVATE -static -fopenmp)
+    else()
+        target_link_libraries(AudioResample PRIVATE OpenMP::OpenMP_C)
+    endif()
+endif()
+
+
+target_compile_options(AudioResample
+    PRIVATE
+    # Debug + CXX + GCC/Clang(GCC)
+    $<$<AND:$<CONFIG:Debug>,$<COMPILE_LANGUAGE:CXX>,$<OR:$<CXX_COMPILER_ID:GNU>,$<BOOL:${IS_CLANG_GCC}>>>:
+        -Wall -Wextra -Wpedantic -Wno-unused-parameter -Wno-unused-variable>
+
+    # Release + CXX + GCC/Clang(GCC)
+    $<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:CXX>,$<OR:$<CXX_COMPILER_ID:GNU>,$<BOOL:${IS_CLANG_GCC}>>>:
+        -O2 -Wall -Wextra -Wpedantic -Wno-unused-parameter -Wno-unused-variable>
+
+    # Debug + CXX + MSVC/Clang(MSVC)
+    $<$<AND:$<CONFIG:Debug>,$<COMPILE_LANGUAGE:CXX>,$<OR:$<CXX_COMPILER_ID:MSVC>,$<BOOL:${IS_CLANG_MSVC}>>>:
+        /W4 /wd4100 /wd4702 /Zc:__cplusplus>
+
+    # Release + CXX + MSVC/Clang(MSVC)
+    $<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:CXX>,$<OR:$<CXX_COMPILER_ID:MSVC>,$<BOOL:${IS_CLANG_MSVC}>>>:
+        /W4 /wd4100 /wd4702 /Zc:__cplusplus>
+)
+
+
+target_link_options(AudioResample
+    PRIVATE
+    # Windows + CXX + GCC/Clang(GCC)
+    $<$<AND:$<PLATFORM_ID:Windows>,$<LINK_LANGUAGE:CXX>,$<OR:$<CXX_COMPILER_ID:GNU>,$<BOOL:${IS_CLANG_GCC}>>>:
+        -static -static-libstdc++ -s>
+
+    # Non-Windows + CXX + GCC/Clang(GCC)
+    $<$<AND:$<NOT:$<PLATFORM_ID:Windows>>,$<LINK_LANGUAGE:CXX>,$<OR:$<CXX_COMPILER_ID:GNU>,$<BOOL:${IS_CLANG_GCC}>>>:
+        -static -s>
+)
+
+
+set_target_properties(AudioResample PROPERTIES PREFIX "")

vapoursynth_ares-0.4.0/ares/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2025 ropagr
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

vapoursynth_ares-0.4.0/ares/README.md

@@ -0,0 +1,152 @@
+# VS-AudioResample
+This is an audio sample rate and sample type converter for VapourSynth utilizing the [SoX Resampler](https://sourceforge.net/projects/soxr/) library.
+
+## Usage
+```python
+ares.Resample(clip: vs.AudioNode,
+              sample_rate: int = -1,
+              sample_type: str = None,
+              quality: str = 'very_high',
+              overflow: str = 'error',
+              overflow_log: str = 'once'
+              ) -> vs.AudioNode
+```
+
+*clip* - input audio clip (any format)
+
+*sample_rate* - new sample rate (e.g. 16000, 44100, 48000, ...); same as input clip if negative; default: -1
+
+*sample_type* - new sample type; same as input clip if None; default: None
+```text
+    'i16' - integer 16-bit
+    'i24' - integer 24-bit
+    'i32' - integer 32-bit
+    'f32' - float   32-bit
+```
+
+*quality* - resample quality; default: 'very_high'
+```text
+    'quick'     - quick cubic interpolation
+    'low'       - low quality
+    'medium'    - medium quality
+    'high'      - high quality
+    'very_high' - very high quality (default)
+    'max'       - maximum quality
+```
+
+*overflow* - sample overflow handling; default: 'error'
+```text
+    'error'      - raise an error (default)
+    'clip'       - clip overflowing samples (all types)
+    'clip_int'   - clip overflowing samples for integer output sample types
+                   keep overflowing samples for float output sample types
+    'keep_float' - keep overflowing samples for float output sample types
+                   raise an error if output sample type is not float
+```
+
+To properly handle overflows the clip should be converted to a float sample type ('f32'), if not already.
+
+⚠️ Overflowing samples of integer sample types (output) are always clipped (disruptive), or they raise an error
+
+Use `overflow='keep_float'` for float output sample types to leave overflowing samples unchanged.  
+Then call a scaling function like `std.AudioGain` that scales the peak sample value below or to equal 1.0 (see [Example 3](#example-3))
+
+
+*overflow_log* - sample overflow logging; default: 'once'
+```text
+    'all'  - log all sample overflows (not recommended, this can be a lot)
+    'once' - log only the first sample overflow (default)
+    'none' - do not log any sample overflows
+```
+
+**Note**: a summary of all overflowing samples will be logged at the end of each function (if any)
+
+### Example 1
+
+basic usage
+```python
+import vapoursynth as vs
+
+# load audio
+audio = ...
+
+# convert sample rate to 48000 and sample type to 24-bit integer
+audio = vs.core.ares.Resample(audio, sample_rate=48000, sample_type='i24')
+```
+
+### Example 2
+
+change speed of an audio clip (but keep the sample rate)
+```python
+import vapoursynth as vs
+
+# load audio
+audio = ...
+
+# speedup factor
+factor = 2.0
+
+resample_rate = round(audio.sample_rate / factor)
+res_audio = vs.core.ares.Resample(audio, sample_rate=resample_rate)
+audio = vs.core.std.AssumeSampleRate(res_audio, samplerate=audio.sample_rate)
+```
+
+
+### Example 3
+
+handle overflowing samples
+```python
+import vapoursynth as vs
+
+# load audio (integer or float sample type)
+audio = ...
+
+# convert sample rate to 48000 and sample type to 32-bit float
+# leave possible overflowing samples unchanged with 'keep_float'
+audio = vs.core.ares.Resample(audio, sample_rate=48000, sample_type='f32', overflow='keep_float')
+
+# scale audio samples
+# choose a factor that limits the peak value below or to equal 1
+audio = vs.core.std.AudioGain(audio, 0.5)
+
+# optional: convert sample type back to integer if needed (e.g. 24-bit)
+audio = vs.core.ares.Resample(audio, sample_type='i24')
+```
+
+## Dependencies
+This project uses the [SoX Resampler](https://sourceforge.net/projects/soxr/) library (`soxr`), which is licensed under the [GNU Lesser General Public License (LGPL) v2.1](https://www.gnu.org/licenses/old-licenses/lgpl-2.1.html).
+
+The distributed binaries of this plugin statically link to `soxr` for performance and ease of use. If you prefer to use a customized version of `soxr`, or to link dynamically instead, you can build the plugin from source. See the [Build from source](#build-from-source) section for instructions.
+
+
+## Build from source
+To build the plugin, you’ll need CMake and a C++20-compatible compiler. OpenMP support is optional.
+
+Run CMake to configure your preferred build system, then build the project. This process will automatically download and build the `soxr` dependency along with the plugin.
+
+**Note:** You don’t need to download or build `soxr` yourself. However, if you prefer to use a local or customized version of `soxr`, you can provide its source path during configuration (see options below).
+
+e.g. CMake with Ninja:
+```sh
+# EITHER build with statically linked soxr
+cmake -G Ninja -B ./build-ninja -DBUILD_SHARED_LIBS=OFF -DCMAKE_BUILD_TYPE=Release
+
+# OR build with dynamically linked soxr
+cmake -G Ninja -B ./build-ninja -DBUILD_SHARED_LIBS=ON -DCMAKE_BUILD_TYPE=Release
+
+ninja -C ./build-ninja
+```
+
+Custom options for cmake:
+```text
+-DSOXR_SOURCE_DIR=<PATH>     Use a custom soxr source directory
+                             (must contain CMakeLists.txt)
+-DSOXR_USE_PATCHES=<ON|OFF>  Enable patches needed for outdated 
+                             soxr build scripts (default: ON)
+-DWITH_OPENMP=<ON|OFF>       Enable or disable OpenMP support (default: ON)
+```
+
+
+## License
+
+This project is licensed under the MIT License.

vapoursynth_ares-0.4.0/ares/cmake/Clang.cmake

@@ -0,0 +1,17 @@
+function(Clang_GetStyle_CXX IS_CLANG_GCC IS_CLANG_MSVC)
+    if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
+        if (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC")
+            set(${IS_CLANG_GCC} OFF PARENT_SCOPE)
+            set(${IS_CLANG_MSVC} ON PARENT_SCOPE)
+        elseif (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "GNU")
+            set(${IS_CLANG_GCC} ON PARENT_SCOPE)
+            set(${IS_CLANG_MSVC} OFF PARENT_SCOPE)
+        else()
+            set(${IS_CLANG_GCC} OFF PARENT_SCOPE)
+            set(${IS_CLANG_MSVC} OFF PARENT_SCOPE)
+        endif()
+    else()
+        set(${IS_CLANG_GCC} OFF PARENT_SCOPE)
+        set(${IS_CLANG_MSVC} OFF PARENT_SCOPE)
+    endif()
+endfunction()

vapoursynth_ares-0.4.0/ares/cmake/fetch.cmake

@@ -0,0 +1,24 @@
+include(FetchContent)
+
+function(fetch_FromGit SOXR_GIT SOXR_COMMIT SOXR_SOURCE_DIR SOXR_BINARY_DIR)
+    if (CMAKE_VERSION VERSION_GREATER_EQUAL 3.30)
+        FetchContent_Populate(
+            soxr
+            GIT_REPOSITORY ${SOXR_GIT}
+            GIT_PROGRESS ON
+            GIT_TAG ${SOXR_COMMIT}
+        )
+    else()
+        FetchContent_Declare(
+            soxr
+            GIT_REPOSITORY ${SOXR_GIT}
+            GIT_PROGRESS ON
+            GIT_TAG ${SOXR_COMMIT}
+        )
+
+        FetchContent_Populate(soxr)
+    endif()
+
+    set(${SOXR_SOURCE_DIR} "${soxr_SOURCE_DIR}" PARENT_SCOPE)
+    set(${SOXR_BINARY_DIR} "${soxr_BINARY_DIR}" PARENT_SCOPE)
+endfunction()