multipers 2.5.0b2__tar.gz → 2.5.0b4__tar.gz

multipers-2.5.0b4/CMakeLists.txt

@@ -0,0 +1,28 @@
+cmake_minimum_required(VERSION 3.24)
+project(multipers LANGUAGES C CXX)
+
+if(POLICY CMP0167)
+  cmake_policy(SET CMP0167 NEW)
+endif()
+
+set(CMAKE_CXX_STANDARD 20)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_POSITION_INDEPENDENT_CODE ON)
+set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
+set(CMAKE_COLOR_DIAGNOSTICS ON)
+
+if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
+  add_compile_options(
+    $<$<COMPILE_LANGUAGE:C>:-fdiagnostics-color=always>
+    $<$<COMPILE_LANGUAGE:CXX>:-fdiagnostics-color=always>
+  )
+endif()
+
+if(MSVC)
+  add_compile_options(/bigobj)
+endif()
+
+include("${CMAKE_SOURCE_DIR}/cmake/MultipersDependencies.cmake")
+include("${CMAKE_SOURCE_DIR}/cmake/MultipersCodegen.cmake")
+include("${CMAKE_SOURCE_DIR}/cmake/MultipersBuild.cmake")
+include("${CMAKE_SOURCE_DIR}/cmake/MultipersInstall.cmake")

{multipers-2.5.0b2 → multipers-2.5.0b4}/PKG-INFO

@@ -1,6 +1,6 @@
 Metadata-Version: 2.4
 Name: multipers
-Version: 2.5.0b2
+Version: 2.5.0b4
 Summary: Multiparameter Topological Persistence for Machine Learning
 Keywords: TDA,Persistence,Multiparameter,sklearn,autodiff
 Author-Email: David Loiseaux <david.lapous@proton.me>, Hannah Schreiber <hannah.schreiber@inria.fr>

{multipers-2.5.0b2 → multipers-2.5.0b4}/THIRD_PARTY_NOTICES.md

@@ -24,6 +24,12 @@ As a result, distributed `multipers` artifacts built with these components are l
   - Commit used in this workspace: `a481f8d90af7a97795c467d81fb3db2cf952a58e`
   - License: GPL-3.0-or-later (see upstream `COPYING`)
 
+- `rhomboidtiling_newer_cgal_version`
+  - Upstream: https://github.com/DavidLapous/rhomboidtiling_newer_cgal_version
+  - Header/source path used at build time: `ext/rhomboidtiling_newer_cgal_version`
+  - Commit used in this workspace: `c414cdc60f30196ffd3ce5cda1817368655905f0`
+  - License: MIT (see `ext/rhomboidtiling_newer_cgal_version/LICENSE.md`)
+
 - `mpfree`
   - Upstream: https://bitbucket.org/mkerber/mpfree/
   - Header source path used at build time: `ext/mpfree`
@@ -42,6 +48,12 @@ As a result, distributed `multipers` artifacts built with these components are l
   - Commit used in this workspace: `d686f7efe623169f00951c376949b8bb30448eaf`
   - License: LGPL-3.0-or-later (see upstream `COPYING.LESSER`)
 
+- `PHAT`
+  - Upstream: https://github.com/xoltar/phat
+  - Header source path used at build time: `ext/phat/include`
+  - Commit used in this workspace: `872ca92b33ebe92dff2542cbdee6768e575e80aa`
+  - License: LGPL-3.0-or-later (see `ext/phat/COPYING.LESSER`)
+
 ## Notes
 
 - Build-time include paths for these dependencies are configured in `CMakeLists.txt`.

multipers-2.5.0b4/_tempita_grid_gen.py

@@ -0,0 +1,6 @@
+"""Compatibility entrypoint for Tempita grid generation.
+
+The implementation lives in tools/tempita_grid_gen.py.
+"""
+
+from tools.tempita_grid_gen import *  # noqa: F401,F403

multipers-2.5.0b4/cmake/MultipersBuild.cmake

@@ -0,0 +1,410 @@
+include_guard(GLOBAL)
+
+function(multipers_apply_common_build_flags target_name)
+  target_compile_definitions(
+    ${target_name}
+    PRIVATE
+      NPY_NO_DEPRECATED_API=NPY_1_7_API_VERSION
+      GUDHI_USE_TBB
+      WITH_TBB=ON
+  )
+
+  if(WIN32)
+    target_compile_definitions(
+      ${target_name}
+      PRIVATE
+        MULTIPERS_DISABLE_MPFREE_INTERFACE=1
+        MULTIPERS_DISABLE_FUNCTION_DELAUNAY_INTERFACE=1
+        MULTIPERS_DISABLE_MULTI_CRITICAL_INTERFACE=1
+        MULTIPERS_DISABLE_RHOMBOID_TILING_INTERFACE=1
+    )
+  endif()
+
+  if(NOT MULTIPERS_HAS_FLAT_FILTRATION_CONTAINER)
+    target_compile_definitions(
+      ${target_name}
+      PRIVATE
+        MULTIPERS_DISABLE_MULTI_CRITICAL_INTERFACE=1
+    )
+  endif()
+
+  if(NOT CGAL_FOUND)
+    target_compile_definitions(
+      ${target_name}
+      PRIVATE
+        MULTIPERS_DISABLE_RHOMBOID_TILING_INTERFACE=1
+    )
+  endif()
+
+  if(MSVC)
+    target_compile_options(${target_name} PRIVATE /O2 /DNDEBUG /W1 /WX- /openmp)
+  else()
+    target_compile_options(
+      ${target_name}
+      PRIVATE
+        -O3
+        -fassociative-math
+        -funsafe-math-optimizations
+        -DNDEBUG
+        -Wall
+        -Wextra
+        -Wno-assume
+    )
+  endif()
+endfunction()
+
+function(multipers_link_openmp target_name)
+  target_link_libraries(${target_name} PRIVATE OpenMP::OpenMP_CXX)
+endfunction()
+
+function(multipers_link_tbb target_name)
+  if(TARGET TBB::tbb)
+    target_link_libraries(${target_name} PRIVATE TBB::tbb)
+  elseif(TARGET TBB::tbb_static)
+    target_link_libraries(${target_name} PRIVATE TBB::tbb_static)
+  else()
+    message(FATAL_ERROR "TBB target not found")
+  endif()
+endfunction()
+
+set(MULTIPERS_SHARED_CORE_MODULES
+  simplex_tree_multi
+  slicer
+  mma_structures
+  multiparameter_module_approximation
+  _mpfree_interface
+  _function_delaunay_interface
+  _multi_critical_interface
+  _rhomboid_tiling_interface
+)
+
+set(MULTIPERS_BOOST_MODULES
+  _aida_interface
+  _mpfree_interface
+  _multi_critical_interface
+  _function_delaunay_interface
+)
+
+set(MULTIPERS_GMP_MODULE
+  _aida_interface
+  _mpfree_interface
+  _multi_critical_interface
+  _function_delaunay_interface
+  _rhomboid_tiling_interface
+)
+
+set(MULTIPERS_GMP_MODULES ${MULTIPERS_GMP_MODULE})
+
+set(MULTIPERS_OPENMP_MODULES
+  _aida_interface
+  _mpfree_interface
+  _multi_critical_interface
+  _function_delaunay_interface
+)
+
+set(MULTIPERS_TBB_MODULES
+  simplex_tree_multi
+  function_rips
+  mma_structures
+  multiparameter_module_approximation
+  point_measure
+  grids
+  slicer
+  _mpfree_interface
+  _function_delaunay_interface
+  _multi_critical_interface
+  _rhomboid_tiling_interface
+)
+
+set(MULTIPERS_MODULE_INCLUDE_DIR_MAP
+  _aida_interface MULTIPERS_AIDA_INCLUDE_DIRS
+  _mpfree_interface MULTIPERS_MPFREE_INCLUDE_DIRS
+  _multi_critical_interface MULTIPERS_MULTI_CRITICAL_INCLUDE_DIRS
+  _function_delaunay_interface MULTIPERS_FUNCTION_DELAUNAY_INCLUDE_DIRS
+  _rhomboid_tiling_interface MULTIPERS_RHOMBOID_TILING_INCLUDE_DIRS
+)
+
+set(MULTIPERS_FORKED_PHAT_MODULES
+  _aida_interface
+  _mpfree_interface
+  _multi_critical_interface
+  _function_delaunay_interface
+)
+
+set(MULTIPERS_GENERATED_INCLUDE_DIRS
+  "${MULTIPERS_GENERATED_ROOT}/multipers"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/gudhi"
+  "${MULTIPERS_GENERATED_ROOT}/tools/core"
+)
+
+function(multipers_add_core_object_library target_name source_file)
+  add_library(${target_name} OBJECT "${source_file}")
+  add_dependencies(${target_name} multipers_tempita ${ARGN})
+  target_include_directories(
+    ${target_name}
+    PRIVATE
+      ${MULTIPERS_GENERATED_INCLUDE_DIRS}
+      ${MULTIPERS_BASE_INCLUDE_DIRS}
+      ${MULTIPERS_PHAT_INCLUDE_DIRS}
+  )
+  multipers_apply_common_build_flags(${target_name})
+endfunction()
+
+multipers_add_core_object_library(
+  multipers_core_filtrations_obj
+  "${CMAKE_SOURCE_DIR}/tools/core/filtrations_core.cc"
+)
+
+multipers_add_core_object_library(
+  multipers_core_simplextree_obj
+  "${CMAKE_SOURCE_DIR}/tools/core/simplextree_core.cc"
+  multipers_core_filtrations_obj
+)
+
+multipers_add_core_object_library(
+  multipers_core_slicer_obj
+  "${CMAKE_SOURCE_DIR}/tools/core/slicer_core.cc"
+  multipers_core_filtrations_obj
+)
+
+add_library(
+  multipers_core_shared
+  SHARED
+  $<TARGET_OBJECTS:multipers_core_filtrations_obj>
+  $<TARGET_OBJECTS:multipers_core_simplextree_obj>
+  $<TARGET_OBJECTS:multipers_core_slicer_obj>
+)
+add_dependencies(multipers_core_shared multipers_tempita)
+multipers_link_tbb(multipers_core_shared)
+
+set(MULTIPERS_LOCAL_RPATH "")
+if(APPLE)
+  set(MULTIPERS_LOCAL_RPATH "@loader_path")
+elseif(UNIX)
+  set(MULTIPERS_LOCAL_RPATH "$ORIGIN")
+endif()
+
+set_target_properties(multipers_core_shared PROPERTIES OUTPUT_NAME "multipers_core")
+if(WIN32)
+  set_target_properties(multipers_core_shared PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS ON)
+endif()
+if(MULTIPERS_LOCAL_RPATH)
+  set_target_properties(
+    multipers_core_shared
+    PROPERTIES
+      BUILD_RPATH "${MULTIPERS_LOCAL_RPATH}"
+      INSTALL_RPATH "${MULTIPERS_LOCAL_RPATH}"
+  )
+endif()
+if(APPLE)
+  set_target_properties(
+    multipers_core_shared
+    PROPERTIES
+      INSTALL_NAME_DIR "@rpath"
+      SUFFIX ".so"
+  )
+endif()
+
+function(multipers_link_shared_core target_name)
+  target_link_libraries(${target_name} PRIVATE multipers_core_shared)
+  if(MULTIPERS_LOCAL_RPATH)
+    set_property(TARGET ${target_name} APPEND PROPERTY BUILD_RPATH "${MULTIPERS_LOCAL_RPATH}")
+    set_property(TARGET ${target_name} APPEND PROPERTY INSTALL_RPATH "${MULTIPERS_LOCAL_RPATH}")
+  endif()
+endfunction()
+
+function(multipers_configure_extension_include_dirs module_name target_name)
+  list(LENGTH MULTIPERS_MODULE_INCLUDE_DIR_MAP include_dir_map_length)
+  if(include_dir_map_length GREATER 1)
+    math(EXPR include_dir_map_last "${include_dir_map_length} - 2")
+    foreach(i RANGE 0 ${include_dir_map_last} 2)
+      math(EXPR j "${i} + 1")
+      list(GET MULTIPERS_MODULE_INCLUDE_DIR_MAP ${i} include_module)
+      list(GET MULTIPERS_MODULE_INCLUDE_DIR_MAP ${j} include_var)
+      if("${module_name}" STREQUAL "${include_module}")
+        target_include_directories(${target_name} PRIVATE ${${include_var}})
+        break()
+      endif()
+    endforeach()
+  endif()
+
+  list(FIND MULTIPERS_FORKED_PHAT_MODULES "${module_name}" uses_forked_phat)
+  if(uses_forked_phat EQUAL -1)
+    target_include_directories(${target_name} BEFORE PRIVATE ${MULTIPERS_PHAT_INCLUDE_DIRS})
+  endif()
+  set_target_properties(${target_name} PROPERTIES COMPILE_FLAGS "--no-warnings")
+endfunction()
+
+function(multipers_configure_extension_backend module_name target_name)
+  if(module_name STREQUAL "_aida_interface" AND WIN32)
+    message(FATAL_ERROR "AIDA backend is not supported on Windows")
+  endif()
+
+  list(FIND MULTIPERS_BOOST_MODULES "${module_name}" uses_boost)
+  if(NOT uses_boost EQUAL -1)
+    target_link_libraries(${target_name} PRIVATE Boost::system Boost::timer Boost::chrono)
+  endif()
+
+  list(FIND MULTIPERS_GMP_MODULE "${module_name}" uses_gmp)
+  if(NOT uses_gmp EQUAL -1)
+    target_link_libraries(${target_name} PRIVATE "${MULTIPERS_GMP_LIBRARY}")
+  endif()
+
+  if(module_name STREQUAL "_aida_interface")
+    target_link_libraries(${target_name} PRIVATE multipers_aida_static)
+  endif()
+
+  if(module_name STREQUAL "_rhomboid_tiling_interface")
+    if(NOT MSVC)
+      target_compile_options(
+        ${target_name}
+        PRIVATE
+          -fno-associative-math
+          -fno-unsafe-math-optimizations
+      )
+    endif()
+    if(TARGET multipers_rhomboid_tiling_static)
+      target_link_libraries(${target_name} PRIVATE multipers_rhomboid_tiling_static)
+    endif()
+    if(TARGET CGAL::CGAL)
+      target_link_libraries(${target_name} PRIVATE CGAL::CGAL)
+    endif()
+    if(TARGET CGAL::CGAL_Core)
+      target_link_libraries(${target_name} PRIVATE CGAL::CGAL_Core)
+    endif()
+  endif()
+
+  list(FIND MULTIPERS_OPENMP_MODULES "${module_name}" uses_openmp)
+  if(NOT uses_openmp EQUAL -1)
+    multipers_link_openmp(${target_name})
+  endif()
+
+  list(FIND MULTIPERS_TBB_MODULES "${module_name}" uses_tbb)
+  if(NOT uses_tbb EQUAL -1)
+    multipers_link_tbb(${target_name})
+  endif()
+endfunction()
+
+function(multipers_add_extension module_name)
+  string(REPLACE "." "/" module_path "${module_name}")
+  set(source_pyx_file "${CMAKE_SOURCE_DIR}/multipers/${module_path}.pyx")
+  set(generated_pyx_file "${MULTIPERS_GENERATED_ROOT}/multipers/${module_path}.pyx")
+  set(pyx_template "${CMAKE_SOURCE_DIR}/multipers/${module_path}.pyx.tp")
+  if(EXISTS "${pyx_template}")
+    set(pyx_file "${generated_pyx_file}")
+  elseif(EXISTS "${source_pyx_file}")
+    set(pyx_file "${source_pyx_file}")
+  else()
+    message(FATAL_ERROR "Missing Cython source/template: ${source_pyx_file}")
+  endif()
+
+  set(cpp_file "${CMAKE_BINARY_DIR}/cython/${module_path}.cpp")
+  set(dep_file "${cpp_file}.dep")
+  get_filename_component(cpp_dir "${cpp_file}" DIRECTORY)
+
+  add_custom_command(
+    OUTPUT "${cpp_file}"
+    COMMAND "${CMAKE_COMMAND}" -E make_directory "${cpp_dir}"
+    COMMAND "${Python3_EXECUTABLE}" -m cython ${MULTIPERS_CYTHON_COMMON_ARGS} -M "${pyx_file}" -o "${cpp_file}"
+    DEPENDS "${pyx_file}" ${MULTIPERS_GENERATED_FILES}
+    DEPFILE "${dep_file}"
+    WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
+    VERBATIM
+  )
+
+  string(REPLACE "." "_" target_name "multipers_${module_name}")
+  Python3_add_library(${target_name} MODULE WITH_SOABI "${cpp_file}")
+  add_dependencies(${target_name} multipers_tempita)
+  set_target_properties(${target_name} PROPERTIES PREFIX "")
+
+  target_include_directories(
+    ${target_name}
+    PRIVATE
+      ${MULTIPERS_GENERATED_INCLUDE_DIRS}
+      ${MULTIPERS_BASE_INCLUDE_DIRS}
+  )
+  multipers_apply_common_build_flags(${target_name})
+
+  list(FIND MULTIPERS_SHARED_CORE_MODULES "${module_name}" uses_shared_core)
+  if(NOT uses_shared_core EQUAL -1)
+    multipers_link_shared_core(${target_name})
+  endif()
+
+  multipers_configure_extension_include_dirs("${module_name}" ${target_name})
+  multipers_configure_extension_backend("${module_name}" ${target_name})
+
+  set(output_name "${module_name}")
+  set(package_dir "multipers")
+
+  set_target_properties(${target_name} PROPERTIES OUTPUT_NAME "${output_name}")
+  if(WIN32)
+    install(TARGETS ${target_name}
+    LIBRARY DESTINATION "${package_dir}"
+    RUNTIME DESTINATION "${package_dir}"
+    ARCHIVE DESTINATION "${package_dir}"
+  )
+
+    install(CODE "
+      message(STATUS \"Bundling runtime deps for: $<TARGET_FILE:${target_name}>\")
+      file(GET_RUNTIME_DEPENDENCIES
+        RESOLVED_DEPENDENCIES_VAR deps
+        UNRESOLVED_DEPENDENCIES_VAR unresolved
+        CONFLICTING_DEPENDENCIES_PREFIX conflict
+        MODULES \"$<TARGET_FILE:${target_name}>\"
+        DIRECTORIES
+          \"\$ENV{CONDA_PREFIX}/Library/bin\"
+          \"\$ENV{CONDA_PREFIX}/bin\"
+        POST_EXCLUDE_REGEXES
+          \".*[Ww]indows[/\\\\][Ss]ystem32[/\\\\].*\"
+          \"api-ms-win-.*\"
+          \"ext-ms-.*\"
+      )
+
+      foreach(dep IN LISTS deps)
+        file(INSTALL
+          DESTINATION \"\${CMAKE_INSTALL_PREFIX}/${package_dir}\"
+          TYPE SHARED_LIBRARY
+          FILES \"\${dep}\"
+        )
+      endforeach()
+
+      foreach(dep IN LISTS unresolved)
+        message(WARNING \"Unresolved dependency: \${dep}\")
+      endforeach()
+    ")
+  else()
+    install(TARGETS ${target_name}
+    LIBRARY DESTINATION "${package_dir}"
+  )
+  endif()
+endfunction()
+
+set(MULTIPERS_MODULES
+  simplex_tree_multi
+  io
+  function_rips
+  mma_structures
+  multiparameter_module_approximation
+  point_measure
+  grids
+  slicer
+  ops
+  _mpfree_interface
+  _aida_interface
+  _function_delaunay_interface
+  _multi_critical_interface
+  _rhomboid_tiling_interface
+)
+
+if(WIN32)
+  list(REMOVE_ITEM MULTIPERS_MODULES
+    _aida_interface
+    # _mpfree_interface
+    # _function_delaunay_interface
+    # _multi_critical_interface
+  )
+endif()
+
+foreach(module_name IN LISTS MULTIPERS_MODULES)
+  multipers_add_extension(${module_name})
+endforeach()

multipers-2.5.0b4/cmake/MultipersCodegen.cmake

@@ -0,0 +1,125 @@
+include_guard(GLOBAL)
+
+set(MULTIPERS_GENERATED_ROOT "${CMAKE_BINARY_DIR}/generated")
+set(MULTIPERS_TEMPITA_CACHE_DIR "${CMAKE_BINARY_DIR}/tmp")
+
+set(MULTIPERS_TEMPLATE_FILES
+  "${CMAKE_SOURCE_DIR}/multipers/filtrations.pxd.tp"
+  "${CMAKE_SOURCE_DIR}/multipers/filtration_conversions.pxd.tp"
+  "${CMAKE_SOURCE_DIR}/multipers/slicer.pxd.tp"
+  "${CMAKE_SOURCE_DIR}/multipers/mma_structures.pyx.tp"
+  "${CMAKE_SOURCE_DIR}/multipers/multiparameter_module_approximation.pyx.tp"
+  "${CMAKE_SOURCE_DIR}/multipers/simplex_tree_multi.pyx.tp"
+  "${CMAKE_SOURCE_DIR}/multipers/slicer.pyx.tp"
+)
+
+set(MULTIPERS_GENERATED_FILES
+  "${MULTIPERS_GENERATED_ROOT}/multipers/filtrations.pxd"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/filtration_conversions.pxd"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/slicer.pxd"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/mma_structures.pyx"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/multiparameter_module_approximation.pyx"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/simplex_tree_multi.pyx"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/slicer.pyx"
+)
+
+set(MULTIPERS_CORE_GENERATED_FILES
+  "${MULTIPERS_GENERATED_ROOT}/tools/core/filtrations_instantiations.inc"
+  "${MULTIPERS_GENERATED_ROOT}/tools/core/simplextree_instantiations.inc"
+  "${MULTIPERS_GENERATED_ROOT}/tools/core/slicer_instantiations.inc"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/gudhi/filtrations_extern_templates.h"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/gudhi/simplextree_multi_extern_templates.h"
+  "${MULTIPERS_GENERATED_ROOT}/multipers/gudhi/slicer_extern_templates.h"
+)
+
+set(MULTIPERS_TEMPITA_GRID_GEN "${CMAKE_SOURCE_DIR}/tools/tempita_grid_gen.py")
+
+execute_process(
+  COMMAND
+    "${Python3_EXECUTABLE}" "-c"
+    "import importlib.util, pathlib; spec = importlib.util.spec_from_file_location('multipers_user_options', pathlib.Path(r'${CMAKE_SOURCE_DIR}') / 'options.py'); mod = importlib.util.module_from_spec(spec); spec.loader.exec_module(mod); print('1' if 'Degree_rips_bifiltration' in getattr(mod, 'FILTRATION_CONTAINERS', ()) else '0')"
+  RESULT_VARIABLE MULTIPERS_FLAT_CONTAINER_DETECT_RESULT
+  OUTPUT_VARIABLE MULTIPERS_HAS_FLAT_CONTAINER_RAW
+  OUTPUT_STRIP_TRAILING_WHITESPACE
+  ERROR_VARIABLE MULTIPERS_FLAT_CONTAINER_DETECT_ERROR
+)
+
+if(NOT MULTIPERS_FLAT_CONTAINER_DETECT_RESULT EQUAL 0)
+  message(
+    FATAL_ERROR
+      "Failed to detect FILTRATION_CONTAINERS from options.py: ${MULTIPERS_FLAT_CONTAINER_DETECT_ERROR}"
+  )
+endif()
+
+set(MULTIPERS_HAS_FLAT_FILTRATION_CONTAINER OFF)
+if(MULTIPERS_HAS_FLAT_CONTAINER_RAW STREQUAL "1")
+  set(MULTIPERS_HAS_FLAT_FILTRATION_CONTAINER ON)
+endif()
+
+message(
+  STATUS
+    "MULTIPERS_HAS_FLAT_FILTRATION_CONTAINER=${MULTIPERS_HAS_FLAT_FILTRATION_CONTAINER}"
+)
+
+option(
+  MULTIPERS_TEMPITA_GRID_VERBOSE
+  "Enable verbose Tempita grid generation logs"
+  OFF
+)
+
+if(MULTIPERS_TEMPITA_GRID_VERBOSE)
+  set(MULTIPERS_TEMPITA_GRID_VERBOSE_VALUE "1")
+else()
+  set(MULTIPERS_TEMPITA_GRID_VERBOSE_VALUE "0")
+endif()
+
+add_custom_command(
+  OUTPUT ${MULTIPERS_GENERATED_FILES} ${MULTIPERS_CORE_GENERATED_FILES}
+  COMMAND "${CMAKE_COMMAND}" -E make_directory "${MULTIPERS_GENERATED_ROOT}"
+  COMMAND "${CMAKE_COMMAND}" -E make_directory "${MULTIPERS_TEMPITA_CACHE_DIR}"
+  COMMAND
+    "${CMAKE_COMMAND}" -E env
+    "MULTIPERS_TEMPITA_GRID_VERBOSE=${MULTIPERS_TEMPITA_GRID_VERBOSE_VALUE}"
+    "MULTIPERS_TEMPITA_GRID_OUTPUT_ROOT=${MULTIPERS_GENERATED_ROOT}"
+    "MULTIPERS_TEMPITA_CACHE_DIR=${MULTIPERS_TEMPITA_CACHE_DIR}"
+    "${Python3_EXECUTABLE}" "${MULTIPERS_TEMPITA_GRID_GEN}"
+  COMMAND
+    "${CMAKE_COMMAND}" -E env
+    "MULTIPERS_TEMPITA_CACHE_DIR=${MULTIPERS_TEMPITA_CACHE_DIR}"
+    "${Python3_EXECUTABLE}" "${CMAKE_SOURCE_DIR}/tools/process_tempita.py"
+    --source-root "${CMAKE_SOURCE_DIR}"
+    --output-root "${MULTIPERS_GENERATED_ROOT}"
+    ${MULTIPERS_TEMPLATE_FILES}
+  DEPENDS
+    "${MULTIPERS_TEMPITA_GRID_GEN}"
+    "${CMAKE_SOURCE_DIR}/options.py"
+    "${CMAKE_SOURCE_DIR}/tools/codegen/_registry.py"
+    "${CMAKE_SOURCE_DIR}/tools/process_tempita.py"
+    ${MULTIPERS_TEMPLATE_FILES}
+  WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
+  VERBATIM
+)
+
+add_custom_target(multipers_tempita DEPENDS ${MULTIPERS_GENERATED_FILES} ${MULTIPERS_CORE_GENERATED_FILES})
+
+set(MULTIPERS_CYTHON_COMMON_ARGS
+  --cplus
+  --fast-fail
+  --directive language_level=3
+  --directive embedsignature=True
+  --directive embedsignature.format=python
+  --directive binding=True
+  --directive infer_types=True
+  --directive boundscheck=False
+  --directive wraparound=True
+  --directive iterable_coroutine=True
+  --directive annotation_typing=True
+  --directive emit_code_comments=True
+  --directive initializedcheck=False
+  --directive cdivision=True
+  --directive profile=False
+  -I "${MULTIPERS_GENERATED_ROOT}"
+  -I "${MULTIPERS_GENERATED_ROOT}/multipers"
+  -I "${CMAKE_SOURCE_DIR}"
+  -I "${CMAKE_SOURCE_DIR}/multipers"
+)