pyfstree 0.1.0__tar.gz

pyfstree-0.1.0/CMakeLists.txt

@@ -0,0 +1,170 @@
+cmake_minimum_required(VERSION 3.21)
+project(fstree)
+
+if(NOT CMAKE_BUILD_TYPE)
+  set(CMAKE_BUILD_TYPE Release)
+endif()
+
+if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
+  set(CMAKE_CXX_FLAGS "/EHsc")
+elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
+  set(CMAKE_CXX_FLAGS_DEBUG "-g")
+  set(CMAKE_CXX_FLAGS_RELEASE "-O3 -Wall -Wextra -Werror -pedantic")
+  set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
+endif()
+
+
+set(CMAKE_CXX_STANDARD 20)
+
+
+################################################################################
+# Find dependencies
+################################################################################
+
+find_package(Protobuf CONFIG REQUIRED)
+find_package(gRPC CONFIG REQUIRED)
+find_package(GTest CONFIG REQUIRED)
+
+
+################################################################################
+# Build library
+################################################################################
+
+set(SRCS
+    src/cache.cpp
+    src/event.cpp
+    src/index.cpp
+    src/inode.cpp
+    src/jolt.proto
+    src/remote.cpp
+    src/remote_jolt.cpp
+    src/sha1.cpp
+    src/thread.cpp
+    src/thread_pool.cpp
+)
+
+if (WIN32)
+    list(APPEND SRCS
+        src/directory_iterator_win32.cpp
+        src/filesystem_win32.cpp
+        src/lock_file_win32.cpp
+    )
+else()
+    list(APPEND SRCS
+        src/directory_iterator_posix.cpp
+        src/filesystem_posix.cpp
+        src/lock_file_posix.cpp
+    )
+endif()
+
+add_library(fstreelib ${SRCS})
+
+protobuf_generate(
+    TARGET
+        fstreelib
+    LANGUAGE
+        cpp
+)
+
+# compile the GRPC services
+protobuf_generate(
+    TARGET
+        fstreelib
+    LANGUAGE
+        grpc
+    GENERATE_EXTENSIONS
+        .grpc.pb.h
+        .grpc.pb.cc
+    PLUGIN
+        "protoc-gen-grpc=$<TARGET_FILE:gRPC::grpc_cpp_plugin>"
+)
+
+target_include_directories(
+    fstreelib
+    PUBLIC
+        "${CMAKE_CURRENT_SOURCE_DIR}/src"
+        "${CMAKE_CURRENT_BINARY_DIR}"
+        "${CMAKE_CURRENT_BINARY_DIR}/src"
+)
+
+target_link_libraries(
+    fstreelib
+    gRPC::grpc++
+    protobuf::libprotobuf
+)
+
+
+################################################################################
+# Build executable
+################################################################################
+
+add_executable(fstree src/main.cpp)
+
+target_link_libraries(
+    fstree
+    PRIVATE
+        fstreelib
+        protobuf::libprotobuf
+)
+
+if (CMAKE_HOST_SYSTEM_NAME STREQUAL "Linux")
+  target_link_options(
+    fstree
+    PRIVATE
+      "-static"
+  )
+endif()
+
+
+install(
+    TARGETS
+        fstree
+    DESTINATION
+        bin
+)
+
+################################################################################
+# Build tests
+################################################################################
+
+add_executable(
+    fstree_test
+    test/test_config.cpp
+    test/test_ignore.cpp
+    test/test_status.cpp
+    test/test_url.cpp
+)
+
+target_link_libraries(
+    fstree_test
+    PRIVATE
+        fstreelib
+        GTest::gtest
+        GTest::gtest_main
+)
+
+add_test(
+    NAME
+        fstree_test
+    COMMAND
+        fstree_test
+)
+
+install(
+    TARGETS
+        fstree_test
+    DESTINATION
+        bin
+)
+
+################################################################################
+# Python bindings (optional)
+################################################################################
+
+option(BUILD_PYTHON_BINDINGS "Build Python bindings" OFF)
+
+if(BUILD_PYTHON_BINDINGS)
+    add_subdirectory(python)
+endif()
+
+################################################################################