cutcells 0.5.0__tar.gz

cutcells-0.5.0/LICENSE

@@ -0,0 +1,21 @@
+The MIT License
+
+Copyright (c) 2022 ONERA (Authors: Susanne Claus)
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+THE SOFTWARE.

cutcells-0.5.0/PKG-INFO

@@ -0,0 +1,95 @@
+Metadata-Version: 2.4
+Name: cutcells
+Version: 0.5.0
+Summary: Cut-cell geometry and quadrature for level set meshes (CutFEM, unfitted FEM)
+Keywords: cut cells,level set,CutFEM,unfitted finite elements,quadrature
+Author-Email: Susanne Claus <susanne.claus@onera.fr>
+License-Expression: MIT AND BSD-3-Clause
+License-File: LICENSE
+License-File: third_party/Basix-LICENSE.txt
+License-File: third_party/THIRD_PARTY_NOTICES.md
+License-File: third_party/VTK-Copyright.txt
+Classifier: Development Status :: 4 - Beta
+Classifier: Intended Audience :: Science/Research
+Classifier: Operating System :: MacOS
+Classifier: Operating System :: POSIX :: Linux
+Classifier: Programming Language :: C++
+Classifier: Programming Language :: Python :: 3
+Classifier: Programming Language :: Python :: 3.10
+Classifier: Programming Language :: Python :: 3.11
+Classifier: Programming Language :: Python :: 3.12
+Classifier: Programming Language :: Python :: 3.13
+Classifier: Programming Language :: Python :: 3.14
+Classifier: Topic :: Scientific/Engineering :: Mathematics
+Classifier: Topic :: Scientific/Engineering :: Physics
+Project-URL: Homepage, https://github.com/sclaus2/CutCells
+Project-URL: Documentation, https://sclaus2.github.io/CutCells/
+Project-URL: Source, https://github.com/sclaus2/CutCells
+Project-URL: Issues, https://github.com/sclaus2/CutCells/issues
+Requires-Python: >=3.10
+Requires-Dist: numpy>=1.21
+Provides-Extra: docs
+Requires-Dist: markdown; extra == "docs"
+Provides-Extra: lint
+Requires-Dist: ruff; extra == "lint"
+Provides-Extra: optional
+Requires-Dist: pyvista; extra == "optional"
+Provides-Extra: test
+Requires-Dist: pytest; extra == "test"
+Requires-Dist: numpy; extra == "test"
+Provides-Extra: ci
+Requires-Dist: mypy; extra == "ci"
+Requires-Dist: pytest-xdist; extra == "ci"
+Requires-Dist: cutcells[test]; extra == "ci"
+Description-Content-Type: text/markdown
+
+# CutCells
+
+CutCells cuts the cells of a mesh by one or more level sets `phi(x)` and
+returns the inside, outside and interface pieces with explicit connectivity and
+quadrature rules. It is a geometry kernel for unfitted finite element methods
+(CutFEM): the C++20 core has no dependencies beyond a compiler, and the Python
+interface passes arrays to and from NumPy without copying where the layout
+allows.
+
+```console
+pip install cutcells
+```
+
+Wheels are published for Linux and macOS. Other platforms build from the source
+distribution, which needs a C++20 compiler and CMake.
+
+## Example
+
+Cut a triangle mesh by a circle and integrate the inside and the interface:
+
+```python
+import numpy as np
+import cutcells
+
+mesh = cutcells.rectangle_mesh(-1.0, -1.0, 1.0, 1.0, 41, 41, cell_type="triangle")
+
+def phi(X):
+    # X has shape (gdim, num_points)
+    return np.sqrt(X[0] ** 2 + X[1] ** 2) - 0.55
+
+level_set = cutcells.create_level_set(mesh, phi, degree=2, name="phi")
+result = cutcells.cut(mesh, level_set)
+
+inside = result[level_set < 0]
+interface = result[level_set == 0]
+
+print("area     ", inside.quadrature(order=4, mode="full").weights.sum())
+print("perimeter", interface.quadrature(order=4, mode="cut_only").weights.sum())
+```
+
+Parent cells can be intervals, triangles, quadrilaterals, tetrahedra,
+hexahedra, prisms and pyramids, with any number of level sets per cell. Level
+sets are interpolated (any degree) or analytic.
+
+## Links
+
+- Documentation and tutorials: <https://sclaus2.github.io/CutCells/>
+- Source, issues and the C++ library: <https://github.com/sclaus2/CutCells>
+- Licence: MIT. Third-party notices for generated VTK-derived tables and
+  Basix-generated quadrature tables ship with the package.

cutcells-0.5.0/cpp/CMakeLists.txt

@@ -0,0 +1,122 @@
+cmake_minimum_required(VERSION 3.21)
+
+project(CutCells VERSION "0.5.0" LANGUAGES CXX C)
+
+set(CMAKE_CXX_STANDARD 20)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+set(CMAKE_CXX_EXTENSIONS OFF)
+
+option(BUILD_SHARED_LIBS "Build CutCells with shared libraries." ON)
+option(CUTCELLS_ENABLE_IPO
+  "Enable interprocedural optimization in release builds when supported."
+  OFF)
+option(CUTCELLS_NATIVE_COMPRESSION
+  "Compile the compression kernels for the build machine's CPU (-march=native)."
+  OFF)
+option(BUILD_TESTING "Build the C++ tests in cpp/tests (run with ctest)." OFF)
+
+include(GNUInstallDirs)
+include(CheckIPOSupported)
+
+add_subdirectory(src)
+
+set(CUTCELLS_BUILD_INCLUDE_DIR "${CMAKE_CURRENT_BINARY_DIR}/include")
+# Rewritten on every configure, so headers that moved or went leave nothing behind
+file(REMOVE_RECURSE "${CUTCELLS_BUILD_INCLUDE_DIR}/cutcells")
+file(MAKE_DIRECTORY "${CUTCELLS_BUILD_INCLUDE_DIR}/cutcells")
+# A header keeps its path below src/, in the build tree and when installed:
+# src/quadrays/rules.h becomes <cutcells/quadrays/rules.h>.
+foreach(_cutcells_header IN LISTS HEADERS)
+  file(RELATIVE_PATH _cutcells_header_path
+       "${CMAKE_CURRENT_SOURCE_DIR}/src" "${_cutcells_header}")
+  get_filename_component(_cutcells_header_dir "${_cutcells_header_path}"
+                         DIRECTORY)
+  file(WRITE "${CUTCELLS_BUILD_INCLUDE_DIR}/cutcells/${_cutcells_header_path}"
+       "#pragma once\n#include \"${_cutcells_header}\"\n")
+  install(FILES "${_cutcells_header}"
+    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/cutcells/${_cutcells_header_dir}"
+    COMPONENT Development)
+endforeach()
+file(COPY "${CMAKE_CURRENT_SOURCE_DIR}/src/generated"
+  DESTINATION "${CUTCELLS_BUILD_INCLUDE_DIR}/cutcells"
+  FILES_MATCHING PATTERN "*.h")
+file(COPY "${CMAKE_CURRENT_SOURCE_DIR}/src/lut/generated"
+  DESTINATION "${CUTCELLS_BUILD_INCLUDE_DIR}/cutcells/lut"
+  FILES_MATCHING PATTERN "*.h")
+
+# No fused multiply-adds unless written: compilers for ARM (and x86 with FMA)
+# fuse a * b + c by default, which changes the last bits, and quadrays' cuts
+# decide on signs and comparisons that a last bit can flip. Without fusion
+# every platform computes what x86-64 does.
+if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
+  target_compile_options(cutcells PRIVATE -ffp-contract=off)
+endif()
+
+find_package(OpenMP QUIET COMPONENTS CXX)
+if(OpenMP_CXX_FOUND AND TARGET OpenMP::OpenMP_CXX)
+  target_link_libraries(cutcells PUBLIC OpenMP::OpenMP_CXX)
+endif()
+
+if(CUTCELLS_ENABLE_IPO)
+  check_ipo_supported(RESULT CUTCELLS_IPO_SUPPORTED OUTPUT CUTCELLS_IPO_ERROR)
+  if(CUTCELLS_IPO_SUPPORTED)
+    set_property(TARGET cutcells PROPERTY INTERPROCEDURAL_OPTIMIZATION_RELEASE TRUE)
+  else()
+    message(STATUS "IPO requested but not supported: ${CUTCELLS_IPO_ERROR}")
+  endif()
+endif()
+
+target_include_directories(cutcells PUBLIC
+  $<BUILD_INTERFACE:${CUTCELLS_BUILD_INCLUDE_DIR}>
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+  $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+
+if(BUILD_TESTING)
+  enable_testing()
+  add_subdirectory(tests)
+endif()
+
+# Install the generated tables: quadrature rules, and the lookup tables
+install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/src/generated
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/cutcells
+  COMPONENT Development
+  FILES_MATCHING PATTERN "*.h")
+install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/src/lut/generated
+  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/cutcells/lut
+  COMPONENT Development
+  FILES_MATCHING PATTERN "*.h")
+
+# Install the cutcells library
+install(TARGETS cutcells
+  EXPORT CutCellsTargets
+  RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT RuntimeExecutables
+  LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT RuntimeLibraries
+  ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT Development)
+
+set(_cutcells_license_install_dir
+  "${CMAKE_INSTALL_DATADIR}/licenses/cutcells")
+install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/../LICENSE"
+  DESTINATION ${_cutcells_license_install_dir}
+  RENAME CutCells-LICENSE.txt)
+install(FILES
+  "${CMAKE_CURRENT_SOURCE_DIR}/../third_party/THIRD_PARTY_NOTICES.md"
+  "${CMAKE_CURRENT_SOURCE_DIR}/../third_party/VTK-Copyright.txt"
+  "${CMAKE_CURRENT_SOURCE_DIR}/../third_party/Basix-LICENSE.txt"
+  DESTINATION ${_cutcells_license_install_dir})
+
+include(CMakePackageConfigHelpers)
+write_basic_package_version_file(CutCellsConfigVersion.cmake
+  VERSION ${PROJECT_VERSION}
+  COMPATIBILITY AnyNewerVersion)
+configure_package_config_file(CutCellsConfig.cmake.in
+  ${CMAKE_CURRENT_BINARY_DIR}/CutCellsConfig.cmake
+  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cutcells)
+
+install(FILES
+  ${CMAKE_CURRENT_BINARY_DIR}/CutCellsConfig.cmake
+  ${CMAKE_CURRENT_BINARY_DIR}/CutCellsConfigVersion.cmake
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cutcells COMPONENT Development)
+install(EXPORT CutCellsTargets
+  FILE CutCellsTargets.cmake
+  NAMESPACE CUTCELLS::
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cutcells)

cutcells-0.5.0/cpp/CutCellsConfig.cmake.in

@@ -0,0 +1,7 @@
+@PACKAGE_INIT@
+
+include(CMakeFindDependencyMacro)
+
+if(NOT TARGET @PROJECT_NAME@)
+  include("${CMAKE_CURRENT_LIST_DIR}/@PROJECT_NAME@Targets.cmake")
+endif()

cutcells-0.5.0/cpp/src/CMakeLists.txt

@@ -0,0 +1,54 @@
+include(GNUInstallDirs)
+
+add_library(cutcells)
+
+configure_file(${CMAKE_CURRENT_SOURCE_DIR}/version.h.in version.h)
+
+target_include_directories(cutcells PUBLIC
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
+
+# Sub-folders add their sources to the cutcells target and return their
+# headers (installed under include/cutcells/<folder>/).
+add_subdirectory(quadrays)
+add_subdirectory(lut)
+add_subdirectory(part)
+add_subdirectory(compression)
+
+set(HEADERS
+  ${CMAKE_CURRENT_SOURCE_DIR}/cell_types.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/cell_flags.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/cell_topology.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/reference_cell.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/mapping.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/bernstein.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/level_set.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/level_set_cell.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/mesh_view.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/selection_expr.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/quadrature.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/quadrature_tables.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/row_view.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/span_math.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/tolerances.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/utils.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/write_tikz.h
+  ${CMAKE_CURRENT_SOURCE_DIR}/write_vtk.h
+  ${QUADRAYS_HEADERS}
+  ${LUT_HEADERS}
+  ${PART_HEADERS}
+  ${COMPRESSION_HEADERS}
+  PARENT_SCOPE)
+
+target_sources(cutcells PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}/mapping.cpp
+  ${CMAKE_CURRENT_SOURCE_DIR}/bernstein.cpp
+  ${CMAKE_CURRENT_SOURCE_DIR}/level_set.cpp
+  ${CMAKE_CURRENT_SOURCE_DIR}/level_set_cell.cpp
+  ${CMAKE_CURRENT_SOURCE_DIR}/selection_expr.cpp
+  ${CMAKE_CURRENT_SOURCE_DIR}/quadrature.cpp
+  ${CMAKE_CURRENT_SOURCE_DIR}/write_vtk.cpp
+)
+
+target_compile_options(cutcells PRIVATE
+  $<$<CONFIG:Release>:-O3>)