DJV-viewer 3.7.0__tar.gz

djv_viewer-3.7.0/.gitattributes

@@ -0,0 +1,12 @@
+# Set the default behavior, in case people don't have core.autocrlf set.
+* text=auto
+
+# Explicitly declare text files you want to always be normalized and converted
+# to native line endings on checkout.
+*.c text
+*.cpp text
+*.h text
+
+# Denote all files that are truly binary and should not be modified.
+*.png binary
+*.jpg binary

djv_viewer-3.7.0/.gitignore

@@ -0,0 +1,17 @@
+build
+Debug
+Release
+RelWithDebInfo
+docs/doxygen
+*~
+.git
+.vscode
+.DS_Store
+
+# Personal build settings, read by etc/Config/default.cmake.
+etc/Config/local.cmake
+__pycache__/
+
+# Python wheel builds (pyproject.toml).
+build-wheel/
+dist/

djv_viewer-3.7.0/.gitmodules

@@ -0,0 +1,3 @@
+[submodule "deps/tlRender"]
+	path = deps/tlRender
+	url = https://github.com/grizzlypeak3d/tlRender.git

djv_viewer-3.7.0/CMakeLists.txt

@@ -0,0 +1,255 @@
+cmake_minimum_required(VERSION 3.31)
+cmake_policy(SET CMP0048 NEW)
+cmake_policy(SET CMP0091 NEW)
+
+file(READ "lib/djv/Models/Version.h" VERSION_H)
+string(REGEX MATCH "VERSION_MAJOR ([0-9]*)" _ ${VERSION_H})
+set(DJV_VERSION_MAJOR ${CMAKE_MATCH_1})
+string(REGEX MATCH "VERSION_MINOR ([0-9]*)" _ ${VERSION_H})
+set(DJV_VERSION_MINOR ${CMAKE_MATCH_1})
+string(REGEX MATCH "VERSION_PATCH ([0-9]*)" _ ${VERSION_H})
+set(DJV_VERSION_PATCH ${CMAKE_MATCH_1})
+string(REGEX MATCH "VERSION_DEV \"([0-9a-z.-]*)\"" _ ${VERSION_H})
+set(DJV_VERSION_DEV ${CMAKE_MATCH_1})
+# Composed here rather than read: the header builds it from the macros
+# above, so there is no literal in the file to match. Keep this in step
+# with the way the header spells it.
+set(DJV_VERSION_FULL
+    "${DJV_VERSION_MAJOR}.${DJV_VERSION_MINOR}.${DJV_VERSION_PATCH}${DJV_VERSION_DEV}")
+
+project(
+    DJV
+    VERSION ${DJV_VERSION_MAJOR}.${DJV_VERSION_MINOR}.${DJV_VERSION_PATCH}
+    DESCRIPTION "DJV is an open source application for media playback and review."
+    HOMEPAGE_URL "https://github.com/grizzlypeak3d/DJV"
+    LANGUAGES CXX)
+
+# A Python wheel build: scikit-build-core sets SKBUILD. The wheel settings
+# are read before the options below, the way "cmake -C" would read them, so
+# they win.
+if(SKBUILD)
+    include(etc/Config/wheel.cmake)
+    include(etc/Python/djvWheel.cmake)
+endif()
+
+#-------------------------------------------------------------------------------
+# Options
+
+# Packaging gathers the dependencies out of the install prefix, where the
+# super build put them; a build against system packages has none there.
+# The package is made either way, with or without them in it.
+set(DJV_PACKAGE_DEPS ON CACHE BOOL "Package the super build's dependencies with the install")
+set(DJV_MACOS_PACKAGE OFF CACHE BOOL "Enable packaging for macOS")
+set(DJV_WINDOWS_PACKAGE OFF CACHE BOOL "Enable packaging for Windows")
+set(DJV_PROGRAMS ON CACHE BOOL "Build programs")
+set(DJV_PYTHON OFF CACHE BOOL "Enable support for Python")
+# Where the djv package goes, relative to the install prefix. The default
+# keeps "PYTHONPATH=<prefix>/lib" working; a wheel puts the package at the
+# top of its install.
+set(DJV_PYTHON_INSTALL_DIR "lib/djv" CACHE STRING "Python package install directory")
+set(DJV_TLRENDER_PACKAGE OFF CACHE BOOL "Use an installed tlRender rather than deps/tlRender")
+set(DJV_TESTS OFF CACHE BOOL "Build tests")
+set(DJV_TESTS_NO_GL OFF CACHE BOOL "Run only the tests that do not need OpenGL")
+set(DJV_GCOV OFF CACHE BOOL "Enable gcov code coverage")
+set(DJV_SANITIZE "" CACHE STRING "Enable sanitizers (comma-separated, e.g. address,undefined)")
+
+#-------------------------------------------------------------------------------
+# Internal configuration
+
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/Modules)
+
+# The libraries mark what only development needs -- static libraries,
+# headers, CMake configuration -- as "dev"; everything else lands here, and
+# packaging takes this component alone. Installing to a prefix takes every
+# component, so a source build still gets the development files.
+set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME runtime)
+
+if(NOT CMAKE_CXX_STANDARD)
+    set(CMAKE_CXX_STANDARD 20)
+endif()
+
+if(DJV_TESTS)
+    set(CTEST_OUTPUT_ON_FAILURE ON)
+    enable_testing()
+endif()
+
+if(MSVC)
+    set(CMAKE_MSVC_RUNTIME_LIBRARY MultiThreaded$<$<CONFIG:Debug>:Debug>DLL)
+    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
+    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP")
+else()
+    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Wno-unused-parameter")
+endif()
+
+if(DJV_GCOV)
+    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --coverage -fprofile-update=atomic")
+    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} --coverage -fprofile-update=atomic")
+    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} --coverage -fprofile-update=atomic")
+endif()
+
+if(DJV_SANITIZE)
+    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=${DJV_SANITIZE} -fno-omit-frame-pointer")
+    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fsanitize=${DJV_SANITIZE} -fno-omit-frame-pointer")
+    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -fsanitize=${DJV_SANITIZE}")
+    set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -fsanitize=${DJV_SANITIZE}")
+endif()
+
+if(APPLE)
+    set(CMAKE_FIND_FRAMEWORK LAST)
+endif()
+
+if(WIN32)
+elseif(APPLE)
+    # Only the bundle keeps the libraries in Frameworks; the zip and a
+    # prefix install put them in lib, so the search path follows the
+    # layout being made.
+    if(DJV_MACOS_PACKAGE)
+        set(CMAKE_INSTALL_RPATH "@executable_path/../Frameworks")
+    else()
+        set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
+    endif()
+    # The freshly built libraries have to come before the installed
+    # copies, or a binary run from the build tree quietly loads the
+    # stale install -- so they are gathered into one directory that
+    # leads the search path. The install prefix entry cannot simply be
+    # dropped: CMake adds it back for the prebuilt dependencies, and
+    # after the build tree's own directories only because they are
+    # listed here first.
+    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
+    set(CMAKE_BUILD_RPATH
+        "${CMAKE_BINARY_DIR}/lib"
+        "${CMAKE_INSTALL_PREFIX}/lib")
+else()
+    set(CMAKE_INSTALL_RPATH "$ORIGIN/../lib")
+endif()
+# The rest of an rpath, relative to <prefix>/lib: a wheel names the libraries
+# of the tlrender and feather_tk packages beside it. The libraries are loaded
+# by Python as well as by the executable there, so on macOS the search starts
+# from the library rather than the executable.
+if(DJV_INSTALL_RPATH_EXTRA)
+    if(APPLE)
+        set(CMAKE_INSTALL_RPATH "@loader_path/../lib")
+        foreach(path ${DJV_INSTALL_RPATH_EXTRA})
+            list(APPEND CMAKE_INSTALL_RPATH "@loader_path/${path}")
+        endforeach()
+    elseif(UNIX)
+        foreach(path ${DJV_INSTALL_RPATH_EXTRA})
+            list(APPEND CMAKE_INSTALL_RPATH "$ORIGIN/${path}")
+        endforeach()
+    endif()
+endif()
+
+set_property(GLOBAL PROPERTY USE_FOLDERS ON)
+
+#-------------------------------------------------------------------------------
+# Dependencies
+
+find_package(ZLIB REQUIRED)
+
+# Python dependencies
+#
+# The djv module is built the way feather-tk's is, the stable ABI or not and
+# against the same nanobind library, since nanobind shares types only
+# between modules built alike and djv takes its types from feather_tk and
+# tlrender. So this is feather-tk's own option, declared here too because
+# feather-tk is not added until below.
+set(ftk_PYTHON_STABLE_ABI ON CACHE BOOL "Build the Python module against the stable ABI")
+if(DJV_PYTHON)
+    # Development.Module rather than Development, as feather-tk asks: an
+    # extension module does not link libpython.
+    set(DJV_PYTHON_COMPONENTS Interpreter Development.Module)
+    set(DJV_PYTHON_VERSION 3.10)
+    set(DJV_NANOBIND_LIBRARY nanobind-static)
+    if(ftk_PYTHON_STABLE_ABI)
+        # nanobind supports the stable ABI from Python 3.12.
+        list(APPEND DJV_PYTHON_COMPONENTS Development.SABIModule)
+        set(DJV_PYTHON_VERSION 3.12)
+        set(DJV_NANOBIND_LIBRARY nanobind-static-abi3)
+    endif()
+    find_package(Python ${DJV_PYTHON_VERSION} REQUIRED COMPONENTS ${DJV_PYTHON_COMPONENTS})
+    find_package(nanobind REQUIRED CONFIG)
+endif()
+
+#-------------------------------------------------------------------------------
+# tlRender
+
+if(DJV_TLRENDER_PACKAGE)
+    # tlRender's package finds feather-tk's.
+    find_package(tlRender REQUIRED)
+    # The resource tool is the feather-tk package's imported target; the
+    # name ftk_icon_resources() falls back on is the one inside feather-tk's
+    # own tree.
+    set(ftk_RESOURCE_COMMAND ftk::ftk-resource)
+    if(DJV_PYTHON)
+        # feather-tk builds this library when it is added with tlRender; an
+        # installed one leaves it to us. Built the same way, since the
+        # binding libraries are compiled into the module against it.
+        nanobind_build_library(${DJV_NANOBIND_LIBRARY})
+        if(ftk_PYTHON_STABLE_ABI)
+            target_compile_definitions(${DJV_NANOBIND_LIBRARY} PUBLIC Py_LIMITED_API=0x030C0000)
+        endif()
+    endif()
+else()
+    find_package(Git REQUIRED)
+    if(NOT EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/deps/tlRender/CMakeLists.txt")
+        execute_process(
+            COMMAND ${GIT_EXECUTABLE} submodule update --init --recursive
+            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+            RESULT_VARIABLE GIT_SUBMODULE_RESULT)
+        if(NOT GIT_SUBMODULE_RESULT EQUAL 0)
+            message(FATAL_ERROR "git submodule update failed with ${GIT_SUBMODULE_RESULT}")
+        endif()
+    endif()
+
+    add_subdirectory(deps/tlRender)
+    add_library(tlRender::tlCore ALIAS tlCore)
+    add_library(tlRender::tlGL ALIAS tlGL)
+    add_library(tlRender::tlIO ALIAS tlIO)
+    add_library(tlRender::tlTimeline ALIAS tlTimeline)
+    add_library(tlRender::tlUI ALIAS tlUI)
+endif()
+
+#-------------------------------------------------------------------------------
+# Sub-directories
+
+add_subdirectory(lib/djv)
+if(DJV_PROGRAMS)
+    add_subdirectory(bin)
+endif()
+if(DJV_TESTS)
+    add_subdirectory(tests)
+endif()
+# Before the documentation, which installs the licenses page this writes.
+add_subdirectory(etc/Legal)
+add_subdirectory(docs)
+# A wheel is the application and its documentation: the sample media and the
+# desktop integration are for the packages.
+if(NOT SKBUILD)
+    add_subdirectory(etc/SampleData)
+    if(UNIX AND NOT APPLE)
+        add_subdirectory(etc/Linux)
+    endif()
+endif()
+
+include(CMakePackageConfigHelpers)
+set(INCLUDE_INSTALL_DIR include/djv)
+configure_package_config_file(
+    djvConfig.cmake.in
+    ${CMAKE_CURRENT_BINARY_DIR}/djvConfig.cmake
+    INSTALL_DESTINATION lib/cmake/djv
+    PATH_VARS INCLUDE_INSTALL_DIR)
+install(
+    FILES ${CMAKE_CURRENT_BINARY_DIR}/djvConfig.cmake
+    DESTINATION lib/cmake/djv
+    COMPONENT dev)
+
+#-------------------------------------------------------------------------------
+# Packaging
+
+# Always: the package target is how a build is turned into an archive, and
+# a build against the system's packages wants one as much as a super build
+# does -- it holds DJV alone. DJV_PACKAGE_DEPS decides whether the super
+# build's libraries are gathered into it; see cmake/Modules/Package.cmake.
+include(Package)
+include(CPack)
+include(InstallRequiredSystemLibraries)

djv_viewer-3.7.0/ChangeLog.md

@@ -0,0 +1,356 @@
+## 3.7.0
+
+Changes:
+* Settings and logs move to the application support directory.
+* System Information shows the settings path, log path, and Linux desktop.
+* The Linux package has a desktop entry and icons.
+* The HUD shows the file name of the current image of a sequence.
+* Opening one image of a sequence starts playback at that image.
+* OTIOZ bundle media can be read with the FFmpeg command line.
+* The status bar shows the highlighted menu item's tooltip.
+* The Python bindings use nanobind.
+* Building requires C++20.
+* CineForm movies can be read and written.
+* Hovering the timeline shows a preview of the frame under the cursor.
+* Exposure and soft clip are in the Color section of the Color tool.
+* Individual audio channels can be played.
+* The status indicator shows the options in use, and clicking one shows
+  its controls.
+* The cache sizes and the FFmpeg thread count can be set from the command
+  line.
+* Automatic OCIO input color spaces follow all of the configuration's file
+  rules, including the default rule.
+* Movies can be exported as APV.
+* Movies can be exported from the command line with the Export/Movie
+  command, and -offscreen runs without showing the window.
+* Added global toggle and reset for color controls.
+* The OCIO environment variable is used to initialize the OCIO settings.
+* Add a -mediaReference command line option.
+* The view's color buffer defaults to RGBA F16.
+* Removed custom font settings, a CJK font is now bundled with the application.
+* The window title shows the review or file name. Contributed by timurhai.
+* The FFmpeg settings show the ffmpeg and ffprobe commands.
+* Movies can be exported to Matroska files: FFV1, AV1, H.264, HEVC, and
+  VP9 are written to ".mkv".
+* Style updates.
+* The left and right arrow keys move between the menus.
+* The file browser filters by kind of file: images, movies, audio, and so
+  on.
+* Gestures are supported on touch screens.
+* Library updates:
+    - FFmpeg 9.0.1
+    - OpenAPV 1.1.1.0
+
+Fixes:
+* The heads up display no longer reports the color and pixel of a file
+  that has been closed.
+* A file with a mono audio stream per channel plays all of the channels.
+* A still image paired with an audio file lasts as long as the audio.
+* Settings fixes for running multiple application instances.
+* Clearing the drawing on a compared frame also clears the "B" strokes.
+* A tilt wheel no longer zooms the view.
+* The window is drawn while it is being resized on macOS and Windows.
+* A movie's start timecode is found when a subtitle or other data track
+  comes before its timecode track.
+* Opening many files at once no longer reads every one of them.
+* Color management no longer slows playback when the timeline shows
+  thumbnails; a regression in 3.6.0.
+* Enlarging with High Quality no longer shows resize artifacts.
+* USD support, removed in 3.6.0, is back in source builds.
+* High Quality filtering no longer softens pictures shown or exported at
+  their own size.
+* Audio no longer crackles when playing faster or slower.
+* A playlist restores a tiled comparison with all of its files.
+
+## 3.6.0
+
+Changes:
+* Add review sessions and annotations, contributed by MattRM2.
+* Add playlists.
+* Directories can be opened with a wildcard filter and a depth.
+* Reloading an image sequence picks up new frames.
+* The file list can be reordered by dragging.
+* Add Python bindings and a full Python version of DJV as an example.
+* Add support for reading camera raw formats (CR3, NEF, ARW, DNG, and others).
+* Add support for reading OpenEXR files with HTJ2K compression.
+* Automatic OCIO input color spaces, including the OpenEXR "colorInteropID"
+  attribute.
+* The LUT can be applied inverted for ICC monitor profiles.
+* Mouse wheel actions can be remapped for zooming and scrubbing.
+* Movie and image sequence exports carry color information.
+* Add thumbnails to the file browser.
+* The file browser can be opened in a window of its own.
+* The file browser can be driven from the keyboard.
+* The FFmpegCmd plugin is merged into the FFmpeg plugin as a fallback.
+* Add presets for movie exports.
+* Movies can be exported with the FFmpeg command line application.
+* AV1 support now works on Windows.
+* The Information tool shows the file name and directory.
+* The color pickers gain a palette of preset colors, and remember which
+  tab was used.
+* Library updates:
+    - OpenColorIO 2.5.2
+    - OpenEXR 3.4.15
+    - OpenImageIO 3.1.16.0
+    - libtiff 4.7.2
+
+Fixes:
+* A warning is shown when comparing files that do not overlap in time.
+* The color corrections are applied in linear when the OCIO configuration
+  names a scene_linear role.
+* The keypad's Enter key works like the Return key.
+* File information showed a frame rate of zero for movies whose container
+  declares it as "0/0".
+* Fixes for anamorphic movies.
+
+## 3.5.0
+
+Changes:
+* Add support for OTIO multiple media references.
+* Add support for OTIO spatial coordinates.
+* Add support for partial image sequences.
+* Add support for reading SVG files.
+* Add audio export.
+* Add a "butterfly" compare mode.
+* Remove "A" compare mode and make the other compare modes toggles.
+* Add support for exporting A/B comparisons.
+* Add a gain to the difference comparison, so that differences too small to
+  see at their own size can be brought up.
+* Group the information tool into video, audio, and file metadata, with the
+  video first, and show the format of the file next to the format it is
+  decoded to.
+* Movie exports carry the start timecode of the range that was exported.
+* Add high quality image scaling options.
+* Multiple tools can be opened at the same time.
+* Add a waveform height option.
+* Add an image negative option.
+* Add custom aspect ratios.
+* Add a center marker option.
+* Add more grid and HUD options.
+* Add an option for whether the magnify tool tracks the view.
+* Multiple files can be opened with the file browser.
+* Add the NotoSansCJKsc-Regular font for basic CJK text rendering.
+* Add more OpenEXR attributes.
+* Add the JPEG file format to export options.
+* Add a FFmpeg option to enable hardware decoding for compatible files.
+* Add the aom library for AV1 decoding support (macOS and Linux).
+* Allow the "Escape" key to be used for keyboard shortcuts.
+* Add image I/O library versions to the system information.
+* Performance improvements.
+* Style updates.
+* Library updates:
+    - FFmpeg 8.1.2
+    - OpenImageIO v3.1.14.0
+    - subprocess
+
+Fixes:
+* Add the file extensions ".avif" and ".mxf" to the FFmpeg command plugin.
+* Fix the duration of movies read with the FFmpeg command plugin.
+* Fix metadata with multiple lines overlapping other entries in the
+  information tool.
+* Fix opening image sequences whose name ends with a hyphen before the frame
+  number, e.g. "shot-0001.exr".
+* Fix exported image sequences being numbered from zero rather than with the
+  frame numbers the export tool shows, which also kept the overwrite warning
+  from appearing when exporting a range twice.
+* Fix the macOS application not starting after being renamed.
+* Fixes for the grid and outline in compare mode.
+* Fixes to prevent cache usage exceeding 100%.
+* Fixes for log file failures.
+
+
+## 3.4.2
+
+Fixes:
+* Fix for FFmpeg command on macOS.
+
+
+## 3.4.1
+
+Fixes:
+* Build fixes.
+
+
+Changes:
+## 3.4.0
+
+Changes:
+* Movies can now be decoded using the ffmpeg command line application.
+* Custom fonts can be added to support different languages.
+* Add a setting to start playback when opening files.
+* Add settings for the thumbnail cache.
+* Add text selection to the information, messages, and system log tools.
+* Add auto-scroll to the messages and system log tools.
+* Move status bar indicators into a popup widget.
+* General performance improvements.
+* USD support has been removed from the packages, but is still available when building from source.
+* Library updates:
+    - FFmpeg 8.1
+    - SVT-AV1 v4.0.1
+    - USD v26.03
+
+Fixes:
+* Mouse focus fixes for zooming the viewport and timeline.
+* Image sequence fix for the built-in file browser.
+* Image sequence fix for files in the same directory with similar names, e.g.,
+  "asteroid_V01" and "asteroid_V02".
+
+
+## 3.3.4
+
+Features:
+* Add a button for switching playback loop mode.
+* Switch compare mode to "A" if there is only a single file open.
+
+Fixes:
+* Fix directory selection for exports.
+* Fix flipped export for images and image sequences.
+* Fix for YUV->RGB conversion.
+* Fix for overlay compare mode.
+* Fix for timeline thumbnails shortcuts.
+* Fix for window "Float On Top" option.
+* Fix for values being clamped to 0.0-1.0 in the color picker tool.
+* Fix for contrast control in the color tool.
+
+
+## 3.3.3
+
+Features:
+* Add the escape key for closing the secondary window.
+
+Fixes:
+* Fix flipped export.
+* Fix tools tooltips.
+
+
+## 3.3.2
+
+Features:
+* Add pixel and mouse binding labels to the color picker and magnifier tools.
+* Both the color picker and magnifier update when picking with the mouse.
+* Add status bar indicators for displaying when mirroring is enabled.
+* Add the version number to the window title.
+* Add a command line flag to print the version.
+* Add a dialog for displaying system information.
+
+Fixes:
+* Fix for keyboard shortcuts search box.
+* Fix for window title bar appearing off screen.
+* Fix for video levels.
+
+
+## 3.3.1
+
+Fixes:
+* macOS package fixes.
+
+
+## 3.3.0
+
+Features:
+* The built-in file browser can now display image sequences as a single item
+  with frame range.
+* The command line now accepts file sequences like "render.#.exr".
+* The tab key can now be assigned to shortcuts (e.g., Ctrl+Tab and
+  Ctrl+Shit+Tab for changing the current file).
+* Add the "Extra 1" and "Extra 2" buttons to the mouse settings.
+* Add a frame shuttle scale to the mouse settings.
+* Changed the default mouse settings: left button = frame shuttle, middle
+  mouse button = pan
+* Add primary and secondary keyboard shortcuts.
+* Add a search box for keyboard shortcut settings.
+* Add the OCIO configuration name to the color tool.
+* Hide the path for the OCIO and LUT file names in the color tool.
+* Add a magnify tool.
+* Add grid labels.
+* The playback speed can be increased and decreased by pressing forward or
+  reverse multiple times.
+* Add status bar indicators to display whether color controls, the audio sync
+  offset, or the output device are enabled.
+* Remove text eliding from the tab bar and HUD file names.
+* Library updates:
+    - SDL2 release-2.32.10
+
+Fixes:
+* Fix compare overlay and difference flipping the image.
+* Fix middle and right mouse buttons that were swapped in the settings.
+* Fix the mouse settings to only show the "Command" key on macOS.
+* Fix for the clipboard that was causing excessive CPU usage on Gnome.
+* Fix for compiling on Rocky 8.
+* Fix for keyboard shortcuts in the secondary window.
+
+
+## 3.2.1
+
+Fixes:
+* macOS package fixes.
+
+
+## 3.2.0
+
+Features:
+* SDL2 support for window creation and input handling.
+* Support for OpenImageIO.
+* Signed macOS packages.
+* Library updates:
+    - tlRender 0.13.0
+    - feather-tk 0.5.0
+    - OpenTimelineIO v0.18.0
+    - OpenColorIO v2.5.0
+    - OpenEXR v3.3.6
+    - Imath 3.2.1
+    - FFmpeg 8.0
+    - USD v25.11
+    - libpng v1.6.50
+    - libjpeg-turbo 3.1.1
+    - OpenSSL 3.5.2
+    - curl 8_15_0
+    - freetype 2-14-1
+    - minizip 4.0.10
+
+Fixes:
+* Fix application closing when window is minimized.
+* Fix outline with alpha blend modes.
+* Fix outline rendering underneath grid.
+* Fix display scale values.
+* Add the units to the audio sync offset label.
+* Fix opening file associations on macOS.
+* Fixes for keyboard mapping and number pad.
+* Fixes for building with CMake 4.x versions.
+* Fix for cached frames wrapping around the timeline.
+
+
+## 3.1.1
+
+Features:
+* Make the timeline minimized by default.
+* Add sample data for testing.
+
+Fixes:
+* Make the default color buffer RGBA_F32.
+* More fixes for OpenColorIO settings.
+
+
+## 3.1.0
+
+Features:
+* Add support for the OCIO environment variable and built-in OCIO configurations.
+* Add more speed options.
+* Add buttons to clear keyboard shortcuts.
+* Add a setting for whether the file browser shows hidden files.
+* Add position and zoom controls to the view tool, and a zoom control to the tool bar.
+* Make the timeline ticks more visible.
+* Add a keyboard shortcut (Ctrl+G) for enabling the grid.
+* Add a keyboard shortcut (Ctrl+N) for toggling whether OCIO is enabled.
+* Add a keyboard shortcut (Ctrl+K) for toggling whether the LUT is enabled.
+* Add a Windows NSIS package.
+* Use the current playback speed and layer when exporting.
+* Add a setting for which mouse button is used for panning, compare wipe, color picker, and frame shuttle.
+* Add a setting for scaling the mouse wheel zoom in the viewport and timeline.
+* Add a button to manually save the settings.
+
+Fixes:
+* Fix for image sequences with uppercase file extensions.
+* Fix for building with BMD support.
+* Fix for OCIO settings not saving.
+* Fix the timeline duration on the bottom tool bar to show the in/out range.

djv_viewer-3.7.0/LICENSE.txt

@@ -0,0 +1,26 @@
+Copyright Contributors to the DJV project.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+* Redistributions of source code must retain the above copyright notice, this
+  list of conditions, and the following disclaimer.
+* Redistributions in binary form must reproduce the above copyright notice,
+  this list of conditions, and the following disclaimer in the documentation
+  and/or other materials provided with the distribution.
+* Neither the names of the copyright holders nor the names of any
+  contributors may be used to endorse or promote products derived from this
+  software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
+AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
+IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
+ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
+LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+SUBSTITUE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+POSSIBILITY OF SUCH DAMAGE.
+