libigl 2.5.2.dev0__tar.gz → 2.5.4.dev0__tar.gz

libigl-2.5.4.dev0/.github/workflows/pip.yml

@@ -0,0 +1,38 @@
+name: Pip
+
+on:
+  workflow_dispatch:
+  #pull_request:
+  #push:
+  #  branches:
+  #    - master
+
+jobs:
+  build:
+    name: Build with Pip
+    runs-on: ${{ matrix.platform }}
+    strategy:
+      fail-fast: false
+      matrix:
+        platform: [windows-latest, macos-latest, ubuntu-latest]
+        python-version: ["3.10"]
+
+    steps:
+    - uses: actions/checkout@v4
+
+    - uses: actions/setup-python@v5
+      with:
+        python-version: ${{ matrix.python-version }}
+
+    - name: Set min macOS version
+      if: runner.os == 'macOS'
+      run: |
+        echo "MACOSX_DEPLOYMENT_TARGET=10.14" >> $GITHUB_ENV
+
+    - name: Build and install
+      run: |
+        python -m pip install pytest
+        pip install --verbose .
+
+    - name: Test
+      run: python -m pytest

libigl-2.5.4.dev0/.github/workflows/wheels.yml

@@ -0,0 +1,70 @@
+name: Wheels
+
+on:
+  push:
+    branches:
+      - main
+  pull_request:
+    branches:
+      - main
+
+jobs:
+  build_sdist:
+    name: Build SDist
+    runs-on: ubuntu-latest
+    steps:
+    - uses: actions/checkout@v4
+      with:
+        submodules: true
+
+    - name: Build SDist
+      run: pipx run build --sdist
+
+    - name: Check metadata
+      run: pipx run twine check dist/*
+
+    - uses: actions/upload-artifact@v4
+      with:
+        name: dist-sdist
+        path: dist/*.tar.gz
+
+          #build_wheels:
+          #  name: Build ${{ matrix.cpversion }} wheels on ${{ matrix.os }}
+          #  runs-on: ${{ matrix.os }}
+          #  strategy:
+          #    fail-fast: false
+          #    matrix:
+          #      os: [ubuntu-latest, ubuntu-24.04-arm, windows-latest, macos-13, macos-14]
+          #      cpversion: [cp38, cp39, cp310, cp311, cp312 ]
+          #      # github actions cp38 on macos-14 runners are cross compiling or
+          #      # something and confusing the stub generation. Just skip it for now.
+          #      # Maybe it'd be friendlier to disable the stub generation for this
+          #      # combination.
+          #      exclude:
+          #        - os: macos-14
+          #          cpversion: cp38
+
+
+          #  steps:
+          #    - uses: actions/checkout@v4
+
+          #    - uses: actions/setup-python@v5
+          #      with:
+          #        python-version: '3.12'
+
+          #    - name: Install cibuildwheel
+          #      run: python -m pip install cibuildwheel==2.22.0
+
+          #    - name: Build wheels
+          #      # why do I need to specify this cpversion here?
+          #      env:
+          #        CIBW_ARCHS: "auto64"
+          #        CIBW_BUILD: "${{ matrix.cpversion }}-*"
+          #        # why isn't auto64 working?
+          #        CIBW_SKIP: "cp*-manylinux_i686 cp*-musllinux* cp*-win32"  
+          #      run: python -m cibuildwheel --output-dir wheelhouse
+
+          #    - uses: actions/upload-artifact@v4
+          #      with:
+          #        name: cibw-wheels-${{ matrix.os }}-${{ strategy.job-index }}
+          #        path: ./wheelhouse/*.whl

libigl-2.5.4.dev0/.gitignore

@@ -0,0 +1,42 @@
+external
+
+*.sublime-*
+
+bin
+bin_rel
+build
+
+tutorial/data
+tutorial/.ipynb_*
+tutorial-old/.ipynb_*
+
+test.obj
+pyigl.cpython*
+pyigl_classes.cpython*
+__pycache__
+
+igl.egg-info
+libigl.egg-info
+*.code-workspace
+out.obj
+test.off
+.vscode
+
+data
+site
+
+**/meshplot
+
+.DS_Store
+
+ttt.py
+*coverage*
+htmlcov
+junit
+.ipynb_checkpoints/tutorials-checkpoint.ipynb
+.*.un~
+.*.swp
+.*.swo
+*~
+dist/
+igl/*

libigl-2.5.4.dev0/CMakeLists.txt

@@ -0,0 +1,188 @@
+# Refactor the cmake/setup.py build to use scikit-build
+# https://github.com/wjakob/nanobind_example
+# Rather than creating multiple modules and dealing with multiple __init__.py
+# files, we can create a single module and use __init__.py to import the
+# submodules, create one extension module with submodules
+# https://stackoverflow.com/a/77020918/148668
+
+cmake_minimum_required(VERSION 3.15...3.27)
+project(pyigl)
+
+# For std::filesystem::path (generic_string)
+set(CMAKE_OSX_DEPLOYMENT_TARGET "10.15")
+# ≥17 for return value optimization 
+# <20 for embree
+set(CMAKE_CXX_STANDARD 17)
+
+if (CMAKE_VERSION VERSION_LESS 3.18)
+  set(DEV_MODULE Development)
+else()
+  set(DEV_MODULE Development.Module)
+endif()
+
+find_package(Python 3.8 COMPONENTS Interpreter ${DEV_MODULE} REQUIRED)
+
+if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
+  set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
+  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
+endif()
+
+message(STATUS "CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
+
+# Enable FetchContent to download dependencies at configure time
+include(FetchContent)
+
+# Download and set up nanobind
+FetchContent_Declare(
+  nanobind
+  GIT_REPOSITORY https://github.com/wjakob/nanobind.git
+  GIT_TAG        v2.2.0
+)
+FetchContent_MakeAvailable(nanobind)
+
+# Download and set up libigl
+option(LIBIGL_COPYLEFT_CORE        "Build target igl_copyleft::core"       ON)
+option(LIBIGL_COPYLEFT_CGAL        "Build target igl_copyleft::cgal"       ON)
+option(LIBIGL_EMBREE               "Build target igl::embree"              ON)
+option(LIBIGL_COPYLEFT_TETGEN      "Build target igl_copyleft::tetgen"     ON)
+option(LIBIGL_RESTRICTED_TRIANGLE  "Build target igl_restricted::triangle" ON)
+FetchContent_Declare(
+  libigl
+  GIT_REPOSITORY https://github.com/libigl/libigl.git
+  GIT_TAG a221faf1e4bd571529ca2101c08bc2458579b1da
+)
+FetchContent_MakeAvailable(libigl)
+
+# set PYIGL_OUTPUT_DIRECTORY to [this dir]/igl
+set(PYIGL_OUTPUT_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/igl")
+
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
+# Color output
+include(UseColors)
+
+# Extra warnings
+include(Warnings)
+
+# Use C++11/14
+include(CXXFeatures)
+
+# Generate position independent code by default
+set(CMAKE_POSITION_INDEPENDENT_CODE ON CACHE INTERNAL "")
+
+
+
+# don't need to worry about nested modules (opengl/** are the only ones and
+# those probably aren't ever getting python bindings)
+#
+# prefix is either "", "copyleft", or "restricted"
+function(pyigl_include prefix name)
+  string(TOUPPER "${prefix}" prefix_uc)
+  string(TOUPPER "${name}" name_uc)
+  if(prefix_uc)
+      string(PREPEND prefix_uc _)
+  endif()
+  string(TOLOWER "${prefix_uc}" prefix_lc)
+  # if(LIBIGL${prefix_uc}_${name_uc}) or name == "core"
+  if(LIBIGL${prefix_uc}_${name_uc} OR name STREQUAL "core")
+    if("${prefix}" STREQUAL "copyleft")
+      if("${name}" STREQUAL "core")
+        set(subpath "copyleft")
+      else()
+        set(subpath "copyleft/${name}")
+      endif()
+    elseif("${name}" STREQUAL "core")
+      set(subpath "")
+    else() # "" or "restricted"
+      set(subpath "${name}")
+    endif()
+    file(GLOB sources "${CMAKE_CURRENT_SOURCE_DIR}/src/${subpath}/*.cpp")
+
+    ## Just compile a single file
+    #list(FILTER sources EXCLUDE REGEX ".*/module\\.cpp$")
+    #list(GET sources 0 sources)
+    #list(APPEND sources "${CMAKE_CURRENT_SOURCE_DIR}/src/${subpath}/module.cpp")
+
+    message(STATUS "$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$")
+    message(STATUS "${prefix} ${name} sources: ${sources}")
+
+    set(BINDING_SOURCES ${sources})
+    list(FILTER BINDING_SOURCES EXCLUDE REGEX ".*/module\\.cpp$")
+
+    # keep just the first in the list and overwrite BINDING_SOURCES
+
+    # Generate the function calls based on filenames
+    set(BINDING_DECLARATIONS "")
+    foreach(source_file ${BINDING_SOURCES})
+      get_filename_component(filename ${source_file} NAME_WE)
+      set(BINDING_DECLARATIONS "${BINDING_DECLARATIONS}extern void bind_${filename}(nb::module_ &m);\n")
+      set(BINDING_INVOCATIONS "${BINDING_INVOCATIONS}    bind_${filename}(m);\n")
+    endforeach()
+    # make a temporary folder in the build directory to store the generated files
+    set(generated_dir "${CMAKE_CURRENT_BINARY_DIR}/include/${subpath}")
+    file(MAKE_DIRECTORY "${generated_dir}")
+    # write contents into BINDING_DECLARATIONS.h and BINDING_INVOCATIONS.h
+    file(WRITE "${generated_dir}/BINDING_DECLARATIONS.in" "${BINDING_DECLARATIONS}")
+    file(WRITE "${generated_dir}/BINDING_INVOCATIONS.in" "${BINDING_INVOCATIONS}")
+
+    set(target_name "pyigl${prefix_lc}_${name}")
+    nanobind_add_module(${target_name} ${sources})
+
+    # important for scikit-build
+    install(TARGETS ${target_name} LIBRARY DESTINATION  "igl/${subpath}")
+
+
+    if("${name}" STREQUAL "core")
+      target_link_libraries(${target_name} PRIVATE igl::core)
+    else()
+      target_link_libraries(${target_name} PRIVATE igl::core igl${prefix_lc}::${name})
+    endif()
+    target_include_directories(${target_name} PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/include")
+    target_include_directories(${target_name} PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/include")
+    set(output_dir "${PYIGL_OUTPUT_DIRECTORY}/${subpath}")
+    file(MAKE_DIRECTORY ${output_dir})
+    file(WRITE "${output_dir}/__init__.py" "from .${target_name} import *\n")
+    install(FILES "${output_dir}/__init__.py" DESTINATION "igl/${subpath}")
+
+    set_target_properties(${target_name} PROPERTIES 
+        LIBRARY_OUTPUT_DIRECTORY         "${output_dir}"
+        RUNTIME_OUTPUT_DIRECTORY         "${output_dir}"
+        LIBRARY_OUTPUT_DIRECTORY_RELEASE "${output_dir}"
+        RUNTIME_OUTPUT_DIRECTORY_RELEASE "${output_dir}"
+    )
+    set(PYI_OUTPUT "${output_dir}/${target_name}.pyi")
+    nanobind_add_stub(
+      ${target_name}_stub
+      MODULE ${target_name}
+      OUTPUT ${PYI_OUTPUT}
+      PYTHON_PATH $<TARGET_FILE_DIR:${target_name}>
+      DEPENDS ${target_name}
+    )
+    install(FILES "${PYI_OUTPUT}" DESTINATION "igl/${subpath}")
+
+    # just to add dependency?
+    if("${name}" STREQUAL "core")
+    else()
+      target_link_libraries(pyigl_core INTERFACE ${target_name})
+    endif()
+  endif()
+endfunction()
+
+pyigl_include("" "core")
+if(LIBIGL_COPYLEFT_CORE)
+  pyigl_include("copyleft" "core")
+endif()
+if(LIBIGL_COPYLEFT_CGAL)
+  pyigl_include("copyleft" "cgal")
+endif()
+if(LIBIGL_EMBREE)
+  pyigl_include("" "embree")
+endif()
+if(LIBIGL_COPYLEFT_TETGEN)
+  pyigl_include("copyleft" "tetgen")
+endif()
+if(LIBIGL_RESTRICTED_TRIANGLE)
+  pyigl_include("restricted" "triangle")
+endif()
+
+
+