@zigc/lib 0.17.0-dev.27 → 0.17.0-dev.296

package/std/heap/BufferFirstAllocator.zig

@@ -0,0 +1,165 @@
+//! An allocator that attempts to allocate from the given buffer, falling back to
+//! `fallback_allocator` if this fails.
+
+const std = @import("../std.zig");
+const heap = std.heap;
+const testing = std.testing;
+
+const Alignment = std.mem.Alignment;
+const Allocator = std.mem.Allocator;
+const FixedBufferAllocator = std.heap.FixedBufferAllocator;
+
+const BufferFirstAllocator = @This();
+
+fallback_allocator: Allocator,
+fixed_buffer_allocator: FixedBufferAllocator,
+
+pub fn init(buffer: []u8, fallback_allocator: Allocator) BufferFirstAllocator {
+    return .{
+        .fallback_allocator = fallback_allocator,
+        .fixed_buffer_allocator = .init(buffer),
+    };
+}
+
+pub fn allocator(self: *BufferFirstAllocator) Allocator {
+    return .{
+        .ptr = self,
+        .vtable = &.{
+            .alloc = alloc,
+            .resize = resize,
+            .remap = remap,
+            .free = free,
+        },
+    };
+}
+
+fn alloc(
+    ctx: *anyopaque,
+    len: usize,
+    alignment: Alignment,
+    ra: usize,
+) ?[*]u8 {
+    const self: *BufferFirstAllocator = @ptrCast(@alignCast(ctx));
+    return FixedBufferAllocator.alloc(&self.fixed_buffer_allocator, len, alignment, ra) orelse
+        return self.fallback_allocator.rawAlloc(len, alignment, ra);
+}
+
+fn resize(
+    ctx: *anyopaque,
+    buf: []u8,
+    alignment: Alignment,
+    new_len: usize,
+    ra: usize,
+) bool {
+    const self: *BufferFirstAllocator = @ptrCast(@alignCast(ctx));
+    if (self.fixed_buffer_allocator.ownsPtr(buf.ptr)) {
+        return FixedBufferAllocator.resize(&self.fixed_buffer_allocator, buf, alignment, new_len, ra);
+    } else {
+        return self.fallback_allocator.rawResize(buf, alignment, new_len, ra);
+    }
+}
+
+fn remap(
+    context: *anyopaque,
+    memory: []u8,
+    alignment: Alignment,
+    new_len: usize,
+    return_address: usize,
+) ?[*]u8 {
+    const self: *BufferFirstAllocator = @ptrCast(@alignCast(context));
+    if (self.fixed_buffer_allocator.ownsPtr(memory.ptr)) {
+        return FixedBufferAllocator.remap(&self.fixed_buffer_allocator, memory, alignment, new_len, return_address);
+    } else {
+        return self.fallback_allocator.rawRemap(memory, alignment, new_len, return_address);
+    }
+}
+
+fn free(
+    ctx: *anyopaque,
+    buf: []u8,
+    alignment: Alignment,
+    ra: usize,
+) void {
+    const self: *BufferFirstAllocator = @ptrCast(@alignCast(ctx));
+    if (self.fixed_buffer_allocator.ownsPtr(buf.ptr)) {
+        return FixedBufferAllocator.free(&self.fixed_buffer_allocator, buf, alignment, ra);
+    } else {
+        return self.fallback_allocator.rawFree(buf, alignment, ra);
+    }
+}
+
+test "BufferFirstAllocator" {
+    // Buffer first specific tests
+    {
+        var buffer: [10]u8 = undefined;
+        var bfa_state: BufferFirstAllocator = .init(&buffer, std.testing.allocator);
+        const bfa = bfa_state.allocator();
+
+        // We're under the limit, so we should be allocated in the buffer
+        const txt0 = "hellowrld";
+        const buf0 = try bfa.create(@TypeOf(txt0.*));
+        buf0.* = txt0.*;
+        try testing.expect(bfa_state.fixed_buffer_allocator.ownsPtr(buf0.ptr));
+
+        // We're now over the limit, so we should be allocated from the fallback
+        const txt1 = "test!";
+        const buf1 = try bfa.create(@TypeOf(txt1.*));
+        buf1.* = txt1.*;
+        try testing.expect(!bfa_state.fixed_buffer_allocator.ownsPtr(buf1.ptr));
+
+        // Free the allocation that took up space in the buffer
+        try testing.expectEqualStrings(txt0, buf0);
+        bfa.destroy(buf0);
+
+        // The next allocation would go in the buffer, but it's too big so it doesn't
+        const txt2 = "qwertyqwerty";
+        const buf2 = try bfa.create(@TypeOf(txt2.*));
+        buf2.* = txt2.*;
+        try testing.expect(!bfa_state.fixed_buffer_allocator.ownsPtr(buf2.ptr));
+
+        // The next allocation is smaller and fits in the buffer
+        const txt3 = "dvorak";
+        const buf3 = try bfa.create(@TypeOf(txt3.*));
+        buf3.* = txt3.*;
+        try testing.expect(bfa_state.fixed_buffer_allocator.ownsPtr(buf3.ptr));
+
+        // The remainder in the buffer is too small for the following allocation so it falls back
+        const txt4 = "moretext";
+        const buf4 = try bfa.create(@TypeOf(txt4.*));
+        buf4.* = txt4.*;
+        try testing.expect(!bfa_state.fixed_buffer_allocator.ownsPtr(buf4.ptr));
+
+        // Check equality on the remaining buffers and free them
+        try testing.expectEqualStrings(txt1, buf1);
+        bfa.destroy(buf1);
+        try testing.expectEqualStrings(txt2, buf2);
+        bfa.destroy(buf2);
+        try testing.expectEqualStrings(txt3, buf3);
+        bfa.destroy(buf3);
+        try testing.expectEqualStrings(txt4, buf4);
+        bfa.destroy(buf4);
+
+        try testing.expectEqual(0, bfa_state.fixed_buffer_allocator.end_index);
+    }
+
+    // Standard allocator tests
+    {
+        var buf: [4096]u8 = undefined;
+        {
+            var bfa: BufferFirstAllocator = .init(&buf, std.testing.allocator);
+            try heap.testAllocator(bfa.allocator());
+        }
+        {
+            var bfa: BufferFirstAllocator = .init(&buf, std.testing.allocator);
+            try heap.testAllocatorAligned(bfa.allocator());
+        }
+        {
+            var bfa: BufferFirstAllocator = .init(&buf, std.testing.allocator);
+            try heap.testAllocatorLargeAlignment(bfa.allocator());
+        }
+        {
+            var bfa: BufferFirstAllocator = .init(&buf, std.testing.allocator);
+            try heap.testAllocatorAlignedShrink(bfa.allocator());
+        }
+    }
+}

package/std/heap/debug_allocator.zig

@@ -164,7 +164,7 @@ pub fn DebugAllocator(comptime config: Config) type {
     return struct {
         backing_allocator: Allocator = std.heap.page_allocator,
         /// Tracks the active bucket, which is the one that has free slots in it.
-        buckets: [small_bucket_count]?*BucketHeader = [1]?*BucketHeader{null} ** small_bucket_count,
+        buckets: [small_bucket_count]?*BucketHeader = @splat(null),
         large_allocations: LargeAllocTable = .empty,
         total_requested_bytes: @TypeOf(total_requested_bytes_init) = total_requested_bytes_init,
         requested_memory_limit: @TypeOf(requested_memory_limit_init) = requested_memory_limit_init,
@@ -189,7 +189,7 @@ pub fn DebugAllocator(comptime config: Config) type {
         const page_size = config.page_size;
         const page_align: mem.Alignment = .fromByteUnits(page_size);
         /// Integer type for pointing to slots in a small allocation
-        const SlotIndex = std.meta.Int(.unsigned, math.log2(page_size) + 1);
+        const SlotIndex = @Int(.unsigned, math.log2(page_size) + 1);
 
         const total_requested_bytes_init = if (config.enable_memory_limit) @as(usize, 0) else {};
         const requested_memory_limit_init = if (config.enable_memory_limit) @as(usize, math.maxInt(usize)) else {};

package/std/heap/memory_pool.zig

@@ -3,11 +3,6 @@ const Allocator = std.mem.Allocator;
 const Alignment = std.mem.Alignment;
 const MemoryPool = std.heap.MemoryPool;
 
-/// Deprecated.
-pub fn Managed(comptime Item: type) type {
-    return ExtraManaged(Item, .{ .alignment = null });
-}
-
 /// A memory pool that can allocate objects of a single type very quickly.
 /// Use this when you need to allocate a lot of objects of the same type,
 /// because it outperforms general purpose allocators.
@@ -18,11 +13,6 @@ pub fn Aligned(comptime Item: type, comptime alignment: Alignment) type {
     return Extra(Item, .{ .alignment = alignment });
 }
 
-/// Deprecated.
-pub fn AlignedManaged(comptime Item: type, comptime alignment: Alignment) type {
-    return ExtraManaged(Item, .{ .alignment = alignment });
-}
-
 pub const Options = struct {
     /// The alignment of the memory pool items. Use `null` for natural alignment.
     alignment: ?Alignment = null,
@@ -83,13 +73,6 @@ pub fn Extra(comptime Item: type, comptime pool_options: Options) type {
             pool.* = undefined;
         }
 
-        pub fn toManaged(pool: Pool, allocator: Allocator) ExtraManaged(Item, pool_options) {
-            return .{
-                .allocator = allocator,
-                .unmanaged = pool,
-            };
-        }
-
         /// Pre-allocates `num` items and adds them to the memory pool.
         /// This allows at least `num` active allocations before an
         /// `OutOfMemory` error might happen when calling `create()`.
@@ -114,7 +97,7 @@ pub fn Extra(comptime Item: type, comptime pool_options: Options) type {
         /// NOTE: If `mode` is `free_all`, the function will always return `true`.
         pub fn reset(pool: *Pool, allocator: Allocator, mode: ResetMode) bool {
             // TODO: Potentially store all allocated objects in a list as well, allowing to
-            //       just move them into the free list instead of actually releasing the memory.
+            // just move them into the free list instead of actually releasing the memory.
 
             var arena = pool.arena_state.promote(allocator);
             defer pool.arena_state = arena.state;
@@ -155,182 +138,56 @@ pub fn Extra(comptime Item: type, comptime pool_options: Options) type {
     };
 }
 
-/// Deprecated.
-pub fn ExtraManaged(comptime Item: type, comptime pool_options: Options) type {
-    if (pool_options.alignment) |a| {
-        if (a.compare(.eq, .of(Item))) {
-            var new_options = pool_options;
-            new_options.alignment = null;
-            return ExtraManaged(Item, new_options);
-        }
-    }
-    return struct {
-        const Pool = @This();
-
-        allocator: Allocator,
-        unmanaged: Unmanaged,
-
-        pub const Unmanaged = Extra(Item, pool_options);
-        pub const item_size = Unmanaged.item_size;
-        pub const item_alignment = Unmanaged.item_alignment;
-
-        const ItemPtr = Unmanaged.ItemPtr;
-
-        /// Creates a new memory pool.
-        pub fn init(allocator: Allocator) Pool {
-            return Unmanaged.empty.toManaged(allocator);
-        }
-
-        /// Creates a new memory pool and pre-allocates `num` items.
-        /// This allows up to `num` active allocations before an
-        /// `OutOfMemory` error might happen when calling `create()`.
-        pub fn initCapacity(allocator: Allocator, num: usize) Allocator.Error!Pool {
-            return (try Unmanaged.initCapacity(allocator, num)).toManaged(allocator);
-        }
-
-        /// Destroys the memory pool and frees all allocated memory.
-        pub fn deinit(pool: *Pool) void {
-            pool.unmanaged.deinit(pool.allocator);
-            pool.* = undefined;
-        }
-
-        /// Pre-allocates `num` items and adds them to the memory pool.
-        /// This allows at least `num` active allocations before an
-        /// `OutOfMemory` error might happen when calling `create()`.
-        pub fn addCapacity(pool: *Pool, num: usize) Allocator.Error!void {
-            return pool.unmanaged.addCapacity(pool.allocator, num);
-        }
-
-        pub const ResetMode = Unmanaged.ResetMode;
-
-        /// Resets the memory pool and destroys all allocated items.
-        /// This can be used to batch-destroy all objects without invalidating the memory pool.
-        ///
-        /// The function will return whether the reset operation was successful or not.
-        /// If the reallocation  failed `false` is returned. The pool will still be fully
-        /// functional in that case, all memory is released. Future allocations just might
-        /// be slower.
-        ///
-        /// NOTE: If `mode` is `free_all`, the function will always return `true`.
-        pub fn reset(pool: *Pool, mode: ResetMode) bool {
-            return pool.unmanaged.reset(pool.allocator, mode);
-        }
-
-        /// Creates a new item and adds it to the memory pool.
-        pub fn create(pool: *Pool) Allocator.Error!ItemPtr {
-            return pool.unmanaged.create(pool.allocator);
-        }
-
-        /// Destroys a previously created item.
-        /// Only pass items to `ptr` that were previously created with `create()` of the same memory pool!
-        pub fn destroy(pool: *Pool, ptr: ItemPtr) void {
-            return pool.unmanaged.destroy(ptr);
-        }
-
-        fn allocNew(pool: *Pool) Allocator.Error!*align(item_alignment) [item_size]u8 {
-            return pool.unmanaged.allocNew(pool.allocator);
-        }
-    };
-}
-
 test "basic" {
     const a = std.testing.allocator;
 
-    {
-        var pool: MemoryPool(u32) = .empty;
-        defer pool.deinit(a);
-
-        const p1 = try pool.create(a);
-        const p2 = try pool.create(a);
-        const p3 = try pool.create(a);
-
-        // Assert uniqueness
-        try std.testing.expect(p1 != p2);
-        try std.testing.expect(p1 != p3);
-        try std.testing.expect(p2 != p3);
+    var pool: MemoryPool(u32) = .empty;
+    defer pool.deinit(a);
 
-        pool.destroy(p2);
-        const p4 = try pool.create(a);
-
-        // Assert memory reuse
-        try std.testing.expect(p2 == p4);
-    }
+    const p1 = try pool.create(a);
+    const p2 = try pool.create(a);
+    const p3 = try pool.create(a);
 
-    {
-        var pool: Managed(u32) = .init(std.testing.allocator);
-        defer pool.deinit();
+    // Assert uniqueness
+    try std.testing.expect(p1 != p2);
+    try std.testing.expect(p1 != p3);
+    try std.testing.expect(p2 != p3);
 
-        const p1 = try pool.create();
-        const p2 = try pool.create();
-        const p3 = try pool.create();
+    pool.destroy(p2);
+    const p4 = try pool.create(a);
 
-        // Assert uniqueness
-        try std.testing.expect(p1 != p2);
-        try std.testing.expect(p1 != p3);
-        try std.testing.expect(p2 != p3);
-
-        pool.destroy(p2);
-        const p4 = try pool.create();
-
-        // Assert memory reuse
-        try std.testing.expect(p2 == p4);
-    }
+    // Assert memory reuse
+    try std.testing.expect(p2 == p4);
 }
 
 test "initCapacity (success)" {
     const a = std.testing.allocator;
 
-    {
-        var pool: MemoryPool(u32) = try .initCapacity(a, 4);
-        defer pool.deinit(a);
-
-        _ = try pool.create(a);
-        _ = try pool.create(a);
-        _ = try pool.create(a);
-    }
-
-    {
-        var pool: Managed(u32) = try .initCapacity(a, 4);
-        defer pool.deinit();
+    var pool: MemoryPool(u32) = try .initCapacity(a, 4);
+    defer pool.deinit(a);
 
-        _ = try pool.create();
-        _ = try pool.create();
-        _ = try pool.create();
-    }
+    _ = try pool.create(a);
+    _ = try pool.create(a);
+    _ = try pool.create(a);
 }
 
 test "initCapacity (failure)" {
     const failer = std.testing.failing_allocator;
     try std.testing.expectError(error.OutOfMemory, MemoryPool(u32).initCapacity(failer, 5));
-    try std.testing.expectError(error.OutOfMemory, Managed(u32).initCapacity(failer, 5));
 }
 
 test "growable" {
     const a = std.testing.allocator;
 
-    {
-        var pool: Extra(u32, .{ .growable = false }) = try .initCapacity(a, 4);
-        defer pool.deinit(a);
-
-        _ = try pool.create(a);
-        _ = try pool.create(a);
-        _ = try pool.create(a);
-        _ = try pool.create(a);
-
-        try std.testing.expectError(error.OutOfMemory, pool.create(a));
-    }
-
-    {
-        var pool: ExtraManaged(u32, .{ .growable = false }) = try .initCapacity(a, 4);
-        defer pool.deinit();
+    var pool: Extra(u32, .{ .growable = false }) = try .initCapacity(a, 4);
+    defer pool.deinit(a);
 
-        _ = try pool.create();
-        _ = try pool.create();
-        _ = try pool.create();
-        _ = try pool.create();
+    _ = try pool.create(a);
+    _ = try pool.create(a);
+    _ = try pool.create(a);
+    _ = try pool.create(a);
 
-        try std.testing.expectError(error.OutOfMemory, pool.create());
-    }
+    try std.testing.expectError(error.OutOfMemory, pool.create(a));
 }
 
 test "greater than pointer default alignment" {
@@ -339,21 +196,11 @@ test "greater than pointer default alignment" {
     };
     const a = std.testing.allocator;
 
-    {
-        var pool: MemoryPool(Foo) = .empty;
-        defer pool.deinit(a);
-
-        const foo: *Foo = try pool.create(a);
-        pool.destroy(foo);
-    }
-
-    {
-        var pool: Managed(Foo) = .init(a);
-        defer pool.deinit();
+    var pool: MemoryPool(Foo) = .empty;
+    defer pool.deinit(a);
 
-        const foo: *Foo = try pool.create();
-        pool.destroy(foo);
-    }
+    const foo: *Foo = try pool.create(a);
+    pool.destroy(foo);
 }
 
 test "greater than pointer manual alignment" {
@@ -362,19 +209,9 @@ test "greater than pointer manual alignment" {
     };
     const a = std.testing.allocator;
 
-    {
-        var pool: Aligned(Foo, .@"16") = .empty;
-        defer pool.deinit(a);
-
-        const foo: *align(16) Foo = try pool.create(a);
-        pool.destroy(foo);
-    }
+    var pool: Aligned(Foo, .@"16") = .empty;
+    defer pool.deinit(a);
 
-    {
-        var pool: AlignedManaged(Foo, .@"16") = .init(a);
-        defer pool.deinit();
-
-        const foo: *align(16) Foo = try pool.create();
-        pool.destroy(foo);
-    }
+    const foo: *align(16) Foo = try pool.create(a);
+    pool.destroy(foo);
 }

package/std/heap.zig

@@ -12,6 +12,7 @@ const Alignment = std.mem.Alignment;
 pub const ArenaAllocator = @import("heap/ArenaAllocator.zig");
 pub const SmpAllocator = @import("heap/SmpAllocator.zig");
 pub const FixedBufferAllocator = @import("heap/FixedBufferAllocator.zig");
+pub const BufferFirstAllocator = @import("heap/BufferFirstAllocator.zig");
 pub const PageAllocator = @import("heap/PageAllocator.zig");
 pub const WasmAllocator = if (builtin.single_threaded) BrkAllocator else @compileError("unimplemented");
 pub const BrkAllocator = @import("heap/BrkAllocator.zig");
@@ -29,13 +30,6 @@ pub fn MemoryPool(comptime Item: type) type {
 }
 pub const memory_pool = @import("heap/memory_pool.zig");
 
-/// Deprecated; use `memory_pool.Aligned`.
-pub const MemoryPoolAligned = memory_pool.Aligned;
-/// Deprecated; use `memory_pool.Extra`.
-pub const MemoryPoolExtra = memory_pool.Extra;
-/// Deprecated; use `memory_pool.Options`.
-pub const MemoryPoolOptions = memory_pool.Options;
-
 /// comptime-known minimum page size of the target.
 ///
 /// All pointers from `mmap` or `NtAllocateVirtualMemory` are aligned to at least
@@ -367,113 +361,6 @@ pub const brk_allocator: Allocator = .{
     .vtable = &BrkAllocator.vtable,
 };
 
-/// Returns a `StackFallbackAllocator` allocating using either a
-/// `FixedBufferAllocator` on an array of size `size` and falling back to
-/// `fallback_allocator` if that fails.
-pub fn stackFallback(comptime size: usize, fallback_allocator: Allocator) StackFallbackAllocator(size) {
-    return StackFallbackAllocator(size){
-        .buffer = undefined,
-        .fallback_allocator = fallback_allocator,
-        .fixed_buffer_allocator = undefined,
-    };
-}
-
-/// An allocator that attempts to allocate using a
-/// `FixedBufferAllocator` using an array of size `size`. If the
-/// allocation fails, it will fall back to using
-/// `fallback_allocator`. Easily created with `stackFallback`.
-pub fn StackFallbackAllocator(comptime size: usize) type {
-    return struct {
-        const Self = @This();
-
-        buffer: [size]u8,
-        fallback_allocator: Allocator,
-        fixed_buffer_allocator: FixedBufferAllocator,
-        get_called: if (std.debug.runtime_safety) bool else void =
-            if (std.debug.runtime_safety) false else {},
-
-        /// This function both fetches a `Allocator` interface to this
-        /// allocator *and* resets the internal buffer allocator.
-        pub fn get(self: *Self) Allocator {
-            if (std.debug.runtime_safety) {
-                assert(!self.get_called); // `get` called multiple times; instead use `const allocator = stackFallback(N).get();`
-                self.get_called = true;
-            }
-            self.fixed_buffer_allocator = FixedBufferAllocator.init(self.buffer[0..]);
-            return .{
-                .ptr = self,
-                .vtable = &.{
-                    .alloc = alloc,
-                    .resize = resize,
-                    .remap = remap,
-                    .free = free,
-                },
-            };
-        }
-
-        /// Unlike most std allocators `StackFallbackAllocator` modifies
-        /// its internal state before returning an implementation of
-        /// the`Allocator` interface and therefore also doesn't use
-        /// the usual `.allocator()` method.
-        pub const allocator = @compileError("use 'const allocator = stackFallback(N).get();' instead");
-
-        fn alloc(
-            ctx: *anyopaque,
-            len: usize,
-            alignment: Alignment,
-            ra: usize,
-        ) ?[*]u8 {
-            const self: *Self = @ptrCast(@alignCast(ctx));
-            return FixedBufferAllocator.alloc(&self.fixed_buffer_allocator, len, alignment, ra) orelse
-                return self.fallback_allocator.rawAlloc(len, alignment, ra);
-        }
-
-        fn resize(
-            ctx: *anyopaque,
-            buf: []u8,
-            alignment: Alignment,
-            new_len: usize,
-            ra: usize,
-        ) bool {
-            const self: *Self = @ptrCast(@alignCast(ctx));
-            if (self.fixed_buffer_allocator.ownsPtr(buf.ptr)) {
-                return FixedBufferAllocator.resize(&self.fixed_buffer_allocator, buf, alignment, new_len, ra);
-            } else {
-                return self.fallback_allocator.rawResize(buf, alignment, new_len, ra);
-            }
-        }
-
-        fn remap(
-            context: *anyopaque,
-            memory: []u8,
-            alignment: Alignment,
-            new_len: usize,
-            return_address: usize,
-        ) ?[*]u8 {
-            const self: *Self = @ptrCast(@alignCast(context));
-            if (self.fixed_buffer_allocator.ownsPtr(memory.ptr)) {
-                return FixedBufferAllocator.remap(&self.fixed_buffer_allocator, memory, alignment, new_len, return_address);
-            } else {
-                return self.fallback_allocator.rawRemap(memory, alignment, new_len, return_address);
-            }
-        }
-
-        fn free(
-            ctx: *anyopaque,
-            buf: []u8,
-            alignment: Alignment,
-            ra: usize,
-        ) void {
-            const self: *Self = @ptrCast(@alignCast(ctx));
-            if (self.fixed_buffer_allocator.ownsPtr(buf.ptr)) {
-                return FixedBufferAllocator.free(&self.fixed_buffer_allocator, buf, alignment, ra);
-            } else {
-                return self.fallback_allocator.rawFree(buf, alignment, ra);
-            }
-        }
-    };
-}
-
 test c_allocator {
     if (builtin.link_libc) {
         try testAllocator(c_allocator);
@@ -524,25 +411,6 @@ test ArenaAllocator {
     try testAllocatorAlignedShrink(allocator);
 }
 
-test "StackFallbackAllocator" {
-    {
-        var stack_allocator = stackFallback(4096, std.testing.allocator);
-        try testAllocator(stack_allocator.get());
-    }
-    {
-        var stack_allocator = stackFallback(4096, std.testing.allocator);
-        try testAllocatorAligned(stack_allocator.get());
-    }
-    {
-        var stack_allocator = stackFallback(4096, std.testing.allocator);
-        try testAllocatorLargeAlignment(stack_allocator.get());
-    }
-    {
-        var stack_allocator = stackFallback(4096, std.testing.allocator);
-        try testAllocatorAlignedShrink(stack_allocator.get());
-    }
-}
-
 /// This one should not try alignments that exceed what C malloc can handle.
 pub fn testAllocator(base_allocator: mem.Allocator) !void {
     var validationAllocator = mem.validationWrap(base_allocator);
@@ -1011,6 +879,7 @@ test {
     _ = ArenaAllocator;
     _ = DebugAllocator(.{});
     _ = FixedBufferAllocator;
+    _ = BufferFirstAllocator;
     if (builtin.single_threaded) {
         if (builtin.cpu.arch.isWasm() or (builtin.os.tag == .linux and !builtin.link_libc)) {
             _ = brk_allocator;