mdz 0.4.0__tar.gz

mdz-0.4.0/.clang-format

@@ -0,0 +1,8 @@
+BasedOnStyle: Google
+IndentWidth: 4
+ColumnLimit: 120
+AccessModifierOffset: -4
+AllowShortFunctionsOnASingleLine: All
+DerivePointerAlignment: false
+PointerAlignment: Left
+SortIncludes: Never

mdz-0.4.0/.gitattributes

@@ -0,0 +1,9 @@
+*.dcd binary
+*.mdz binary
+*.xtc binary
+*.npy binary
+
+# Reference files are compared byte for byte; never convert their line endings.
+tests/cpp/fixtures/** -text
+tests/cpp/golden/** -text
+examples/** -text

mdz-0.4.0/.gitignore

@@ -0,0 +1,37 @@
+# Build artifacts
+dist/
+*.egg-info/
+
+# Python
+uv.lock
+__pycache__/
+*.pyc
+*.pyo
+.venv/
+.pytest_cache/
+
+# Compiled extensions
+*.so
+*.pyd
+*.dylib
+
+# IDE / editor
+.vscode/
+.idea/
+*.swp
+*.swo
+
+# Large data directories
+examples/olivine_nvt/
+
+# Generated example outputs
+test.mdz
+examples/*.mdz
+examples/*.xyz
+examples/*.extxyz
+
+# macOS
+.DS_Store
+
+# CMake build trees
+build*/

mdz-0.4.0/CITATION.cff

@@ -0,0 +1,23 @@
+cff-version: 1.2.0
+message: "If you use mdz in your research, please cite it using these metadata."
+type: software
+title: "mdz: molecular dynamics trajectory compression with fast random access"
+abstract: >-
+  mdz compresses molecular dynamics trajectories (positions, velocities,
+  forces and per-frame data) using inter-frame prediction, adaptive
+  quantization and zstd, in groups of frames that are individually indexed
+  for fast random access. It provides a C++ library, a command-line tool,
+  Python bindings, a C API and a LAMMPS dump style.
+authors:
+  - family-names: Spackman
+    given-names: Peter
+    email: peterspackman@fastmail.com
+repository-code: "https://github.com/peterspackman/mdz"
+url: "https://github.com/peterspackman/mdz"
+license: MIT
+version: 0.4.0
+keywords:
+  - molecular dynamics
+  - trajectory
+  - compression
+  - random access

mdz-0.4.0/CMakeLists.txt

@@ -0,0 +1,178 @@
+cmake_minimum_required(VERSION 3.18)
+project(mdz VERSION 0.4.0 LANGUAGES C CXX)
+
+# When mdz is built on its own it is the top-level project. When another
+# project includes it with add_subdirectory, only the library is built.
+if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
+  set(MDZ_TOP_LEVEL ON)
+else()
+  set(MDZ_TOP_LEVEL OFF)
+endif()
+
+option(MDZ_BUILD_CLI "Build the mdz command-line tool" ${MDZ_TOP_LEVEL})
+option(MDZ_BUILD_TESTS "Build the C++ tests" ${MDZ_TOP_LEVEL})
+option(MDZ_BUILD_BENCH "Build the benchmarks" ${MDZ_TOP_LEVEL})
+option(MDZ_BUILD_PYTHON "Build the Python extension (nanobind)" OFF)
+option(MDZ_UNITY_BUILD "Compile the library as a few large translation units" OFF)
+option(MDZ_FUZZ "Build the fuzz targets (libFuzzer with clang)" OFF)
+option(MDZ_SANITIZE "Build with address and undefined-behaviour sanitizers" OFF)
+set(MDZ_ZSTD "fetch" CACHE STRING "Where zstd comes from: fetch (build 1.5.7 from source) or system")
+set_property(CACHE MDZ_ZSTD PROPERTY STRINGS fetch system)
+
+if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
+  set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type" FORCE)
+endif()
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_CXX_EXTENSIONS OFF)
+set(CMAKE_POSITION_INDEPENDENT_CODE ON)
+
+include(cmake/zstd.cmake)
+include(cmake/deps.cmake)
+
+# ---- library ---------------------------------------------------------------
+
+set(MDZ_SOURCES
+  src/bytes.cpp
+  src/codec.cpp
+  src/column.cpp
+  src/columns.cpp
+  src/container.cpp
+  src/crc32.cpp
+  src/error.cpp
+  src/file_io.cpp
+  src/frame_batch.cpp
+  src/kernels.cpp
+  src/library.cpp
+  src/mapped_file.cpp
+  src/metadata.cpp
+  src/options.cpp
+  src/parallel.cpp
+  src/reader.cpp
+  src/rigid.cpp
+  src/trajectory.cpp
+  src/units.cpp
+  src/variable.cpp
+  src/writer.cpp
+  src/xdr3d.cpp
+  src/zstd.cpp
+  src/streams.cpp
+  src/formats/registry.cpp
+  src/formats/text.cpp
+  src/formats/mdz_format.cpp
+  src/formats/dcd.cpp
+  src/formats/xtc.cpp
+  src/formats/npy.cpp
+  src/formats/extxyz.cpp
+  src/formats/lammps.cpp
+  src/formats/pdb.cpp
+  src/formats/xyz.cpp
+  src/capi.cpp
+)
+
+add_library(mdz ${MDZ_SOURCES})
+add_library(mdz::mdz ALIAS mdz)
+target_include_directories(mdz
+  PUBLIC  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+          $<INSTALL_INTERFACE:include>
+  PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src)
+target_include_directories(mdz SYSTEM PRIVATE ${MDZ_HEADER_DEPS})
+if(MDZ_ZSTD STREQUAL "fetch")
+  # Compile zstd's objects into mdz rather than linking a separate library, so
+  # a static libmdz is self-contained and exports no extra target.
+  target_sources(mdz PRIVATE $<TARGET_OBJECTS:mdz_zstd>)
+  target_include_directories(mdz PRIVATE $<TARGET_PROPERTY:mdz_zstd,INTERFACE_INCLUDE_DIRECTORIES>)
+  target_compile_definitions(mdz PRIVATE $<TARGET_PROPERTY:mdz_zstd,INTERFACE_COMPILE_DEFINITIONS>)
+else()
+  target_link_libraries(mdz PRIVATE ${MDZ_ZSTD_LINK})
+  if(MDZ_ZSTD_INCLUDE)
+    target_include_directories(mdz SYSTEM PRIVATE ${MDZ_ZSTD_INCLUDE})
+  endif()
+endif()
+find_package(Threads REQUIRED)
+target_link_libraries(mdz PUBLIC Threads::Threads)
+target_compile_definitions(mdz PRIVATE MDZ_VERSION_STRING="${PROJECT_VERSION}")
+if(MDZ_UNITY_BUILD)
+  set_target_properties(mdz PROPERTIES UNITY_BUILD ON UNITY_BUILD_BATCH_SIZE 8)
+endif()
+
+# Every target that does floating-point work on mdz data must round the same
+# way, so fused multiply-adds and reassociation are disabled. The encoder
+# predicts from its own reconstruction, and a decoder that rounds differently
+# would drift from it.
+function(mdz_strict_fp target)
+  if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
+    target_compile_options(${target} PRIVATE -ffp-contract=off -fno-fast-math)
+  elseif(MSVC)
+    target_compile_options(${target} PRIVATE /fp:precise)
+  endif()
+endfunction()
+
+# fopen, strerror and getenv are standard C; MSVC deprecates them in favour of
+# its _s variants. Applies to this directory tree only.
+if(MSVC)
+  add_compile_definitions(_CRT_SECURE_NO_WARNINGS)
+endif()
+
+function(mdz_warnings target)
+  if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
+    target_compile_options(${target} PRIVATE -Wall -Wextra -Wpedantic -Wshadow -Wno-unused-parameter)
+  elseif(MSVC)
+    target_compile_options(${target} PRIVATE /W4 /permissive- /utf-8)
+  endif()
+endfunction()
+
+mdz_strict_fp(mdz)
+mdz_warnings(mdz)
+
+if(MDZ_SANITIZE AND CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
+  add_compile_options(-fsanitize=address,undefined -fno-omit-frame-pointer)
+  add_link_options(-fsanitize=address,undefined)
+  target_compile_options(mdz PRIVATE -fsanitize=address,undefined -fno-omit-frame-pointer)
+  target_link_options(mdz PUBLIC -fsanitize=address,undefined)
+endif()
+
+# ---- tools, tests, bindings ------------------------------------------------
+
+if(MDZ_BUILD_CLI)
+  add_subdirectory(cli)
+endif()
+
+if(MDZ_BUILD_TESTS)
+  enable_testing()
+  add_subdirectory(tests/cpp)
+endif()
+
+if(MDZ_FUZZ)
+  add_subdirectory(fuzz)
+endif()
+
+if(MDZ_BUILD_BENCH)
+  add_subdirectory(bench)
+endif()
+
+if(MDZ_BUILD_PYTHON)
+  add_subdirectory(bindings/python)
+endif()
+
+# ---- install ---------------------------------------------------------------
+
+if(MDZ_TOP_LEVEL AND NOT SKBUILD)
+  include(GNUInstallDirs)
+  install(TARGETS mdz EXPORT mdzTargets
+    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
+  install(DIRECTORY include/mdz DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
+  install(EXPORT mdzTargets NAMESPACE mdz:: DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/mdz)
+  include(CMakePackageConfigHelpers)
+  configure_package_config_file(cmake/mdzConfig.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/mdzConfig.cmake
+    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/mdz)
+  write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/mdzConfigVersion.cmake
+    COMPATIBILITY SameMinorVersion)
+  install(FILES ${CMAKE_CURRENT_BINARY_DIR}/mdzConfig.cmake
+                ${CMAKE_CURRENT_BINARY_DIR}/mdzConfigVersion.cmake
+    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/mdz)
+endif()

mdz-0.4.0/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2026 Peter Spackman
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

mdz-0.4.0/PKG-INFO

@@ -0,0 +1,90 @@
+Metadata-Version: 2.4
+Name: mdz
+Version: 0.4.0
+Summary: Molecular dynamics trajectory compression with fast random access
+Keywords: molecular-dynamics,compression,trajectory,science
+Author-Email: Peter Spackman <peterspackman@fastmail.com>
+License-Expression: MIT AND BSD-3-Clause
+License-File: LICENSE
+License-File: THIRD_PARTY_LICENSES
+Classifier: Development Status :: 4 - Beta
+Classifier: Intended Audience :: Science/Research
+Classifier: Programming Language :: C++
+Classifier: Programming Language :: Python :: 3
+Classifier: Topic :: Scientific/Engineering :: Chemistry
+Classifier: Topic :: Scientific/Engineering :: Physics
+Classifier: Topic :: System :: Archiving :: Compression
+Project-URL: Homepage, https://github.com/peterspackman/mdz
+Project-URL: Repository, https://github.com/peterspackman/mdz
+Project-URL: Issues, https://github.com/peterspackman/mdz/issues
+Requires-Python: >=3.10
+Requires-Dist: numpy>=1.24
+Provides-Extra: test
+Requires-Dist: pytest>=7.0; extra == "test"
+Description-Content-Type: text/markdown
+
+# mdz
+
+mdz compresses molecular dynamics trajectories to a fixed maximum error
+(0.005 Å by default, the same as XTC). Any frame can be read without
+decompressing the rest of the file.
+
+Frames are predicted from the ones before them, so files are 2.5-3.5x
+smaller than XTC when frames are saved every few femtoseconds, and never
+bigger than XTC. See [docs/BENCHMARKS.md](docs/BENCHMARKS.md).
+
+mdz is a C++17 library with a command-line tool, Python bindings, a C API and
+a [LAMMPS dump style](lammps/README.md). It reads and writes DCD, XTC, XYZ,
+extended XYZ, PDB, LAMMPS dumps and `.npy`.
+
+## Install
+
+```bash
+pip install mdz
+```
+
+Prebuilt `mdz` binaries are on the
+[releases page](https://github.com/peterspackman/mdz/releases). To build
+from source you need CMake 3.18+ and a C++17 compiler:
+
+```bash
+cmake -S . -B build -DCMAKE_BUILD_TYPE=Release
+cmake --build build --parallel
+```
+
+## Usage
+
+```bash
+mdz compress traj.dcd -o traj.mdz
+mdz decompress traj.mdz -o traj.xtc
+mdz extract traj.mdz 100:200 -o slice.pdb
+mdz info traj.mdz
+```
+
+```python
+import mdz
+
+r = mdz.open("traj.mdz")
+r[42]           # one frame, (natoms, 3), in nm
+r[1000:2000]    # a range of frames
+
+with mdz.Writer("out.mdz") as w:
+    for step, x in simulation():
+        w.write(x, step=step)
+```
+
+[docs/USAGE.md](docs/USAGE.md) covers precision, units, lossless mode,
+varying atom counts, rigid bodies and the C++ API.
+[docs/FORMAT.md](docs/FORMAT.md) describes the file format.
+
+## Development
+
+```bash
+ctest --test-dir build
+MDZ_CLI=$PWD/build/cli/mdz python -m pytest cli/tests
+pip install . && python -m pytest tests
+```
+
+## License
+
+MIT. To cite mdz, see [CITATION.cff](CITATION.cff).

mdz-0.4.0/README.md

@@ -0,0 +1,65 @@
+# mdz
+
+mdz compresses molecular dynamics trajectories to a fixed maximum error
+(0.005 Å by default, the same as XTC). Any frame can be read without
+decompressing the rest of the file.
+
+Frames are predicted from the ones before them, so files are 2.5-3.5x
+smaller than XTC when frames are saved every few femtoseconds, and never
+bigger than XTC. See [docs/BENCHMARKS.md](docs/BENCHMARKS.md).
+
+mdz is a C++17 library with a command-line tool, Python bindings, a C API and
+a [LAMMPS dump style](lammps/README.md). It reads and writes DCD, XTC, XYZ,
+extended XYZ, PDB, LAMMPS dumps and `.npy`.
+
+## Install
+
+```bash
+pip install mdz
+```
+
+Prebuilt `mdz` binaries are on the
+[releases page](https://github.com/peterspackman/mdz/releases). To build
+from source you need CMake 3.18+ and a C++17 compiler:
+
+```bash
+cmake -S . -B build -DCMAKE_BUILD_TYPE=Release
+cmake --build build --parallel
+```
+
+## Usage
+
+```bash
+mdz compress traj.dcd -o traj.mdz
+mdz decompress traj.mdz -o traj.xtc
+mdz extract traj.mdz 100:200 -o slice.pdb
+mdz info traj.mdz
+```
+
+```python
+import mdz
+
+r = mdz.open("traj.mdz")
+r[42]           # one frame, (natoms, 3), in nm
+r[1000:2000]    # a range of frames
+
+with mdz.Writer("out.mdz") as w:
+    for step, x in simulation():
+        w.write(x, step=step)
+```
+
+[docs/USAGE.md](docs/USAGE.md) covers precision, units, lossless mode,
+varying atom counts, rigid bodies and the C++ API.
+[docs/FORMAT.md](docs/FORMAT.md) describes the file format.
+
+## Development
+
+```bash
+ctest --test-dir build
+MDZ_CLI=$PWD/build/cli/mdz python -m pytest cli/tests
+pip install . && python -m pytest tests
+```
+
+## License
+
+MIT. To cite mdz, see [CITATION.cff](CITATION.cff).

mdz-0.4.0/THIRD_PARTY_LICENSES

@@ -0,0 +1,157 @@
+Third-party software compiled into the mdz library, command-line tool and
+Python package. Their licenses follow.
+
+--------------------------------------------------------------------------------
+zstd 1.5.7
+https://github.com/facebook/zstd
+--------------------------------------------------------------------------------
+
+BSD License
+
+For Zstandard software
+
+Copyright (c) Meta Platforms, Inc. and affiliates. All rights reserved.
+
+Redistribution and use in source and binary forms, with or without modification,
+are permitted provided that the following conditions are met:
+
+ * Redistributions of source code must retain the above copyright notice, this
+   list of conditions and the following disclaimer.
+
+ * Redistributions in binary form must reproduce the above copyright notice,
+   this list of conditions and the following disclaimer in the documentation
+   and/or other materials provided with the distribution.
+
+ * Neither the name Facebook, nor Meta, nor the names of its contributors may
+   be used to endorse or promote products derived from this software without
+   specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
+ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
+ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+--------------------------------------------------------------------------------
+fast_float 8.0.2 (used under the MIT option of its MIT/Apache-2.0/BSL-1.0 license)
+https://github.com/fastfloat/fast_float
+--------------------------------------------------------------------------------
+
+MIT License
+
+Copyright (c) 2021 The fast_float authors
+
+Permission is hereby granted, free of charge, to any
+person obtaining a copy of this software and associated
+documentation files (the "Software"), to deal in the
+Software without restriction, including without
+limitation the rights to use, copy, modify, merge,
+publish, distribute, sublicense, and/or sell copies of
+the Software, and to permit persons to whom the Software
+is furnished to do so, subject to the following
+conditions:
+
+The above copyright notice and this permission notice
+shall be included in all copies or substantial portions
+of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF
+ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED
+TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A
+PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT
+SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
+CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR
+IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
+DEALINGS IN THE SOFTWARE.
+
+--------------------------------------------------------------------------------
+unordered_dense 4.5.0
+https://github.com/martinus/unordered_dense
+--------------------------------------------------------------------------------
+
+MIT License
+
+Copyright (c) 2022 Martin Leitner-Ankerl
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.
+
+--------------------------------------------------------------------------------
+nanobind (Python package only)
+https://github.com/wjakob/nanobind
+--------------------------------------------------------------------------------
+
+Copyright (c) 2022 Wenzel Jakob <wenzel.jakob@epfl.ch>, All rights reserved.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+1. Redistributions of source code must retain the above copyright notice, this
+   list of conditions and the following disclaimer.
+
+2. Redistributions in binary form must reproduce the above copyright notice,
+   this list of conditions and the following disclaimer in the documentation
+   and/or other materials provided with the distribution.
+
+3. Neither the name of the copyright holder nor the names of its contributors
+   may be used to endorse or promote products derived from this software
+   without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
+FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
+DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
+SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
+CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
+OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+--------------------------------------------------------------------------------
+robin-map, bundled with nanobind (Python package only)
+https://github.com/Tessil/robin-map
+--------------------------------------------------------------------------------
+
+MIT License
+
+Copyright (c) 2017 Thibaut Goetghebuer-Planchon <tessil@gmx.com>
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

mdz-0.4.0/bench/CMakeLists.txt

@@ -0,0 +1,9 @@
+add_executable(bench_encode bench_encode.cpp)
+target_link_libraries(bench_encode PRIVATE mdz::mdz)
+mdz_strict_fp(bench_encode)
+
+add_executable(bench_files bench_files.cpp)
+target_link_libraries(bench_files PRIVATE mdz::mdz)
+# The raw-floats baseline uses the library's internal zstd wrapper.
+target_include_directories(bench_files PRIVATE ${PROJECT_SOURCE_DIR}/src)
+mdz_strict_fp(bench_files)