ntgcalls 2.0.6__tar.gz → 2.0.9__tar.gz

ntgcalls-2.0.9/CMakeLists.txt

@@ -0,0 +1,47 @@
+cmake_minimum_required(VERSION 3.27)
+
+if (WIN32)
+    add_compile_options(/wd4068)
+endif ()
+
+include(ExternalProject)
+
+option(STATIC_BUILD "Build static libraries" ON)
+option(USE_LIBCXX   "Use libc++" ON)
+
+add_custom_target(clean_objects
+    COMMAND ${CMAKE_COMMAND} -P "${CMAKE_SOURCE_DIR}/cmake/CleanObjects.cmake"
+    COMMENT "Removing all object (.o) files"
+)
+
+project(ntgcalls VERSION 2.0.9 LANGUAGES C CXX)
+include(cmake/VersionUtil.cmake)
+
+if (MACOS)
+    enable_language(OBJCXX)
+endif ()
+
+find_package(Threads REQUIRED)
+
+get_filename_component(DEPS_DIR     "deps" REALPATH)
+get_filename_component(android_loc  "android" REALPATH)
+get_filename_component(jni_loc      "${android_loc}/app/src/main/jni" REALPATH)
+get_filename_component(props_loc    "version.properties" REALPATH)
+
+include(cmake/FindGLib.cmake)
+include(cmake/FindX11.cmake)
+include(cmake/FindMesa.cmake)
+include(cmake/FindWebRTC.cmake)
+include(cmake/FindLibCXX.cmake)
+include(cmake/FindBoost.cmake)
+include(cmake/FindOpenH264.cmake)
+include(cmake/FindFFmpeg.cmake)
+
+if (IS_PYTHON)
+    # pybind11
+    set(PYBIND11_FINDPYTHON "NEW")
+    add_subdirectory(deps/pybind11)
+endif ()
+
+add_subdirectory(wrtc)
+add_subdirectory(ntgcalls)

ntgcalls-2.0.9/PKG-INFO

@@ -0,0 +1,172 @@
+Metadata-Version: 2.4
+Name: ntgcalls
+Version: 2.0.9
+Summary: A Native Implementation of Telegram Calls in a seamless way.
+Author-email: Laky-64 <iraci.matteo@gmail.com>
+Project-URL: Homepage, https://pytgcalls.github.io/
+Project-URL: Repository, https://github.com/pytgcalls/ntgcalls.git
+Project-URL: Documentation, https://pytgcalls.github.io/NTgCalls
+Project-URL: Changelog, https://pytgcalls.github.io/PyTgCalls/Changelogs
+Keywords: audio,python,library,video,telegram,stream,ffmpeg,cpp,webrtc,voice-chat,voip,group-chat,video-calls,calls,video-chat,pytgcalls,ntgcalls,tgcalls,py-tgcalls
+Classifier: Programming Language :: Python :: 3
+Classifier: Programming Language :: Python :: 3 :: Only
+Classifier: Programming Language :: Python :: 3.10
+Classifier: Programming Language :: Python :: 3.11
+Classifier: Programming Language :: Python :: 3.12
+Classifier: Programming Language :: Python :: 3.13
+Classifier: Programming Language :: Python :: 3.14
+Classifier: Programming Language :: Python :: Implementation :: CPython
+Requires-Python: >=3.10
+Description-Content-Type: text/markdown
+License-File: LICENSE
+Provides-Extra: test
+Requires-Dist: pytest>=6.0; extra == "test"
+Dynamic: license-file
+
+<img src="https://raw.githubusercontent.com/pytgcalls/ntgcalls/master/.github/images/banner.png" alt="pytgcalls logo" />
+<p align="center">
+    <b>A Native Implementation of Telegram Calls in a seamless way.</b>
+    <br>
+    <a href="https://github.com/pytgcalls/ntgcalls/tree/master/examples">
+        Examples
+    </a>
+    •
+    <a href="https://pytgcalls.github.io/">
+        Documentation
+    </a>
+    •
+    <a href="https://pypi.org/project/ntgcalls/">
+        PyPi
+    </a>
+    •
+    <a href="https://github.com/pytgcalls/ntgcalls/releases">
+        Releases
+    </a>
+    •
+    <a href="https://t.me/pytgcallsnews">
+        Channel
+    </a>
+    •
+    <a href="https://t.me/pytgcallschat">
+        Chat
+    </a>
+</p>
+
+# NTgCalls [![PyPI - Version](https://img.shields.io/pypi/v/ntgcalls?logo=python&logoColor=%23959DA5&label=pypi&labelColor=%23282f37)](https://pypi.org/project/ntgcalls/) [![Downloads](https://img.shields.io/pepy/dt/ntgcalls?logoColor=%23959DA5&labelColor=%23282f37&color=%2328A745)](https://pepy.tech/project/ntgcalls)
+NTgCalls is a lightweight open-source library for media streaming in Telegram calls. Built from scratch in C++ with WebRTC & Boost, it prioritizes accessibility to developers and resource efficiency.
+
+|                                                                                     Powerful                                                                                      |                                                                                            Simple                                                                                            |                                                                                                   Light                                                                                                    |
+|:---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------:|:--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------:|:----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------:|
+| <img src="https://raw.githubusercontent.com/pytgcalls/ntgcalls/master/.github/images/fast.gif" width=150 alt="Fast Logo"/><br>Built from scratch in C++ using Boost and libwebrtc | <img src="https://raw.githubusercontent.com/pytgcalls/ntgcalls/master/.github/images/simple.gif" width=150 alt="Simple Logo"/><br>Simple Python, GO, C Bindings and Java for Android SDK<br> | <img src="https://raw.githubusercontent.com/pytgcalls/ntgcalls/master/.github/images/light.gif" width=150 alt="Light logo"/><br>We removed anything that could burden the library, including <b>NodeJS</b> |
+
+## Build Status
+| Architecture |                                                                   Windows                                                                   |                                                                Linux                                                                |                                                                  MacOS                                                                  |
+|:------------:|:-------------------------------------------------------------------------------------------------------------------------------------------:|:-----------------------------------------------------------------------------------------------------------------------------------:|:---------------------------------------------------------------------------------------------------------------------------------------:|
+|    x86_64    |   ![BUILD](https://img.shields.io/badge/build-passing-dark_green?logo=windows11&logoColor=%23959DA5&labelColor=%23282f37&color=%2328A745)   | ![BUILD](https://img.shields.io/badge/build-passing-dark_green?logo=linux&logoColor=%23959DA5&labelColor=%23282f37&color=%2328A745) | ![BUILD](https://img.shields.io/badge/build-unsupported-dark_green?logo=apple&logoColor=%23959DA5&labelColor=%23282f37&color=%23959DA5) |
+|    ARM64     | ![BUILD](https://img.shields.io/badge/build-unsupported-dark_green?logo=windows11&logoColor=%23959DA5&labelColor=%23282f37&color=%23959DA5) | ![BUILD](https://img.shields.io/badge/build-passing-dark_green?logo=linux&logoColor=%23959DA5&labelColor=%23282f37&color=%2328A745) |   ![BUILD](https://img.shields.io/badge/build-passing-dark_green?logo=apple&logoColor=%23959DA5&labelColor=%23282f37&color=%2328A745)   |
+
+## Features
+- Pre-built binaries for macOS (arm64-v8a), Linux (x86_64, arm64-v8a), Windows (x86_64), and Android (x86, 86_64, arm64-v8a, armv7)
+- Call flexibility: Group and private call support
+- Media controls: pause/resume and mute/unmute
+- Codec compatibility: H.264, HEVC (H.265), VP8, VP9, AV1, AAC, MP3, Opus
+- Content sharing: Screen streaming, Microphone and Camera streaming
+- Pre-built wheels for Python & AAR SDK library for Android
+
+## Compiling
+
+### Python Bindings
+NTgCalls includes Python bindings for seamless integration. Follow these steps to compile it with Python Bindings:
+1. Ensure you are in the root directory of the NTgCalls project.
+2. Run the following command to install the Py Bindings:
+
+   ```shell
+   python3 setup.py install
+   ```
+### Go Bindings
+> [!WARNING]
+> Static linking for Windows is not supported yet since our library is built with MSVC and Go uses MinGW for static linking.
+> More info can be found [here](https://github.com/golang/go/issues/63903)
+
+NTgCalls includes Go Bindings, enabling seamless integration with Go. Follow these steps to compile it with Go Bindings:
+1. There is an example project for Go in `./examples/go/` directory, ensure you are in that directory
+2. Prerequisites for building are the same as for building a library itself and can be found [here](https://pytgcalls.github.io/NTgCalls/Build%20Guide#Installing=Prerequisites)
+3. Download **shared** or **static** release of the library from https://github.com/pytgcalls/ntgcalls/releases
+4. Copy `ntgcalls.h` file into `./examples/go/ntgcalls/` directory
+5. The rest of the files should be copied to `./examples/go/` directory
+    * `ntgcalls.dll` or `ntgcalls.lib` files in case of Windows amd64
+    * `libntgcalls.so` or `libntgcalls.a` files in case of Linux amd64
+    * `libntgcalls.dylib` or `libntgcalls.a` files in case of macOS
+6. Then in `./examples/go/` directory run `go build` or `go run .` with CGO_ENABLED=1 env variable set
+    * `$env:CGO_ENABLED=1; go run .` for Windows PowerShell
+    * `CGO_ENABLED=1 go run .` for UNIX
+
+
+### C Bindings
+For developers looking to use NTgCalls with C and C++, we provide C Bindings. Follow these steps to compile it with C Bindings:
+1. Ensure you are in the root directory of the NTgCalls project.
+2. Run the following command to generate the library:
+   ```shell
+   # Static library
+   python3 setup.py build_lib --static
+   
+   # Shared library
+   python3 setup.py build_lib --shared
+   ```
+3. Upon successful execution, a library will be generated in the "shared-output" or "static-output" directory, depending on the chosen option.
+   Now you can use this library to develop applications with NTgCalls.
+4. To include the necessary headers in your C/C++ projects, you will find the "include" folder in the "shared-output" or "static-output" directory.
+   Use this folder by including the required header files.
+
+## Key Contributors
+* <b><a href="https://github.com/Laky-64">@Laky-64</a> (DevOps Engineer, Software Architect, Porting Engineer):</b>
+    * Played a crucial role in developing NTgCalls.
+    * Created the Python Bindings that made the library accessible to Python developers.
+    * Developed the C Bindings, enabling the library's use in various environments.
+* <b><a href="https://github.com/dadadani">@dadadani</a> (Senior C++ Developer, Performance engineer):</b>
+    * Contributed to setting up CMakeLists and integrating with pybind11,
+      greatly simplifying the library's usage for C++ developers.
+* <b><a href="https://github.com/kuogi">@kuogi</a> (Senior UI/UX designer, Documenter):</b>
+    * As a Senior UI/UX Designer, Kuogi has significantly improved the user interface of our documentation,
+      making it more visually appealing and user-friendly.
+    * It Has also played a key role in writing and structuring our documentation, ensuring that it is clear,
+      informative, and accessible to all users.
+* <b><a href="https://github.com/vrumger">@vrumger</a> (Mid-level NodeJS Developer):</b>
+    * Avrumy has made important fixes and enhancements to the WebRTC component of the library,
+      improving its stability and performance.
+
+## Junior Developers
+* <b><a href="https://github.com/TuriOG">@TuriOG</a> (Junior Python Developer):</b>
+    * Currently working on integrating NTgCalls into <a href="//github.com/pytgcalls/pytgcalls">PyTgCalls</a>, an important step
+      in expanding the functionality and usability of the library.
+* <b><a href="https://github.com/doggyhaha">@doggyhaha</a> (Junior DevOps, Tester):</b>
+    * Performs testing of NTgCalls on Linux to ensure its reliability and compatibility.
+    * Specializes in creating and maintaining GitHub Actions, focusing on automation tasks.
+* <b><a href="https://github.com/tappo03">@tappo03</a> (Junior Go Developer, Tester):</b>
+    * Performs testing of NTgCalls on Windows to ensure its reliability and compatibility.
+    * It Is in the process of integrating NTgCalls into a Go wrapper, further enhancing the library's
+      versatility and accessibility.
+
+## Special Thanks
+* <b><a href="https://github.com/shiguredo">@shiguredo</a>:</b>
+  We extend our special thanks to 時雨堂 (shiguredo) for their invaluable assistance in integrating the WebRTC component. Their contributions,
+  using the Sora C++ SDK, have been instrumental in enhancing the functionality of our library.
+
+* <b><a href="https://github.com/evgeny-nadymov">@evgeny-nadymov</a>:</b>
+  A heartfelt thank you to Evgeny Nadymov for graciously allowing us to use their code from telegram-react.
+  His contribution has been pivotal to the success of this project.
+
+* <b><a href="https://github.com/morethanwords">@morethanwords</a>:</b>
+  We extend our special thanks to morethanwords for their invaluable help in integrating the connection to WebRTC with Telegram Web K.
+  Their assistance has been instrumental in enhancing the functionality of our library.
+
+* <b><a href="https://github.com/MarshalX">@MarshalX</a>:</b> for their generous assistance in answering questions and providing insights regarding WebRTC.
+
+* <b><a href="https://github.com/LyzCoote">@LyzCoote</a>:</b> for providing an ARM64 Server and allowing us to build an image with clang-18 preinstalled on manylinux2014 arm64.
+
+_We would like to extend a special thanks to <b><a href='https://github.com/null-nick'>@null-nick</a></b>
+and <b><a href='https://github.com/branchscope'>@branchscope</a></b> for their valuable contributions to the testing phase of the library and to
+<b><a href='https://github.com/SadLuffy'>@SadLuffy</a></b> for his assistance as a copywriter.
+Their dedication to testing and optimizing the library has been instrumental in its success._
+
+_Additionally, we extend our gratitude to all contributors for their exceptional work in making this project a reality._

ntgcalls-2.0.9/cmake/Android.cmake

@@ -0,0 +1,21 @@
+if (ANDROID_ABI STREQUAL "arm64-v8a")
+    target_compile_options(${target_name} PUBLIC
+        -fexperimental-relative-c++-abi-vtables
+    )
+endif ()
+target_link_options(${target_name} PRIVATE
+    -Wl,-z,max-page-size=16384
+)
+target_compile_definitions(${target_name} PUBLIC
+    WEBRTC_POSIX
+    WEBRTC_LINUX
+    WEBRTC_ANDROID
+    _LIBCPP_ABI_NAMESPACE=Cr
+    _LIBCPP_ABI_VERSION=2
+    _LIBCPP_DISABLE_AVAILABILITY
+    _LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS
+    _LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS
+    _LIBCPP_ENABLE_NODISCARD
+    _LIBCPP_HARDENING_MODE=_LIBCPP_HARDENING_MODE_EXTENSIVE
+    BOOST_NO_CXX98_FUNCTION_BASE
+)

ntgcalls-2.0.9/cmake/FindBoost.cmake

@@ -0,0 +1,116 @@
+set(BOOST_DIR ${DEPS_DIR}/boost)
+set(BOOST_SRC ${BOOST_DIR}/src)
+set(BOOST_GIT https://github.com/pytgcalls/boost)
+set(BOOST_LIB_DIR ${BOOST_SRC}/lib)
+set(BOOST_ATOMIC_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}boost_atomic${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(BOOST_CONTEXT_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}boost_context${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(BOOST_DATE_TIME_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}boost_date_time${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(BOOST_FILESYSTEM_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}boost_filesystem${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(BOOST_PROCESS_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}boost_process${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(BOOST_JSON_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}boost_json${CMAKE_STATIC_LIBRARY_SUFFIX})
+
+if (ANDROID)
+    set(BOOST_LIB_DIR ${BOOST_LIB_DIR}/${ANDROID_ABI})
+endif ()
+
+if (LINUX_ARM64)
+    set(PLATFORM linux)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH arm64)
+elseif (LINUX_x86_64)
+    set(PLATFORM linux)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH x86_64)
+elseif (MACOS_ARM64)
+    set(PLATFORM macos)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH arm64)
+elseif (WINDOWS_x86_64)
+    set(PLATFORM windows)
+    set(ARCHIVE_FORMAT .zip)
+    set(ARCH x86_64)
+elseif (ANDROID)
+    set(PLATFORM android)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH ${ANDROID_ABI})
+else ()
+    message(STATUS "Boost is not supported on ${CMAKE_SYSTEM_NAME} with ${CMAKE_HOST_SYSTEM_PROCESSOR}")
+    return()
+endif ()
+
+add_compile_definitions(BOOST_ALL_NO_LIB)
+GetProperty("version.boost" BOOST_VERSION)
+message(STATUS "boost v${BOOST_VERSION}")
+
+set(FILE_NAME boost.${PLATFORM})
+if (NOT ANDROID)
+    set(FILE_NAME ${FILE_NAME}-${ARCH})
+endif ()
+set(FILE_NAME ${FILE_NAME}${ARCHIVE_FORMAT})
+
+DownloadProject(
+    URL ${BOOST_GIT}/releases/download/v${BOOST_VERSION}/${FILE_NAME}
+    DOWNLOAD_DIR ${BOOST_DIR}/download
+    SOURCE_DIR ${BOOST_SRC}
+)
+
+if (NOT TARGET Boost::json)
+    add_library(Boost::json STATIC IMPORTED)
+    set_target_properties(Boost::json PROPERTIES
+        INTERFACE_INCLUDE_DIRECTORIES "${BOOST_SRC}/include"
+        IMPORTED_LINK_INTERFACE_LANGUAGES CXX
+        IMPORTED_LOCATION "${BOOST_LIB_DIR}/${BOOST_JSON_LIB}"
+    )
+endif ()
+
+if (NOT ANDROID)
+    if (NOT TARGET Boost::atomic)
+        add_library(Boost::atomic STATIC IMPORTED)
+        set_target_properties(Boost::atomic PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${BOOST_SRC}/include"
+            IMPORTED_LINK_INTERFACE_LANGUAGES CXX
+            IMPORTED_LOCATION "${BOOST_LIB_DIR}/${BOOST_ATOMIC_LIB}"
+        )
+    endif ()
+
+    if (NOT TARGET Boost::context)
+        add_library(Boost::context STATIC IMPORTED)
+        set_target_properties(Boost::context PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${BOOST_SRC}/include"
+            IMPORTED_LINK_INTERFACE_LANGUAGES CXX
+            IMPORTED_LOCATION "${BOOST_LIB_DIR}/${BOOST_CONTEXT_LIB}"
+        )
+    endif ()
+
+    if (NOT TARGET Boost::date_time)
+        add_library(Boost::date_time STATIC IMPORTED)
+        set_target_properties(Boost::date_time PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${BOOST_SRC}/include"
+            IMPORTED_LINK_INTERFACE_LANGUAGES CXX
+            IMPORTED_LOCATION "${BOOST_LIB_DIR}/${BOOST_DATE_TIME_LIB}"
+        )
+    endif ()
+
+    if (NOT TARGET Boost::filesystem)
+        add_library(Boost::filesystem STATIC IMPORTED)
+        set_target_properties(Boost::filesystem PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${BOOST_SRC}/include"
+            IMPORTED_LINK_INTERFACE_LANGUAGES CXX
+            IMPORTED_LOCATION "${BOOST_LIB_DIR}/${BOOST_FILESYSTEM_LIB}"
+        )
+        target_link_libraries(Boost::filesystem INTERFACE Boost::atomic)
+    endif ()
+
+    if(NOT TARGET Boost::process)
+        add_library(Boost::process STATIC IMPORTED)
+        set_target_properties(Boost::process PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${BOOST_SRC}/include"
+            IMPORTED_LINK_INTERFACE_LANGUAGES CXX
+            IMPORTED_LOCATION "${BOOST_LIB_DIR}/${BOOST_PROCESS_LIB}"
+        )
+        target_link_libraries(Boost::process INTERFACE Boost::atomic Boost::context Boost::date_time Boost::filesystem)
+    endif ()
+
+    add_compile_definitions(BOOST_ENABLED)
+    set(BOOST_ENABLED TRUE)
+endif ()

ntgcalls-2.0.9/cmake/FindClang.cmake

@@ -0,0 +1,107 @@
+GetProperty("version.clang" CLANG_VERSION)
+if (LINUX_x86_64 OR MACOS_ARM64 OR ANDROID_ABI)
+    set(CLANG_DIR ${DEPS_DIR}/clang)
+    set(CLANG_LIB_DIR ${CLANG_DIR}/lib)
+    set(CLANG_BIN_DIR ${CLANG_DIR}/bin)
+    set(CLANG_UPDATE ${CLANG_DIR}/update.py)
+    set(CLANG_API_DIR ${CLANG_DIR}/result.xml)
+
+    if (MACOS_ARM64)
+        set(CLANG_OS_PREFIX Mac_arm64)
+    elseif (LINUX_x86_64 OR ANDROID)
+        set(CLANG_OS_PREFIX Linux_x64)
+    endif ()
+
+    if (NOT EXISTS ${CLANG_UPDATE} AND NOT EXISTS ${CLANG_BIN_DIR})
+        GitFile(
+            URL https://chromium.googlesource.com/chromium/src/tools/+/refs/heads/main/clang/scripts/update.py
+            DIRECTORY ${CLANG_UPDATE}
+        )
+        set(URL_BASE "https://commondatastorage.googleapis.com/chromium-browser-clang/?delimiter=/&prefix=${CLANG_OS_PREFIX}/")
+        set(URL_TMP ${URL_BASE})
+        set(BEST_GENERATION 0)
+        set(CLANG_REVISION)
+        set(CLANG_SUB_REVISION)
+
+        while (1)
+            file(DOWNLOAD ${URL_TMP} ${CLANG_API_DIR})
+            file(READ ${CLANG_API_DIR} CLANG_API_CONTENT)
+            PythonFindAllRegex(
+                REGEX "<Key>${CLANG_OS_PREFIX}/clang-(llvmorg-([0-9]+)-[\\w\-]+?)-([0-9]+)\.(tgz|tar\.xz)</Key><Generation>([0-9]+)</Generation>"
+                STRING "${CLANG_API_CONTENT}"
+                VERSIONS
+            )
+            list(LENGTH VERSIONS num_results)
+            math(EXPR VERSIONS_COUNT "${num_results} / 5 - 1")
+            if (num_results GREATER 0)
+                foreach (x RANGE 0 ${VERSIONS_COUNT})
+                    math(EXPR IDX "${x} * 5")
+                    set(CLANG_INFO)
+                    foreach (y RANGE 4)
+                        math(EXPR NEW_IDX "${IDX} + ${y}")
+                        list(GET VERSIONS ${NEW_IDX} TMP_VAR)
+                        list(APPEND CLANG_INFO ${TMP_VAR})
+                    endforeach ()
+                    list(GET CLANG_INFO 0 FOUND_CLANG_REVISION)
+                    list(GET CLANG_INFO 1 FOUND_CLANG_VERSION)
+                    list(GET CLANG_INFO 2 FOUND_CLANG_SUB_REVISION)
+                    list(GET CLANG_INFO 4 GENERATION)
+                    if (${GENERATION} GREATER ${BEST_GENERATION} AND ${FOUND_CLANG_VERSION} STREQUAL ${CLANG_VERSION})
+                        set(BEST_GENERATION ${GENERATION})
+                        set(CLANG_REVISION ${FOUND_CLANG_REVISION})
+                        set(CLANG_SUB_REVISION ${FOUND_CLANG_SUB_REVISION})
+                    endif ()
+                endforeach ()
+            endif ()
+            PythonFindAllRegex(
+                REGEX "<NextMarker>(.*?)</NextMarker>"
+                STRING "${CLANG_API_CONTENT}"
+                NEXT_MARKER
+            )
+            if (NEXT_MARKER)
+                set(URL_TMP "${URL_BASE}&marker=${NEXT_MARKER}")
+            else ()
+                break()
+            endif ()
+        endwhile ()
+        file(REMOVE ${CLANG_API_DIR})
+        file(READ ${CLANG_UPDATE} FILE_CONTENT)
+        PythonFindAllRegex(
+            REGEX "CLANG_REVISION = '.*?'"
+            STRING ${FILE_CONTENT}
+            OLD_CLANG_REVISION
+        )
+        string(REPLACE ${OLD_CLANG_REVISION} "CLANG_REVISION = '${CLANG_REVISION}'" FILE_CONTENT ${FILE_CONTENT})
+        PythonFindAllRegex(
+            REGEX "CLANG_SUB_REVISION = [0-9]+"
+            STRING ${FILE_CONTENT}
+            OLD_CLANG_SUB_REVISION
+        )
+        string(REPLACE ${OLD_CLANG_SUB_REVISION} "CLANG_SUB_REVISION = ${CLANG_SUB_REVISION}" FILE_CONTENT ${FILE_CONTENT})
+        PythonFindAllRegex(
+            REGEX "RELEASE_VERSION = '[0-9]+'"
+            STRING ${FILE_CONTENT}
+            OLD_CLANG_RELEASE
+        )
+        string(REPLACE ${OLD_CLANG_RELEASE} "RELEASE_VERSION = '${CLANG_VERSION}'" FILE_CONTENT ${FILE_CONTENT})
+
+        file(WRITE ${CLANG_UPDATE} ${FILE_CONTENT})
+    endif ()
+
+    if (NOT EXISTS ${CLANG_BIN_DIR})
+        execute_process(
+            COMMAND ${Python_EXECUTABLE} ${CLANG_UPDATE} --output-dir ${CLANG_DIR}
+        )
+    endif ()
+    if (NOT JUST_INSTALL_CLANG)
+        set(CMAKE_AR "${CLANG_BIN_DIR}/llvm-ar")
+        set(CMAKE_STRIP "${CLANG_BIN_DIR}/llvm-strip")
+        set(CMAKE_C_COMPILER "${CLANG_BIN_DIR}/clang")
+        set(CMAKE_CXX_COMPILER "${CLANG_BIN_DIR}/clang++")
+    endif ()
+elseif (LINUX_ARM64)
+    find_program(CMAKE_C_COMPILER NAMES clang-${CLANG_VERSION} clang)
+    find_program(CMAKE_CXX_COMPILER NAMES clang++-${CLANG_VERSION} clang++)
+    find_program(CMAKE_AR NAMES llvm-ar-${CLANG_VERSION} llvm-ar)
+    find_program(CMAKE_STRIP NAMES llvm-strip-${CLANG_VERSION} llvm-strip)
+endif ()

ntgcalls-2.0.9/cmake/FindFFmpeg.cmake

@@ -0,0 +1,130 @@
+set(FFMPEG_DIR ${DEPS_DIR}/ffmpeg)
+set(FFMPEG_SRC ${FFMPEG_DIR}/src)
+set(FFMPEG_GIT https://github.com/pytgcalls/ffmpeg)
+set(FFMPEG_LIB_DIR ${FFMPEG_SRC}/lib)
+if (ANDROID)
+    set(FFMPEG_LIB_DIR ${FFMPEG_LIB_DIR}/${ANDROID_ABI})
+endif ()
+set(AVCODEC_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}avcodec${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(AVFORMAT_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}avformat${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(AVUTIL_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}avutil${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(SWRESAMPLE_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}swresample${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(VA_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}va${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(VA_DRM_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}va-drm${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(VA_X11_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}va-x11${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(VDPAU_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}vdpau${CMAKE_STATIC_LIBRARY_SUFFIX})
+
+if (LINUX_ARM64)
+    set(PLATFORM linux)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH arm64)
+elseif (LINUX_x86_64)
+    set(PLATFORM linux)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH x86_64)
+elseif (MACOS_ARM64)
+    set(PLATFORM macos)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH arm64)
+elseif (WINDOWS_x86_64)
+    set(PLATFORM windows)
+    set(ARCHIVE_FORMAT .zip)
+    set(ARCH x86_64)
+elseif (ANDROID)
+    set(PLATFORM android)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH ${ANDROID_ABI})
+else ()
+    message(STATUS "FFmpeg is not supported on ${CMAKE_SYSTEM_NAME} with ${CMAKE_HOST_SYSTEM_PROCESSOR}")
+    return()
+endif ()
+
+GetProperty("version.ffmpeg" FFMPEG_VERSION)
+message(STATUS "ffmpeg v${FFMPEG_VERSION}")
+
+set(FILE_NAME ffmpeg.${PLATFORM})
+if (NOT ANDROID)
+    set(FILE_NAME ${FILE_NAME}-${ARCH})
+endif ()
+set(FILE_NAME ${FILE_NAME}${ARCHIVE_FORMAT})
+DownloadProject(
+    URL ${FFMPEG_GIT}/releases/download/v${FFMPEG_VERSION}/${FILE_NAME}
+    DOWNLOAD_DIR ${FFMPEG_DIR}/download
+    SOURCE_DIR ${FFMPEG_SRC}
+)
+
+if (LINUX)
+    if (NOT TARGET intel::va-drm)
+        add_library(intel::va-drm STATIC IMPORTED)
+        set_target_properties(intel::va-drm PROPERTIES
+                IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${VA_DRM_LIB}")
+    endif ()
+
+    if (LINUX_x86_64)
+        if (NOT TARGET intel::va-x11)
+            add_library(intel::va-x11 STATIC IMPORTED)
+            set_target_properties(intel::va-x11 PROPERTIES
+                    IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${VA_X11_LIB}")
+        endif ()
+    endif ()
+
+    if (NOT TARGET intel::va)
+        add_library(intel::va STATIC IMPORTED)
+        set_target_properties(intel::va PROPERTIES
+                IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${VA_LIB}")
+    endif ()
+
+    if (NOT TARGET mesa::vdpau)
+        add_library(mesa::vdpau STATIC IMPORTED)
+        set_target_properties(mesa::vdpau PROPERTIES
+                IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${VDPAU_LIB}")
+    endif ()
+endif ()
+
+if(NOT TARGET ffmpeg::avcodec)
+    add_library(ffmpeg::avcodec STATIC IMPORTED)
+    set_target_properties(ffmpeg::avcodec PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${FFMPEG_SRC}/include"
+            IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${AVCODEC_LIB}")
+
+    if (IS_LINUX)
+        set_target_properties(ffmpeg::avcodec PROPERTIES IMPORTED_LINK_INTERFACE_LIBRARIES "-Wl,-Bsymbolic")
+    endif ()
+endif ()
+
+if(NOT TARGET ffmpeg::avformat)
+    add_library(ffmpeg::avformat STATIC IMPORTED)
+    set_target_properties(ffmpeg::avformat PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${FFMPEG_SRC}/include"
+            IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${AVFORMAT_LIB}")
+    target_link_libraries(ffmpeg::avformat INTERFACE ffmpeg::avcodec)
+
+    if (IS_LINUX)
+        set_target_properties(ffmpeg::avformat PROPERTIES IMPORTED_LINK_INTERFACE_LIBRARIES "-Wl,-Bsymbolic")
+    endif ()
+endif ()
+
+if(NOT TARGET ffmpeg::avutil)
+    add_library(ffmpeg::avutil STATIC IMPORTED)
+    set_target_properties(ffmpeg::avutil PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${FFMPEG_SRC}/include"
+            IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${AVUTIL_LIB}")
+    if (LINUX AND NOT ANDROID)
+        target_link_libraries(ffmpeg::avutil INTERFACE xorg::X11 mesa::vdpau intel::va intel::va-drm mesa::drm)
+        if (LINUX_x86_64)
+            target_link_libraries(ffmpeg::avutil INTERFACE intel::va-x11)
+        endif ()
+        set_target_properties(ffmpeg::avutil PROPERTIES IMPORTED_LINK_INTERFACE_LIBRARIES "-Wl,-Bsymbolic")
+    endif ()
+endif ()
+
+if (NOT TARGET ffmpeg::swresample)
+    add_library(ffmpeg::swresample STATIC IMPORTED)
+    set_target_properties(ffmpeg::swresample PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${FFMPEG_SRC}/include"
+            IMPORTED_LOCATION "${FFMPEG_LIB_DIR}/${SWRESAMPLE_LIB}")
+
+    if (IS_LINUX)
+        set_target_properties(ffmpeg::swresample PROPERTIES IMPORTED_LINK_INTERFACE_LIBRARIES "-Wl,-Bsymbolic")
+    endif ()
+endif ()

ntgcalls-2.0.9/cmake/FindLibCXX.cmake

@@ -0,0 +1,31 @@
+set(LIBCXX_INCLUDE ${DEPS_DIR}/libcxx)
+set(LIBCXXABI_INCLUDE ${DEPS_DIR}/libcxxabi)
+
+if((LINUX OR MACOS OR ANDROID) AND USE_LIBCXX)
+    GitClone(
+        URL https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxx.git
+        COMMIT ${LIBCXX_COMMIT}
+        DIRECTORY ${LIBCXX_INCLUDE}
+    )
+    GitFile(
+        URL https://chromium.googlesource.com/chromium/src/buildtools.git/+/${BUILDTOOLS_COMMIT}/third_party/libc++/__config_site
+        DIRECTORY ${LIBCXX_INCLUDE}/include/__config_site
+    )
+    GitFile(
+        URL https://chromium.googlesource.com/chromium/src/buildtools.git/+/${BUILDTOOLS_COMMIT}/third_party/libc++/__assertion_handler
+        DIRECTORY ${LIBCXX_INCLUDE}/include/__assertion_handler
+    )
+    GitClone(
+        URL https://chromium.googlesource.com/external/github.com/llvm/llvm-project/libcxxabi.git
+        COMMIT ${LIBCXX_ABI_COMMIT}
+        DIRECTORY ${LIBCXXABI_INCLUDE}
+    )
+    add_compile_options(
+        "$<$<COMPILE_LANGUAGE:CXX>:-nostdinc++>"
+        "$<$<AND:$<COMPILE_LANGUAGE:CXX>,$<BOOL:LIBCXX_INCLUDE_DIR>>:-isystem${LIBCXX_INCLUDE}/include>"
+        "$<$<AND:$<COMPILE_LANGUAGE:CXX>,$<BOOL:LIBCXXABI_INCLUDE_DIR>>:-isystem${LIBCXXABI_INCLUDE}/include>"
+        "$<$<COMPILE_LANGUAGE:OBJCXX>:-nostdinc++>"
+        "$<$<AND:$<COMPILE_LANGUAGE:OBJCXX>,$<BOOL:LIBCXX_INCLUDE_DIR>>:-isystem${LIBCXX_INCLUDE}/include>"
+        "$<$<AND:$<COMPILE_LANGUAGE:OBJCXX>,$<BOOL:LIBCXXABI_INCLUDE_DIR>>:-isystem${LIBCXXABI_INCLUDE}/include>"
+    )
+endif ()

ntgcalls-2.0.9/cmake/FindMesa.cmake

@@ -0,0 +1,42 @@
+set(MESA_DIR ${DEPS_DIR}/mesa)
+set(MESA_SRC ${MESA_DIR}/src)
+set(MESA_GIT https://github.com/pytgcalls/mesa)
+set(GBM_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}gbm${CMAKE_STATIC_LIBRARY_SUFFIX})
+set(DRM_LIB ${CMAKE_STATIC_LIBRARY_PREFIX}drm${CMAKE_STATIC_LIBRARY_SUFFIX})
+
+if (LINUX_ARM64)
+    set(PLATFORM linux)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH arm64)
+elseif (LINUX_x86_64)
+    set(PLATFORM linux)
+    set(ARCHIVE_FORMAT .tar.gz)
+    set(ARCH x86_64)
+else ()
+    return()
+endif ()
+
+GetProperty("version.mesa" MESA_VERSION)
+message(STATUS "mesa v${MESA_VERSION}")
+
+set(FILE_NAME mesa.${PLATFORM}-${ARCH}${ARCHIVE_FORMAT})
+DownloadProject(
+    URL ${MESA_GIT}/releases/download/v${MESA_VERSION}/${FILE_NAME}
+    DOWNLOAD_DIR ${MESA_DIR}/download
+    SOURCE_DIR ${MESA_SRC}
+)
+
+if(NOT TARGET mesa::drm)
+    add_library(mesa::drm STATIC IMPORTED)
+    set_target_properties(mesa::drm PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${MESA_SRC}/include"
+            IMPORTED_LOCATION "${MESA_SRC}/lib/${DRM_LIB}")
+endif ()
+
+if(NOT TARGET mesa::gbm)
+    add_library(mesa::gbm STATIC IMPORTED)
+    set_target_properties(mesa::gbm PROPERTIES
+            INTERFACE_INCLUDE_DIRECTORIES "${MESA_SRC}/include"
+            IMPORTED_LOCATION "${MESA_SRC}/lib/${GBM_LIB}")
+    target_link_libraries(mesa::gbm INTERFACE gnu::expat mesa::drm)
+endif ()