prodigy-ppl-ginac 0.0.1__tar.gz

prodigy_ppl_ginac-0.0.1/.gitignore

@@ -0,0 +1,6 @@
+/build
+/cmake-build-debug
+/.idea
+*.egg-info
+/dist
+/wheelhouse

prodigy_ppl_ginac-0.0.1/.gitmodules

@@ -0,0 +1,7 @@
+[submodule "lib/pybind11"]
+	path = lib/pybind11
+	url = https://github.com/pybind/pybind11.git
+	branch = stable
+[submodule "lib/googletest"]
+	path = lib/googletest
+	url = https://github.com/google/googletest.git

prodigy_ppl_ginac-0.0.1/CMakeLists.txt

@@ -0,0 +1,51 @@
+cmake_minimum_required(VERSION 3.15...3.31)
+set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/modules/")
+
+project(prodigy_ginac LANGUAGES CXX)
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_POSITION_INDEPENDENT_CODE ON)
+
+# The wheel build (pyproject.toml) turns both off, so it needs neither googletest nor the submodules.
+option(PRODIGY_GINAC_BUILD_TESTS "Build the C++ tests (needs the googletest submodule)" ON)
+option(PRODIGY_GINAC_BUILD_DEMO "Build the C++ demo executable" ON)
+# Directory with the license files of GiNaC, CLN and GMP; the wheel build installs them into the wheel.
+set(PRODIGY_GINAC_THIRD_PARTY_LICENSES "" CACHE PATH "Directory with license files of bundled libraries")
+
+# find ginac on system and add headers to include path
+find_package(GiNaC REQUIRED)
+include_directories(${GINAC_INCLUDE_DIRS})
+
+# so that tests and bindings can easily include the library headers
+include_directories(src)
+
+# actual library
+add_subdirectory(src)
+
+# tests
+if (PRODIGY_GINAC_BUILD_TESTS)
+    add_subdirectory(lib/googletest)
+    add_subdirectory(test)
+endif()
+
+# python bindings: pybind11 from the Python environment (pip install pybind11), else the submodule
+find_package(Python COMPONENTS Interpreter Development.Module REQUIRED)
+find_package(pybind11 CONFIG QUIET)
+if (NOT pybind11_FOUND)
+    add_subdirectory(lib/pybind11)
+endif()
+pybind11_add_module(prodigy_ginac python/bindings.cpp)
+target_link_libraries(prodigy_ginac PRIVATE ${CMAKE_PROJECT_NAME}_lib)
+if (DEFINED SKBUILD_PROJECT_VERSION)
+    target_compile_definitions(prodigy_ginac PRIVATE VERSION_INFO=${SKBUILD_PROJECT_VERSION})
+endif()
+if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
+    # keep the symbols of statically linked GiNaC, CLN and GMP out of the module's dynamic symbol table
+    target_link_options(prodigy_ginac PRIVATE "LINKER:--exclude-libs,ALL")
+endif()
+
+install(TARGETS prodigy_ginac LIBRARY DESTINATION .)
+if (PRODIGY_GINAC_THIRD_PARTY_LICENSES AND DEFINED SKBUILD_METADATA_DIR)
+    install(DIRECTORY "${PRODIGY_GINAC_THIRD_PARTY_LICENSES}/"
+            DESTINATION "${SKBUILD_METADATA_DIR}/licenses/third_party")
+endif()

prodigy_ppl_ginac-0.0.1/LICENSE

@@ -0,0 +1,201 @@
+                                 Apache License
+                           Version 2.0, January 2004
+                        http://www.apache.org/licenses/
+
+   TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION
+
+   1. Definitions.
+
+      "License" shall mean the terms and conditions for use, reproduction,
+      and distribution as defined by Sections 1 through 9 of this document.
+
+      "Licensor" shall mean the copyright owner or entity authorized by
+      the copyright owner that is granting the License.
+
+      "Legal Entity" shall mean the union of the acting entity and all
+      other entities that control, are controlled by, or are under common
+      control with that entity. For the purposes of this definition,
+      "control" means (i) the power, direct or indirect, to cause the
+      direction or management of such entity, whether by contract or
+      otherwise, or (ii) ownership of fifty percent (50%) or more of the
+      outstanding shares, or (iii) beneficial ownership of such entity.
+
+      "You" (or "Your") shall mean an individual or Legal Entity
+      exercising permissions granted by this License.
+
+      "Source" form shall mean the preferred form for making modifications,
+      including but not limited to software source code, documentation
+      source, and configuration files.
+
+      "Object" form shall mean any form resulting from mechanical
+      transformation or translation of a Source form, including but
+      not limited to compiled object code, generated documentation,
+      and conversions to other media types.
+
+      "Work" shall mean the work of authorship, whether in Source or
+      Object form, made available under the License, as indicated by a
+      copyright notice that is included in or attached to the work
+      (an example is provided in the Appendix below).
+
+      "Derivative Works" shall mean any work, whether in Source or Object
+      form, that is based on (or derived from) the Work and for which the
+      editorial revisions, annotations, elaborations, or other modifications
+      represent, as a whole, an original work of authorship. For the purposes
+      of this License, Derivative Works shall not include works that remain
+      separable from, or merely link (or bind by name) to the interfaces of,
+      the Work and Derivative Works thereof.
+
+      "Contribution" shall mean any work of authorship, including
+      the original version of the Work and any modifications or additions
+      to that Work or Derivative Works thereof, that is intentionally
+      submitted to Licensor for inclusion in the Work by the copyright owner
+      or by an individual or Legal Entity authorized to submit on behalf of
+      the copyright owner. For the purposes of this definition, "submitted"
+      means any form of electronic, verbal, or written communication sent
+      to the Licensor or its representatives, including but not limited to
+      communication on electronic mailing lists, source code control systems,
+      and issue tracking systems that are managed by, or on behalf of, the
+      Licensor for the purpose of discussing and improving the Work, but
+      excluding communication that is conspicuously marked or otherwise
+      designated in writing by the copyright owner as "Not a Contribution."
+
+      "Contributor" shall mean Licensor and any individual or Legal Entity
+      on behalf of whom a Contribution has been received by Licensor and
+      subsequently incorporated within the Work.
+
+   2. Grant of Copyright License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      copyright license to reproduce, prepare Derivative Works of,
+      publicly display, publicly perform, sublicense, and distribute the
+      Work and such Derivative Works in Source or Object form.
+
+   3. Grant of Patent License. Subject to the terms and conditions of
+      this License, each Contributor hereby grants to You a perpetual,
+      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
+      (except as stated in this section) patent license to make, have made,
+      use, offer to sell, sell, import, and otherwise transfer the Work,
+      where such license applies only to those patent claims licensable
+      by such Contributor that are necessarily infringed by their
+      Contribution(s) alone or by combination of their Contribution(s)
+      with the Work to which such Contribution(s) was submitted. If You
+      institute patent litigation against any entity (including a
+      cross-claim or counterclaim in a lawsuit) alleging that the Work
+      or a Contribution incorporated within the Work constitutes direct
+      or contributory patent infringement, then any patent licenses
+      granted to You under this License for that Work shall terminate
+      as of the date such litigation is filed.
+
+   4. Redistribution. You may reproduce and distribute copies of the
+      Work or Derivative Works thereof in any medium, with or without
+      modifications, and in Source or Object form, provided that You
+      meet the following conditions:
+
+      (a) You must give any other recipients of the Work or
+          Derivative Works a copy of this License; and
+
+      (b) You must cause any modified files to carry prominent notices
+          stating that You changed the files; and
+
+      (c) You must retain, in the Source form of any Derivative Works
+          that You distribute, all copyright, patent, trademark, and
+          attribution notices from the Source form of the Work,
+          excluding those notices that do not pertain to any part of
+          the Derivative Works; and
+
+      (d) If the Work includes a "NOTICE" text file as part of its
+          distribution, then any Derivative Works that You distribute must
+          include a readable copy of the attribution notices contained
+          within such NOTICE file, excluding those notices that do not
+          pertain to any part of the Derivative Works, in at least one
+          of the following places: within a NOTICE text file distributed
+          as part of the Derivative Works; within the Source form or
+          documentation, if provided along with the Derivative Works; or,
+          within a display generated by the Derivative Works, if and
+          wherever such third-party notices normally appear. The contents
+          of the NOTICE file are for informational purposes only and
+          do not modify the License. You may add Your own attribution
+          notices within Derivative Works that You distribute, alongside
+          or as an addendum to the NOTICE text from the Work, provided
+          that such additional attribution notices cannot be construed
+          as modifying the License.
+
+      You may add Your own copyright statement to Your modifications and
+      may provide additional or different license terms and conditions
+      for use, reproduction, or distribution of Your modifications, or
+      for any such Derivative Works as a whole, provided Your use,
+      reproduction, and distribution of the Work otherwise complies with
+      the conditions stated in this License.
+
+   5. Submission of Contributions. Unless You explicitly state otherwise,
+      any Contribution intentionally submitted for inclusion in the Work
+      by You to the Licensor shall be under the terms and conditions of
+      this License, without any additional terms or conditions.
+      Notwithstanding the above, nothing herein shall supersede or modify
+      the terms of any separate license agreement you may have executed
+      with Licensor regarding such Contributions.
+
+   6. Trademarks. This License does not grant permission to use the trade
+      names, trademarks, service marks, or product names of the Licensor,
+      except as required for reasonable and customary use in describing the
+      origin of the Work and reproducing the content of the NOTICE file.
+
+   7. Disclaimer of Warranty. Unless required by applicable law or
+      agreed to in writing, Licensor provides the Work (and each
+      Contributor provides its Contributions) on an "AS IS" BASIS,
+      WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
+      implied, including, without limitation, any warranties or conditions
+      of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A
+      PARTICULAR PURPOSE. You are solely responsible for determining the
+      appropriateness of using or redistributing the Work and assume any
+      risks associated with Your exercise of permissions under this License.
+
+   8. Limitation of Liability. In no event and under no legal theory,
+      whether in tort (including negligence), contract, or otherwise,
+      unless required by applicable law (such as deliberate and grossly
+      negligent acts) or agreed to in writing, shall any Contributor be
+      liable to You for damages, including any direct, indirect, special,
+      incidental, or consequential damages of any character arising as a
+      result of this License or out of the use or inability to use the
+      Work (including but not limited to damages for loss of goodwill,
+      work stoppage, computer failure or malfunction, or any and all
+      other commercial damages or losses), even if such Contributor
+      has been advised of the possibility of such damages.
+
+   9. Accepting Warranty or Additional Liability. While redistributing
+      the Work or Derivative Works thereof, You may choose to offer,
+      and charge a fee for, acceptance of support, warranty, indemnity,
+      or other liability obligations and/or rights consistent with this
+      License. However, in accepting such obligations, You may act only
+      on Your own behalf and on Your sole responsibility, not on behalf
+      of any other Contributor, and only if You agree to indemnify,
+      defend, and hold each Contributor harmless for any liability
+      incurred by, or claims asserted against, such Contributor by reason
+      of your accepting any such warranty or additional liability.
+
+   END OF TERMS AND CONDITIONS
+
+   APPENDIX: How to apply the Apache License to your work.
+
+      To apply the Apache License to your work, attach the following
+      boilerplate notice, with the fields enclosed by brackets "[]"
+      replaced with your own identifying information. (Don't include
+      the brackets!)  The text should be enclosed in the appropriate
+      comment syntax for the file format. We also recommend that a
+      file or class name and description of purpose be included on the
+      same "printed page" as the copyright notice for easier
+      identification within third-party archives.
+
+   Copyright [2022] [Lutz Klinkenberg]
+
+   Licensed under the Apache License, Version 2.0 (the "License");
+   you may not use this file except in compliance with the License.
+   You may obtain a copy of the License at
+
+       http://www.apache.org/licenses/LICENSE-2.0
+
+   Unless required by applicable law or agreed to in writing, software
+   distributed under the License is distributed on an "AS IS" BASIS,
+   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+   See the License for the specific language governing permissions and
+   limitations under the License.

prodigy_ppl_ginac-0.0.1/PKG-INFO

@@ -0,0 +1,109 @@
+Metadata-Version: 2.4
+Name: prodigy-ppl-ginac
+Version: 0.0.1
+Summary: GiNaC-based Python bindings for manipulating distributions through generating functions, used by Prodigy
+Keywords: probabilistic programs,generating functions,ginac,computer algebra
+Author: Lutz Klinkenberg
+Author-Email: Tobias Winkler <tobias.winkler@cs.rwth-aachen.de>
+License-Expression: Apache-2.0 AND GPL-2.0-or-later
+License-File: LICENSE
+Classifier: Development Status :: 4 - Beta
+Classifier: Intended Audience :: Science/Research
+Classifier: Operating System :: MacOS
+Classifier: Operating System :: POSIX :: Linux
+Classifier: Programming Language :: C++
+Classifier: Programming Language :: Python :: 3
+Classifier: Programming Language :: Python :: 3 :: Only
+Classifier: Programming Language :: Python :: 3.11
+Classifier: Programming Language :: Python :: 3.12
+Classifier: Programming Language :: Python :: 3.13
+Classifier: Programming Language :: Python :: 3.14
+Classifier: Topic :: Scientific/Engineering :: Mathematics
+Project-URL: Repository, https://github.com/LKlinke/prodigy-ginac-bindings
+Project-URL: Issues, https://github.com/LKlinke/prodigy-ginac-bindings/issues
+Project-URL: Prodigy, https://github.com/LKlinke/Prodigy
+Requires-Python: >=3.11
+Provides-Extra: test
+Requires-Dist: pytest; extra == "test"
+Description-Content-Type: text/markdown
+
+# prodigy-ppl-ginac: A library for manipulating discrete distributions through generating functions
+
+GiNaC-based Python bindings used by [Prodigy](https://github.com/LKlinke/Prodigy) for its fast `ginac` engine.
+
+The main features are
+- python bindings
+- a purely string-based interface, no need to mess around with data structures for algebraic expression and the like
+- support for parameters (can also be used as meta symbols in second-order PGFs)
+
+## Installation
+
+```
+pip install prodigy-ppl-ginac
+```
+
+Prebuilt wheels contain GiNaC, CLN and GMP, so they need neither a compiler nor a system GiNaC.
+They exist for CPython 3.11 to 3.14 on
+- Linux (manylinux_2_28) x86_64 and aarch64,
+- macOS 11 or later, x86_64 and arm64.
+
+Windows is not supported.
+
+## Usage
+
+The distribution is called `prodigy-ppl-ginac`, the module `prodigy_ginac`:
+
+```
+import prodigy_ginac
+dist = prodigy_ginac.geometric("x", "1/2")
+e = dist.E("x")  # e becomes 1, the expected value of the 1/2-geometric distribution
+```
+
+Before it was published on PyPI, the module was installed from Git as `pygin` (version 1.0); the package `pygin` on PyPI
+is an unrelated project.
+
+## Building from source
+
+On other platforms pip builds the sdist, which needs a C++17 compiler, CMake and a system GiNaC with pkg-config,
+e.g. `brew install ginac pkgconf` on macOS or `apt install libginac-dev pkg-config` on Debian and Ubuntu.
+In a clone of this repository
+
+```
+pip install .
+```
+
+builds and installs the module.
+
+`scripts/build-deps.sh PREFIX` builds the pinned versions of GMP, CLN and GiNaC as static libraries into `PREFIX`,
+as for the wheels; with `CMAKE_PREFIX_PATH=PREFIX` the build uses them instead of the system GiNaC.
+
+### Wheels and releases
+
+[cibuildwheel](https://cibuildwheel.pypa.io) builds the wheels (configuration in `pyproject.toml`, workflow
+`.github/workflows/wheels.yml`). Pushing a tag `v<version>` (e.g. `v0.0.1`, or `v0.1.0rc1` for a pre-release) publishes the wheels and the sdist with
+this version on PyPI (`.github/workflows/release.yml`). The version is in no file; without a tag, builds get a
+development version such as `0.1.devN`.
+
+### C++ tests and demo
+
+The C++ tests need the googletest submodule:
+
+```
+git submodule update --init
+cmake -B build && cmake --build build
+./build/test/prodigy_ginac_test
+```
+
+The CMake options `PRODIGY_GINAC_BUILD_TESTS` and `PRODIGY_GINAC_BUILD_DEMO` (both on by default, off for the wheels)
+switch the tests and the demo executable.
+
+## License
+
+The source code in this repository is licensed under the Apache License 2.0 (`LICENSE`).
+
+The wheels on PyPI also contain statically linked copies of
+[GiNaC](https://www.ginac.de) and [CLN](https://www.ginac.de/CLN/) (GPL-2.0-or-later) and
+[GMP](https://gmplib.org) (LGPL-3.0-or-later or GPL-2.0-or-later). A wheel as a whole is therefore distributed under
+the terms of the GNU General Public License, version 3 or later, the GPL version compatible with the Apache License 2.0.
+The license texts of these libraries are in the wheel's `.dist-info/licenses/third_party` directory; their source
+code is available from the links above, in the versions pinned in `scripts/build-deps.sh`.

prodigy_ppl_ginac-0.0.1/README.md

@@ -0,0 +1,80 @@
+# prodigy-ppl-ginac: A library for manipulating discrete distributions through generating functions
+
+GiNaC-based Python bindings used by [Prodigy](https://github.com/LKlinke/Prodigy) for its fast `ginac` engine.
+
+The main features are
+- python bindings
+- a purely string-based interface, no need to mess around with data structures for algebraic expression and the like
+- support for parameters (can also be used as meta symbols in second-order PGFs)
+
+## Installation
+
+```
+pip install prodigy-ppl-ginac
+```
+
+Prebuilt wheels contain GiNaC, CLN and GMP, so they need neither a compiler nor a system GiNaC.
+They exist for CPython 3.11 to 3.14 on
+- Linux (manylinux_2_28) x86_64 and aarch64,
+- macOS 11 or later, x86_64 and arm64.
+
+Windows is not supported.
+
+## Usage
+
+The distribution is called `prodigy-ppl-ginac`, the module `prodigy_ginac`:
+
+```
+import prodigy_ginac
+dist = prodigy_ginac.geometric("x", "1/2")
+e = dist.E("x")  # e becomes 1, the expected value of the 1/2-geometric distribution
+```
+
+Before it was published on PyPI, the module was installed from Git as `pygin` (version 1.0); the package `pygin` on PyPI
+is an unrelated project.
+
+## Building from source
+
+On other platforms pip builds the sdist, which needs a C++17 compiler, CMake and a system GiNaC with pkg-config,
+e.g. `brew install ginac pkgconf` on macOS or `apt install libginac-dev pkg-config` on Debian and Ubuntu.
+In a clone of this repository
+
+```
+pip install .
+```
+
+builds and installs the module.
+
+`scripts/build-deps.sh PREFIX` builds the pinned versions of GMP, CLN and GiNaC as static libraries into `PREFIX`,
+as for the wheels; with `CMAKE_PREFIX_PATH=PREFIX` the build uses them instead of the system GiNaC.
+
+### Wheels and releases
+
+[cibuildwheel](https://cibuildwheel.pypa.io) builds the wheels (configuration in `pyproject.toml`, workflow
+`.github/workflows/wheels.yml`). Pushing a tag `v<version>` (e.g. `v0.0.1`, or `v0.1.0rc1` for a pre-release) publishes the wheels and the sdist with
+this version on PyPI (`.github/workflows/release.yml`). The version is in no file; without a tag, builds get a
+development version such as `0.1.devN`.
+
+### C++ tests and demo
+
+The C++ tests need the googletest submodule:
+
+```
+git submodule update --init
+cmake -B build && cmake --build build
+./build/test/prodigy_ginac_test
+```
+
+The CMake options `PRODIGY_GINAC_BUILD_TESTS` and `PRODIGY_GINAC_BUILD_DEMO` (both on by default, off for the wheels)
+switch the tests and the demo executable.
+
+## License
+
+The source code in this repository is licensed under the Apache License 2.0 (`LICENSE`).
+
+The wheels on PyPI also contain statically linked copies of
+[GiNaC](https://www.ginac.de) and [CLN](https://www.ginac.de/CLN/) (GPL-2.0-or-later) and
+[GMP](https://gmplib.org) (LGPL-3.0-or-later or GPL-2.0-or-later). A wheel as a whole is therefore distributed under
+the terms of the GNU General Public License, version 3 or later, the GPL version compatible with the Apache License 2.0.
+The license texts of these libraries are in the wheel's `.dist-info/licenses/third_party` directory; their source
+code is available from the links above, in the versions pinned in `scripts/build-deps.sh`.

prodigy_ppl_ginac-0.0.1/cmake/modules/FindCLN.cmake

@@ -0,0 +1,126 @@
+# CLN_FOUND		CLN has been successfully found
+# CLN_INCLUDE_DIR       the include directories
+# CLN_LIBRARIES         CLN library and its dependencies (if any)
+
+if (CLN_INCLUDE_DIR AND CLN_LIBRARIES)
+    set(CLN_FIND_QUIETLY TRUE)
+endif()
+
+function(_cl_get_version _out_major _out_minor _out_patch _cl_version_h)
+    file(STRINGS ${_cl_version_h} _cl_vinfo REGEX "^#define[\t ]+CL_VERSION_.*")
+    if (NOT _cl_vinfo)
+        message(FATAL_ERROR "include file ${_cl_version_h} does not exist")
+    endif()
+    string(REGEX REPLACE "^.*CL_VERSION_MAJOR[ \t]+([0-9]+).*" "\\1" ${_out_major} "${_cl_vinfo}")
+    string(REGEX REPLACE "^.*CL_VERSION_MINOR[ \t]+([0-9]+).*" "\\1" ${_out_minor} "${_cl_vinfo}")
+    string(REGEX REPLACE "^.*CL_VERSION_PATCHLEVEL[ \t]+([0-9]+).*" "\\1" ${_out_patch} "${_cl_vinfo}")
+    if (NOT ${_out_major} MATCHES "[0-9]+")
+        message(FATAL_ERROR "failed to determine CL_VERSION_MAJOR, "
+                "expected a number, got ${${_out_major}}")
+    endif()
+    if (NOT ${_out_minor} MATCHES "[0-9]+")
+        message(FATAL_ERROR "failed to determine CL_VERSION_MINOR, "
+                "expected a number, got ${${_out_minor}}")
+    endif()
+    if (NOT ${_out_patch} MATCHES "[0-9]+")
+        message(FATAL_ERROR "failed to determine CL_VERSION_PATCHLEVEL, "
+                "expected a number, got ${${_out_patch}}")
+    endif()
+    message(STATUS "found CLN [${_cl_version_h}], version ${${_out_major}}.${${_out_minor}}.${${_out_patch}}")
+    set(${_out_major} ${${_out_major}} PARENT_SCOPE)
+    set(${_out_minor} ${${_out_minor}} PARENT_SCOPE)
+    set(${_out_patch} ${${_out_patch}} PARENT_SCOPE)
+endfunction()
+
+set(CLN_FOUND)
+set(CLN_INCLUDE_DIR)
+set(CLN_LIBRARIES)
+
+include(FindPkgConfig)
+if (PKG_CONFIG_FOUND)
+    pkg_check_modules(_cln cln)
+endif()
+
+find_path(CLN_INCLUDE_DIR NAMES cln/cln.h
+        HINTS ${_cln_INCLUDE_DIRS}
+        $ENV{CLN_DIR}/include)
+find_library(CLN_LIBRARIES NAMES libcln cln
+        HINTS ${_cln_LIBRARY_DIR}
+        ${_cln_LIBRARY_DIRS}
+        $ENV{CLN_DIR}/lib)
+
+# A static libcln (as built for the wheels) needs GMP on the link line as well.
+if (CLN_LIBRARIES MATCHES "\\.a$")
+    get_filename_component(_cln_static_dir "${CLN_LIBRARIES}" PATH)
+    find_library(_cln_gmp_library NAMES libgmp.a gmp HINTS ${_cln_static_dir})
+    if (_cln_gmp_library)
+        set(CLN_LIBRARIES ${CLN_LIBRARIES} ${_cln_gmp_library})
+    endif()
+endif()
+
+if (CLN_INCLUDE_DIR)
+    _cl_get_version(CLN_VERSION_MAJOR
+            CLN_VERSION_MINOR
+            CLN_VERSION_PATCHLEVEL
+            ${CLN_INCLUDE_DIR}/cln/version.h)
+    set(CLN_VERSION ${CLN_VERSION_MAJOR}.${CLN_VERSION_MINOR}.${CLN_VERSION_PATCHLEVEL})
+    # Check if the version reported by pkg-config is the same
+    # as the one read from the header. This prevents us from
+    # picking the wrong version of CLN (say, if several versions
+    # are installed)
+    if (_cln_FOUND AND NOT CLN_VERSION VERSION_EQUAL _cln_VERSION)
+        if (NOT CLN_FIND_QUIETLY)
+            message(ERROR "pkg-config and version.h disagree, "
+                    "${_cln_VERSION} vs ${CLN_VERSION}, "
+                    "please check your installation")
+        endif()
+        set(CLN_LIBRARIES CLN-NOTFOUND)
+        set(CLN_INCLUDE_DIR CLN-NOTFOUND)
+        set(CLN_LIBRARY_DIRS)
+        set(CLN_VERSION)
+    endif()
+endif()
+
+# Check if the version embedded into the library is the same as the one in the headers.
+if (CLN_INCLUDE_DIR AND CLN_LIBRARIES AND NOT CMAKE_CROSSCOMPILING)
+    include(CheckCXXSourceRuns)
+    set(_save_required_includes ${CMAKE_REQUIRED_INCLUDES})
+    set(_save_required_libraries ${CMAKE_REQUIRED_LIBRARIES})
+    set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${CLN_INCLUDE_DIR})
+    set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${CLN_LIBRARIES})
+    check_cxx_source_runs("
+		#include <cln/version.h>
+		int main() {
+			return (CL_VERSION_MAJOR == cln::version_major) &&
+			       (CL_VERSION_MINOR == cln::version_minor) &&
+			       (CL_VERSION_PATCHLEVEL == cln::version_patchlevel) ? 0 : 1;
+		}
+		"
+            _cl_version_matches)
+    set(CMAKE_REQUIRED_LIBRARIES ${_save_required_libraries})
+    set(CMAKE_REQUIRED_INCLUDES ${_save_required_includes})
+    if (NOT _cl_version_matches)
+        if (NOT CLN_FIND_QUIETLY)
+            message(ERROR "header (version differs from the library one, "
+                    "please check your installation.")
+        endif()
+        set(CLN_INCLUDE_DIR CLN-NOTFOUND)
+        set(CLN_LIBRARIES CLN-NOTFOUND)
+        set(CLN_LIBRARY_DIRS)
+        set(CLN_VERSION)
+    endif()
+endif()
+
+if (CLN_LIBRARIES AND CLN_INCLUDE_DIR)
+    set(_cln_library_dirs)
+    foreach(_l ${CLN_LIBRARIES})
+        get_filename_component(_d "${_l}" PATH)
+        list(APPEND _cln_library_dirs "${_d}")
+    endforeach()
+    list(REMOVE_DUPLICATES _cln_library_dirs)
+    set(CLN_LIBRARY_DIRS ${_cln_library_dirs})
+endif()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(CLN REQUIRED_VARS CLN_LIBRARIES CLN_INCLUDE_DIR
+        VERSION_VAR CLN_VERSION)