turbolinks 0.1.0

data/README.md

@@ -0,0 +1,40 @@
+Turbolinks
+===========
+
+Turbolinks makes following links in your web application faster. Instead of letting the browser reload the JavaScript and CSS between each page change, and spend extra HTTP requests checking if the assets are up-to-date, we keep the current instance alive and replace only the body and the title in the head.
+
+This is similar to pjax, but instead of worrying about what element on the page to replace, and tailoring the server-side response to fit, we replace the entire body. This means that you get the bulk of the speed benefits from pjax (no recompiling of the JavaScript or CSS) without having to tailor the server-side response. It just works.
+
+By default, all internal links will be funneled through Turbolinks, but you can opt out by marking links with data-no-turbolink.
+
+
+No jQuery or any other framework
+--------------------------------
+
+Turbolinks is designed to be as light-weight as possible (so you won't think twice about using it even for mobile stuff). It does not require jQuery or any other framework to work. But it works great _with_ jQuery or Prototype or whatever else have you.
+
+
+The page:update event
+---------------------
+
+Since pages will change without a full reload with Turbolinks, you can't by default rely on dom:loaded to trigger your JavaScript code. Instead, Turbolinks uses the page:update event.
+
+
+Triggering a Turbolinks visit manually
+---------------------------------------
+
+You can use `Turbolinks.visit(path)` to go to a URL through Turbolinks.
+
+
+Available only for pushState browsers
+-------------------------------------
+
+Like pjax, this naturally only works with browsers capable of pushState. But of course we fall back gracefully to full page reloads for browsers that do not support it.
+
+
+Work left to do
+---------------
+
+* CSS/JS asset change detection and reload
+* Add a DOM cache for faster back button
+* Remember scroll position when using back button 

data/lib/assets/javascripts/turbolinks.js.coffee

@@ -0,0 +1,82 @@
+visit = (url) ->
+  if browserSupportsPushState
+    reflectNewUrl url
+    fetchReplacement url
+  else
+    document.location.href = url
+
+
+fetchReplacement = (url) ->
+  xhr = new XMLHttpRequest
+  xhr.open 'GET', url, true
+  xhr.onload = -> fullReplacement xhr.responseText, url
+  xhr.send()
+
+fullReplacement = (html, url) ->
+  replaceHTML html
+  triggerPageChange()
+
+reflectNewUrl = (url) ->
+  window.history.pushState { turbolinks: true }, "", url
+
+triggerPageChange = ->
+  event = document.createEvent 'Events'
+  event.initEvent 'page:change', true, true
+  document.dispatchEvent event
+
+replaceHTML = (html) ->
+  doc = document.implementation.createHTMLDocument ""
+  doc.open "replace"
+  doc.write html
+  doc.close()
+
+  originalBody = document.body
+  document.documentElement.appendChild doc.body, originalBody
+  document.documentElement.removeChild originalBody
+  document.title = title.textContent if title = doc.querySelector "title"
+
+
+extractLink = (event) ->
+  link = event.target
+  until link is this or link.nodeName is 'A'
+    link = link.parentNode
+  link
+
+crossOriginLink = (link) ->
+  location.protocol isnt link.protocol || location.host isnt link.host
+
+anchoredLink = (link) ->
+  ((link.hash && link.href.replace(link.hash, '')) is location.href.replace(location.hash, '')) ||
+    (link.href is location.href + '#')
+
+noTurbolink = (link) ->
+  link.getAttribute('data-no-turbolink')?
+
+newTabClick = (event) ->
+  event.which > 1 || event.metaKey || event.ctrlKey
+
+ignoreClick = (event, link) ->
+  crossOriginLink(link) || anchoredLink(link) || noTurbolink(link) || newTabClick(event)
+
+handleClick = (event) ->
+  link = extractLink event
+
+  if link.nodeName is 'A' and !ignoreClick(event, link)
+    visit link.href
+    event.preventDefault()
+
+
+browserSupportsPushState =
+  window.history && window.history.pushState && window.history.replaceState
+
+
+if browserSupportsPushState
+  window.addEventListener 'popstate', (event) ->
+    if event.state?.turbolinks
+      fetchReplacement document.location.href
+
+  document.addEventListener 'click', (event) ->
+    handleClick event
+
+# Call Turbolinks.visit(url) from client code
+@Turbolinks = { visit: visit }

metadata

@@ -0,0 +1,47 @@
+--- !ruby/object:Gem::Specification
+name: turbolinks
+version: !ruby/object:Gem::Version
+  version: 0.1.0
+  prerelease: 
+platform: ruby
+authors:
+- David Heinemeier Hansson
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2012-09-26 00:00:00.000000000 Z
+dependencies: []
+description: 
+email: david@loudthinking.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- lib/assets/javascripts/turbolinks.js.coffee
+- README.md
+homepage: 
+licenses: []
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  none: false
+  requirements:
+  - - ! '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  none: false
+  requirements:
+  - - ! '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 1.8.7
+signing_key: 
+specification_version: 3
+summary: Turbolinks makes following links in your web application faster (use with
+  Rails Asset Pipeline)
+test_files: []