libcasm-clexulator 2.0.0__tar.gz

libcasm_clexulator-2.0.0/CHANGELOG.md

@@ -0,0 +1,122 @@
+# Changelog
+
+All notable changes to `libcasm-clexulator` will be documented in this file.
+
+The format is based on [Keep a Changelog](https://keepachangelog.com/en/1.1.0/),
+and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0.html).
+
+
+## [2.0.0] - 2025-05-02
+
+### Fixed
+
+- Fixed `SparseCoefficients.value` to return value instead of index
+- Fixed construction of default PrimNeighborList in `make_cluster_expansion`
+
+### Changed
+
+- Build for Python 3.13
+- Restrict requires-python to ">=3.9,<3.14"
+- Run CI tests using Python 3.13
+- Build MacOS arm64 wheels using MacOS 15
+- Build Linux wheels using Ubuntu 24.04
+
+
+## [2.0a7] - 2024-12-11
+
+### Fixed
+
+- Fixed `calc_local_correlations` arguments and docs
+
+### Changed
+
+- Build macos x86_64 wheels with macos-13 Github Actions runner
+
+
+## [2.0a6] - 2024-07-26
+
+### Fixed
+
+- Fixed `required_update_neighborhood` methods, changing the return type to list[IntegralSiteCoordinate].
+
+
+## [2.0a5] - 2024-07-12
+
+### Added
+
+- Added `libcasm.clexulator.PrimNeighborList.weight_matrix()` to access the weight matrix
+
+### Changed
+
+- Wheels compiled with numpy>=2.0.0
+
+### Fixed
+
+- Fixed missing include (#19)
+
+
+## [2.0a4] - 2024-03-14
+
+### Fixed
+
+- Fixed DoFSpace basis pseudoinverse calculation
+
+### Added
+
+- Added gradients of correlations functionality in C++, Python functions
+- Added FADBAD library to support compiling of Clexulators capable of calculating gradients 
+- Added methods to libcasm.clexulator.PrimNeighborList to construct a PrimNeighborList with default parameters for a libcasm.xtal.Prim and to expand and access the neighbors.
+- Added libcasm.clexulator.make_default_prim_neighbor_list
+- Added methods to libcasm.clexulator.SuperNeighborList to access the neighbor sites and unitcells.
+- Added support in ConfigDoFValues for multiple discrete DoF
+- Added CASM::clexulator::get_dof_vector_value_at and CASM::clexulator::get_mean_dof_vector_value
+
+
+### Changed
+
+- Updated docs for PyData Sphinx Theme 0.14.3, particularly dark theme colors and logo
+- Changed "intensive_value" methods to "per_unitcell" and "extensive_value" methods to "per_supercell"
+- Changed names of libcasm.clexulator.PrimNeighborList methods default_nlist_weight_matrix to default_lattice_weight_matrix and default_nlist_sublattice_indices to default_sublattice_indices
+
+### Removed
+
+- Removed libcasm.clexulator.PrimNeighborList.default_nlist
+
+
+## [2.0a3] - 2023-10-25
+
+### Fixed
+
+- Fixed error messages for conversion of local DoF to the standard basis
+- Fixed DiffClexParamPack traits namespace
+- Fixed DoFSpace.is_global binding
+
+### Added
+
+- Tests for correct treatment of local DoF basis with dim=0 on some sublattices
+
+
+## [2.0a2] - 2023-09-28
+
+### Fixed
+
+- Fixed calculation of homogeneous mode space when some sites do not include a local DoF
+
+
+## [2.0a1] - 2023-08-20
+
+This release separates out casm/clexulator from CASM v1. It creates a Python package, libcasm.clexulator, that enables using casm/clexulator and may be installed via pip install, using scikit-build, CMake, and pybind11. This release also includes usage and API documentation for using libcasm.clexulator, built using Sphinx.
+
+### Added
+
+- Added Python package libcasm.clexulator
+- Added scikit-build, CMake, and pybind11 build process
+- Added GitHub Actions for unit testing
+- Added GitHub Action build_wheels.yml for Python x86_64 wheel building using cibuildwheel
+- Added Cirrus-CI .cirrus.yml for Python aarch64 and arm64 wheel building using cibuildwheel
+- Added Python documentation
+
+### Removed
+
+- Removed autotools build process
+- Removed boost dependencies

libcasm_clexulator-2.0.0/CMakeLists.txt

@@ -0,0 +1,245 @@
+cmake_minimum_required(VERSION 3.20)
+set(CMAKE_OSX_DEPLOYMENT_TARGET "10.15" CACHE STRING "Minimum OS X deployment version")
+
+project(CASMcode_clexulator VERSION 2.0.0 LANGUAGES CXX)
+
+# set CMAKE_INSTALL_X variables
+include(GNUInstallDirs)
+
+# specify the C++ standard
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED True)
+
+# try to use ccache
+find_program(CCACHE_PROGRAM ccache)
+if(CCACHE_PROGRAM)
+    set(CMAKE_CXX_COMPILER_LAUNCHER "${CCACHE_PROGRAM}")
+endif()
+
+##############################################
+## Find dependencies
+
+# Should find ZLIB::ZLIB
+find_package(ZLIB)
+
+# Find CASM
+if(NOT DEFINED CASM_PREFIX)
+  message(STATUS "CASM_PREFIX not defined")
+  # try to find Python
+  find_package (Python COMPONENTS Interpreter Development)
+  if(DEFINED Python_EXECUTABLE)
+    # if Python found, obtain CASM_PREFIX from the libcasm.casmglobal
+    message(STATUS "found Python_EXECUTABLE: ${Python_EXECUTABLE}")
+    message(STATUS "checking for libcasm-global")
+    execute_process(
+      COMMAND pip show libcasm-global
+      RESULT_VARIABLE EXIT_CODE
+      OUTPUT_QUIET
+    )
+    if (${EXIT_CODE} EQUAL 0)
+      message(STATUS "found libcasm-global")
+      execute_process(COMMAND ${Python_EXECUTABLE} -m libcasm.casmglobal --prefix
+                      OUTPUT_VARIABLE CASM_PREFIX_RAW)
+      string(STRIP "${CASM_PREFIX_RAW}" CASM_PREFIX)
+      message(STATUS "CASM_PREFIX: ${CASM_PREFIX}")
+    else()
+      message(STATUS "did not find libcasm-global")
+    endif()
+  endif()
+endif()
+if(DEFINED CASM_PREFIX)
+  set(CASMcode_global_ROOT ${CASM_PREFIX}/share/CASMcode_global/cmake)
+  set(CASMcode_crystallography_ROOT ${CASM_PREFIX}/share/CASMcode_crystallography/cmake)
+endif()
+find_package(CASMcode_global)
+if(NOT CASMcode_global_FOUND)
+  message(FATAL_ERROR "CMake failed to find CASMcode_global")
+endif()
+# if successful, we have CASM::casm_global
+
+find_package(CASMcode_crystallography)
+if(NOT CASMcode_crystallography_FOUND)
+  message(FATAL_ERROR "CMake failed to find CASMcode_crystallography")
+endif()
+# if successful, we have CASM::casm_crystallography
+
+# if no user CMAKE_INSTALL_PREFIX, use CASM_PREFIX if it exists
+IF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+  if(DEFINED CASM_PREFIX)
+    message(STATUS "CMAKE_INSTALL_PREFIX initialized to default, so updating CMAKE_INSTALL_PREFIX to CASM_PREFIX")
+    set(CMAKE_INSTALL_PREFIX ${CASM_PREFIX} CACHE PATH "set CMAKE_INSTALL_PREFIX to CASM_PREFIX" FORCE)
+    message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}")
+  endif()
+ENDIF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+
+##############################################
+## Build libcasm_clexulator
+
+# create libcasm_clexulator
+set(
+  libcasm_clexulator_HEADERS
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/BaseClexulator.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/BasicClexParamPack.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/ClexParamPack.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/Clexulator.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/ClusterExpansion.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/ConfigDoFValues.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/ConfigDoFValuesTools.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/ConfigDoFValuesTools_impl.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/Correlations.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/DiffClexParamPack.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/DoFSpace.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/DoFSpaceAxisInfo.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/ImpactTable.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/LocalClusterExpansion.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/LocalCorrelations.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/NeighborList.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/OrderParameter.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/SparseCoefficients.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/external/fadbad/badiff.h
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/external/fadbad/fadbad.h
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/external/fadbad/fadiff.h
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/external/fadbad/tadiff.h
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/io/json/Clexulator_json_io.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/io/json/ConfigDoFValues_json_io.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/io/json/DoFSpace_json_io.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/io/json/SparseCoefficients_json_io.hh
+  ${PROJECT_SOURCE_DIR}/include/casm/clexulator/version.hh
+)
+set(
+  libcasm_clexulator_SOURCES
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/BaseClexulator.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/Clexulator.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/ClusterExpansion.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/Correlations.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/DoFSpace.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/DoFSpaceAxisInfo.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/ImpactTable.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/LocalClusterExpansion.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/LocalCorrelations.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/NeighborList.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/OrderParameter.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/io/json/Clexulator_json_io.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/io/json/ConfigDoFValues_json_io.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/io/json/DoFSpace_json_io.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/io/json/SparseCoefficients_json_io.cc
+  ${PROJECT_SOURCE_DIR}/src/casm/clexulator/version.cc
+)
+add_library(casm_clexulator SHARED ${libcasm_clexulator_SOURCES})
+target_include_directories(casm_clexulator
+  PUBLIC
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/casm/external>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/casm/external/gzstream>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/casm/external>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/casm/external/gzstream>
+)
+target_compile_options(casm_clexulator
+  PUBLIC
+    "-DCASM_CLEXULATOR_TXT_VERSION=\"${CMAKE_PROJECT_VERSION}\""
+    -DEIGEN_DEFAULT_DENSE_INDEX_TYPE=long
+    -DGZSTREAM_NAMESPACE=gz
+)
+target_link_libraries(casm_clexulator
+  ZLIB::ZLIB
+  ${CMAKE_DL_LIBS}
+  CASM::casm_global
+  CASM::casm_crystallography
+)
+if(APPLE)
+  set_target_properties(
+    casm_clexulator PROPERTIES INSTALL_RPATH "@loader_path")
+else()
+  set_target_properties(
+    casm_clexulator PROPERTIES INSTALL_RPATH "$ORIGIN")
+endif()
+
+##############################################
+## Install libcasm_clexulator
+
+# install header files in <prefix>/libcasm/include/,
+# while preserving directory structure
+foreach ( filevar ${libcasm_clexulator_HEADERS} )
+  file(RELATIVE_PATH relfile ${PROJECT_SOURCE_DIR}/include/ ${filevar})
+  get_filename_component( reldir ${relfile} DIRECTORY )
+  install( FILES ${filevar} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${reldir} )
+endforeach()
+
+# install libcasm_clexulator in <prefix>/libcasm/lib/
+install(
+  TARGETS casm_clexulator
+  EXPORT CASMcode_clexulatorTargets
+  DESTINATION lib)
+
+##############################################
+## Python extensions
+
+# The CMake package config and target files are installed under the Python
+# package root. This is necessary to ensure that all the relative paths in the
+# helloTargets.cmake resolve correctly. It also provides encapsulation.
+#
+# The actual path used must be selected so that consuming projects can locate it
+# via `find_package`. To support finding CMake packages in the Python package
+# prefix, using `find_package`s default search path of
+# `<prefix>/<name>/share/<name>*/cmake/` is reasonable. Adding the Python
+# package installation prefix to CMAKE_PREFIX_PATH in combination with this path
+# will allow `find_package` to find this package and any other package installed
+# via a Python package if the CMake and Python packages are named the same.
+set(CASM_CMAKE_PACKAGE_INSTALL_SUBDIR "share/CASMcode_clexulator/cmake")
+
+install(
+  EXPORT CASMcode_clexulatorTargets
+  NAMESPACE CASM::
+  DESTINATION ${CASM_CMAKE_PACKAGE_INSTALL_SUBDIR})
+
+include(CMakePackageConfigHelpers)
+
+write_basic_package_version_file(
+  CASMcode_clexulatorConfigVersion.cmake
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY SameMinorVersion)
+
+configure_package_config_file(
+  "${PROJECT_SOURCE_DIR}/cmake/CASMcode_clexulatorConfig.cmake.in" CASMcode_clexulatorConfig.cmake
+  INSTALL_DESTINATION ${CASM_CMAKE_PACKAGE_INSTALL_SUBDIR})
+
+install(FILES "${PROJECT_BINARY_DIR}/CASMcode_clexulatorConfig.cmake"
+              "${PROJECT_BINARY_DIR}/CASMcode_clexulatorConfigVersion.cmake"
+        DESTINATION ${CASM_CMAKE_PACKAGE_INSTALL_SUBDIR})
+
+# We are using the SKBUILD variable, which is defined when scikit-build is
+# running the CMake build, to control building the Python wrapper. This allows
+# the C++ project to be installed, standalone, when using the standard CMake
+# build flow.
+if(DEFINED SKBUILD)
+
+  # call pybind11-config to obtain the root of the cmake package
+  execute_process(COMMAND ${PYTHON_EXECUTABLE} -m pybind11 --cmakedir
+                  OUTPUT_VARIABLE pybind11_ROOT_RAW)
+  string(STRIP "${pybind11_ROOT_RAW}" pybind11_ROOT)
+  find_package(pybind11)
+
+  # The extension modules must load:
+  # - the casm_global library
+  # - the casm_clexulator library
+  # They can be found by setting a relative rpath
+
+  ### libcasm.clexulator._clexulator ###
+  pybind11_add_module(_clexulator MODULE
+                      "${PROJECT_SOURCE_DIR}/python/src/clexulator.cpp")
+  target_link_libraries(_clexulator PRIVATE
+    CASM::casm_global
+    CASM::casm_crystallography
+    casm_clexulator
+  )
+  install(TARGETS _clexulator DESTINATION clexulator)
+  if(APPLE)
+    set_target_properties(
+      _clexulator PROPERTIES INSTALL_RPATH "@loader_path/../lib")
+  else()
+    set_target_properties(
+      _clexulator PROPERTIES INSTALL_RPATH "$ORIGIN/../lib")
+  endif()
+
+endif()

libcasm_clexulator-2.0.0/CMakeLists.txt.in

@@ -0,0 +1,202 @@
+cmake_minimum_required(VERSION 3.20)
+set(CMAKE_OSX_DEPLOYMENT_TARGET "10.15" CACHE STRING "Minimum OS X deployment version")
+
+project(CASMcode_clexulator VERSION 2.0.0 LANGUAGES CXX)
+
+# set CMAKE_INSTALL_X variables
+include(GNUInstallDirs)
+
+# specify the C++ standard
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED True)
+
+# try to use ccache
+find_program(CCACHE_PROGRAM ccache)
+if(CCACHE_PROGRAM)
+    set(CMAKE_CXX_COMPILER_LAUNCHER "${CCACHE_PROGRAM}")
+endif()
+
+##############################################
+## Find dependencies
+
+# Should find ZLIB::ZLIB
+find_package(ZLIB)
+
+# Find CASM
+if(NOT DEFINED CASM_PREFIX)
+  message(STATUS "CASM_PREFIX not defined")
+  # try to find Python
+  find_package (Python COMPONENTS Interpreter Development)
+  if(DEFINED Python_EXECUTABLE)
+    # if Python found, obtain CASM_PREFIX from the libcasm.casmglobal
+    message(STATUS "found Python_EXECUTABLE: ${Python_EXECUTABLE}")
+    message(STATUS "checking for libcasm-global")
+    execute_process(
+      COMMAND pip show libcasm-global
+      RESULT_VARIABLE EXIT_CODE
+      OUTPUT_QUIET
+    )
+    if (${EXIT_CODE} EQUAL 0)
+      message(STATUS "found libcasm-global")
+      execute_process(COMMAND ${Python_EXECUTABLE} -m libcasm.casmglobal --prefix
+                      OUTPUT_VARIABLE CASM_PREFIX_RAW)
+      string(STRIP "${CASM_PREFIX_RAW}" CASM_PREFIX)
+      message(STATUS "CASM_PREFIX: ${CASM_PREFIX}")
+    else()
+      message(STATUS "did not find libcasm-global")
+    endif()
+  endif()
+endif()
+if(DEFINED CASM_PREFIX)
+  set(CASMcode_global_ROOT ${CASM_PREFIX}/share/CASMcode_global/cmake)
+  set(CASMcode_crystallography_ROOT ${CASM_PREFIX}/share/CASMcode_crystallography/cmake)
+endif()
+find_package(CASMcode_global)
+if(NOT CASMcode_global_FOUND)
+  message(FATAL_ERROR "CMake failed to find CASMcode_global")
+endif()
+# if successful, we have CASM::casm_global
+
+find_package(CASMcode_crystallography)
+if(NOT CASMcode_crystallography_FOUND)
+  message(FATAL_ERROR "CMake failed to find CASMcode_crystallography")
+endif()
+# if successful, we have CASM::casm_crystallography
+
+# if no user CMAKE_INSTALL_PREFIX, use CASM_PREFIX if it exists
+IF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+  if(DEFINED CASM_PREFIX)
+    message(STATUS "CMAKE_INSTALL_PREFIX initialized to default, so updating CMAKE_INSTALL_PREFIX to CASM_PREFIX")
+    set(CMAKE_INSTALL_PREFIX ${CASM_PREFIX} CACHE PATH "set CMAKE_INSTALL_PREFIX to CASM_PREFIX" FORCE)
+    message(STATUS "CMAKE_INSTALL_PREFIX: ${CMAKE_INSTALL_PREFIX}")
+  endif()
+ENDIF(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
+
+##############################################
+## Build libcasm_clexulator
+
+# create libcasm_clexulator
+set(
+  libcasm_clexulator_HEADERS
+@header_files@)
+set(
+  libcasm_clexulator_SOURCES
+@source_files@)
+add_library(casm_clexulator SHARED ${libcasm_clexulator_SOURCES})
+target_include_directories(casm_clexulator
+  PUBLIC
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/casm/external>
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/casm/external/gzstream>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/casm/external>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/casm/external/gzstream>
+)
+target_compile_options(casm_clexulator
+  PUBLIC
+    "-DCASM_CLEXULATOR_TXT_VERSION=\"${CMAKE_PROJECT_VERSION}\""
+    -DEIGEN_DEFAULT_DENSE_INDEX_TYPE=long
+    -DGZSTREAM_NAMESPACE=gz
+)
+target_link_libraries(casm_clexulator
+  ZLIB::ZLIB
+  ${CMAKE_DL_LIBS}
+  CASM::casm_global
+  CASM::casm_crystallography
+)
+if(APPLE)
+  set_target_properties(
+    casm_clexulator PROPERTIES INSTALL_RPATH "@loader_path")
+else()
+  set_target_properties(
+    casm_clexulator PROPERTIES INSTALL_RPATH "$ORIGIN")
+endif()
+
+##############################################
+## Install libcasm_clexulator
+
+# install header files in <prefix>/libcasm/include/,
+# while preserving directory structure
+foreach ( filevar ${libcasm_clexulator_HEADERS} )
+  file(RELATIVE_PATH relfile ${PROJECT_SOURCE_DIR}/include/ ${filevar})
+  get_filename_component( reldir ${relfile} DIRECTORY )
+  install( FILES ${filevar} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${reldir} )
+endforeach()
+
+# install libcasm_clexulator in <prefix>/libcasm/lib/
+install(
+  TARGETS casm_clexulator
+  EXPORT CASMcode_clexulatorTargets
+  DESTINATION lib)
+
+##############################################
+## Python extensions
+
+# The CMake package config and target files are installed under the Python
+# package root. This is necessary to ensure that all the relative paths in the
+# helloTargets.cmake resolve correctly. It also provides encapsulation.
+#
+# The actual path used must be selected so that consuming projects can locate it
+# via `find_package`. To support finding CMake packages in the Python package
+# prefix, using `find_package`s default search path of
+# `<prefix>/<name>/share/<name>*/cmake/` is reasonable. Adding the Python
+# package installation prefix to CMAKE_PREFIX_PATH in combination with this path
+# will allow `find_package` to find this package and any other package installed
+# via a Python package if the CMake and Python packages are named the same.
+set(CASM_CMAKE_PACKAGE_INSTALL_SUBDIR "share/CASMcode_clexulator/cmake")
+
+install(
+  EXPORT CASMcode_clexulatorTargets
+  NAMESPACE CASM::
+  DESTINATION ${CASM_CMAKE_PACKAGE_INSTALL_SUBDIR})
+
+include(CMakePackageConfigHelpers)
+
+write_basic_package_version_file(
+  CASMcode_clexulatorConfigVersion.cmake
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY SameMinorVersion)
+
+configure_package_config_file(
+  "${PROJECT_SOURCE_DIR}/cmake/CASMcode_clexulatorConfig.cmake.in" CASMcode_clexulatorConfig.cmake
+  INSTALL_DESTINATION ${CASM_CMAKE_PACKAGE_INSTALL_SUBDIR})
+
+install(FILES "${PROJECT_BINARY_DIR}/CASMcode_clexulatorConfig.cmake"
+              "${PROJECT_BINARY_DIR}/CASMcode_clexulatorConfigVersion.cmake"
+        DESTINATION ${CASM_CMAKE_PACKAGE_INSTALL_SUBDIR})
+
+# We are using the SKBUILD variable, which is defined when scikit-build is
+# running the CMake build, to control building the Python wrapper. This allows
+# the C++ project to be installed, standalone, when using the standard CMake
+# build flow.
+if(DEFINED SKBUILD)
+
+  # call pybind11-config to obtain the root of the cmake package
+  execute_process(COMMAND ${PYTHON_EXECUTABLE} -m pybind11 --cmakedir
+                  OUTPUT_VARIABLE pybind11_ROOT_RAW)
+  string(STRIP "${pybind11_ROOT_RAW}" pybind11_ROOT)
+  find_package(pybind11)
+
+  # The extension modules must load:
+  # - the casm_global library
+  # - the casm_clexulator library
+  # They can be found by setting a relative rpath
+
+  ### libcasm.clexulator._clexulator ###
+  pybind11_add_module(_clexulator MODULE
+                      "${PROJECT_SOURCE_DIR}/python/src/clexulator.cpp")
+  target_link_libraries(_clexulator PRIVATE
+    CASM::casm_global
+    CASM::casm_crystallography
+    casm_clexulator
+  )
+  install(TARGETS _clexulator DESTINATION clexulator)
+  if(APPLE)
+    set_target_properties(
+      _clexulator PROPERTIES INSTALL_RPATH "@loader_path/../lib")
+  else()
+    set_target_properties(
+      _clexulator PROPERTIES INSTALL_RPATH "$ORIGIN/../lib")
+  endif()
+
+endif()