neovim 0.5.0 → 0.5.1

checksums.yaml

@@ -1,7 +1,7 @@
 ---
 SHA1:
-  metadata.gz: '056393636b2bb2d1a11454e495378d30b5b886de'
-  data.tar.gz: 32202a000db324574ec4b55bdff4ddb0eb1bc4ef
+  metadata.gz: 64c75505d6b6148e56df55a0f63f20dcc33ff329
+  data.tar.gz: 23581eb000bf8165fcbccc01b1ef004c86f57aac
 SHA512:
-  metadata.gz: a7379f601e28d71f02f89c8687a38a9516e75def94af5a7c867c764f0538a6b4131adcbe503a80e90e48804e8802e0677f013337d597aaff25c87df2eb7fd7a0
-  data.tar.gz: a245f880c4c873421f2d41839ff0ea63e923dd25120bb112838881cd33b9bf4ba649dcc96206a836a83c821acd14d56a6125b8d752bdede2f9986a390e40906c
+  metadata.gz: ea759f8fe2edd4b37c2646245deffb627466633f7424e7ce0ff563e32c141d113cd4b7a2094c82cd62fbeb5238cd9bf512521ccbe3ba376996f45021f9451d10
+  data.tar.gz: '08498a8f0928796988e6e4abe2c3e27fc1c70b8c59786898649e2acbdfd9f9f8e333dae0438b15b04fd3a51189ae421570bc91de7eb6bbe8230faaef4f7b9ae7'

data/.travis.yml

@@ -1,16 +1,17 @@
 language: ruby
 sudo: false
+dist: trusty
 
 branches:
   only: master
 
 rvm:
-  - 1.9.3
-  - 2.0.0
-  - 2.1.0
-  - 2.2.0
-  - 2.3.0
-  - 2.4.0
+  - 1.9
+  - 2.0
+  - 2.1
+  - 2.2
+  - 2.3
+  - 2.4
   - ruby-head
 
 before_install:

data/CHANGELOG.md

@@ -1,3 +1,7 @@
+# 0.5.1
+- Convert vader.vim from submodule to subtree so it is included in gem
+  installations
+
 # 0.5.0
 - Breaking API changes:
   - Update generated methods to map to `nvim_` RPC functions, rather than the

data/Rakefile

@@ -11,11 +11,6 @@ task :api do
   sh File.expand_path("../script/dump_api", __FILE__)
 end
 
-desc "Initialize and update git submodules"
-task :submodules do
-  sh "git submodule update --init"
-end
-
 namespace :spec do
   desc "Run functional specs"
   RSpec::Core::RakeTask.new(:functional) do |t|
@@ -23,10 +18,10 @@ namespace :spec do
   end
 
   desc "Run integration specs"
-  RSpec::Core::RakeTask.new(:integration => :submodules) do |t|
+  RSpec::Core::RakeTask.new(:integration) do |t|
     t.pattern = "spec/integration_spec.rb"
   end
 end
 
-RSpec::Core::RakeTask.new(:spec => :submodules)
+RSpec::Core::RakeTask.new(:spec)
 task :default => :spec

data/lib/neovim/version.rb

@@ -1,3 +1,3 @@
 module Neovim
-  VERSION = Gem::Version.new("0.5.0")
+  VERSION = Gem::Version.new("0.5.1")
 end

data/spec/integration/runtime/vader.vim/autoload/vader.vim

@@ -0,0 +1,348 @@
+" Copyright (c) 2015 Junegunn Choi
+"
+" MIT License
+"
+" Permission is hereby granted, free of charge, to any person obtaining
+" a copy of this software and associated documentation files (the
+" "Software"), to deal in the Software without restriction, including
+" without limitation the rights to use, copy, modify, merge, publish,
+" distribute, sublicense, and/or sell copies of the Software, and to
+" permit persons to whom the Software is furnished to do so, subject to
+" the following conditions:
+"
+" The above copyright notice and this permission notice shall be
+" included in all copies or substantial portions of the Software.
+"
+" THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+" NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+" LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+" OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+" WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+
+let s:register = {}
+let s:register_undefined = []
+let s:indent = 2
+
+function! vader#run(bang, ...) range
+  let s:error_line = 0
+
+  if a:lastline - a:firstline > 0
+    if a:0 > 1
+      echoerr "You can't apply range on multiple files"
+      return
+    endif
+    let [line1, line2] = [a:firstline, a:lastline]
+  else
+    let [line1, line2] = [1, 0]
+  endif
+
+  let options = { 'exitfirst': index(a:000, '-x') >= 0 }
+  let patterns = filter(copy(a:000), "v:val !=# '-x'")
+  if empty(patterns)
+    let patterns = [expand('%')]
+  endif
+
+  call vader#assert#reset()
+  call s:prepare()
+  try
+    let all_cases = []
+    let qfl = []
+    let st  = reltime()
+    let [success, pending, total] = [0, 0, 0]
+
+    for gl in patterns
+      if filereadable(gl)
+        let files = [gl]
+      else
+        let files = filter(split(glob(gl), "\n"),
+              \ "fnamemodify(v:val, ':e') ==# 'vader'")
+      endif
+      for fn in files
+        let afn = fnamemodify(fn, ':p')
+        let cases = vader#parser#parse(afn, line1, line2)
+        call add(all_cases, [afn, cases])
+        let total += len(cases)
+      endfor
+    endfor
+    if empty(all_cases)
+      throw 'Vader: no tests found for patterns ('.join(patterns).')'
+    endif
+
+    call vader#window#open()
+    call vader#window#append(
+    \ printf("Starting Vader: %d suite(s), %d case(s)", len(all_cases), total), 0)
+
+    for pair in all_cases
+      let [fn, case] = pair
+      let [cs, cp, ct, lqfl] = s:run(fn, case, options)
+      let success += cs
+      let pending += cp
+      call extend(qfl, lqfl)
+      call vader#window#append(
+            \ printf('Success/Total: %s/%s%s',
+            \     cs, ct, cp > 0 ? (' ('.cp.' pending)') : ''),
+            \ 1)
+    endfor
+
+    let stats = vader#assert#stat()
+    call vader#window#append(printf('Success/Total: %s/%s (%sassertions: %d/%d)',
+          \ success, total, (pending > 0 ? pending . ' pending, ' : ''),
+          \ stats[0], stats[1]), 0)
+    call vader#window#append('Elapsed time: '.
+          \ substitute(reltimestr(reltime(st)), '^\s*', '', '') .' sec.', 0)
+    call vader#window#cleanup()
+
+    let g:vader_report = join(getline(1, '$'), "\n")
+    let g:vader_errors = qfl
+    call setqflist(qfl)
+
+    if a:bang
+      redir => ver
+      silent version
+      redir END
+
+      call s:print_stderr(ver . "\n\n" . g:vader_report)
+      if success + pending == total
+        qall!
+      else
+        cq
+      endif
+    elseif !empty(qfl)
+      call vader#window#copen()
+    endif
+  catch
+    let error = 'Vader error: '.v:exception.' (in '.v:throwpoint.')'
+    if a:bang
+      call s:print_stderr(error)
+      cq
+    else
+      echoerr error
+    endif
+  finally
+    call s:cleanup()
+  endtry
+endfunction
+
+function! s:print_stderr(output)
+  let lines = split(a:output, '\n')
+  if filewritable($VADER_OUTPUT_FILE)
+    call writefile(lines, $VADER_OUTPUT_FILE, 'a')
+  else
+    let tmp = tempname()
+    call writefile(lines, tmp)
+    execute 'silent !cat '.tmp.' 1>&2'
+    call delete(tmp)
+  endif
+endfunction
+
+function! s:split_args(arg)
+  let varnames = split(a:arg, ',')
+  let names = []
+  for varname in varnames
+    let name = substitute(varname, '^\s*\(.*\)\s*$', '\1', '')
+    let name = substitute(name, '^''\(.*\)''$', '\1', '')
+    let name = substitute(name, '^"\(.*\)"$',  '\1', '')
+    call add(names, name)
+  endfor
+  return names
+endfunction
+
+function! vader#log(msg)
+  let msg = type(a:msg) == 1 ? a:msg : string(a:msg)
+  call vader#window#append('> ' . msg, s:indent)
+endfunction
+
+function! vader#save(args)
+  for varname in s:split_args(a:args)
+    if exists(varname)
+      let s:register[varname] = eval(varname)
+    else
+      let s:register_undefined += [varname]
+    endif
+  endfor
+endfunction
+
+function! vader#restore(args)
+  let varnames = s:split_args(a:args)
+  for varname in empty(varnames) ? keys(s:register) : varnames
+    if has_key(s:register, varname)
+      execute printf("let %s = s:register['%s']", varname, varname)
+    endif
+  endfor
+  let undefined = empty(varnames) ? s:register_undefined
+        \ : filter(copy(varnames), 'index(s:register_undefined, v:val) != -1')
+  for varname in undefined
+    if varname[0] ==# '$'
+      execute printf('let %s = ""', varname)
+    else
+      execute printf('unlet! %s', varname)
+    endif
+  endfor
+endfunction
+
+function! s:prepare()
+  command! -nargs=+ Log            :call vader#log(<args>)
+  command! -nargs=+ Save           :call vader#save(<q-args>)
+  command! -nargs=* Restore        :call vader#restore(<q-args>)
+  command! -nargs=+ Assert         :call vader#assert#true(<args>)
+  command! -nargs=+ AssertEqual    :call vader#assert#equal(<args>)
+  command! -nargs=+ AssertNotEqual :call vader#assert#not_equal(<args>)
+  command! -nargs=+ AssertThrows   :call vader#assert#throws(<q-args>)
+  let g:SyntaxAt = function('vader#helper#syntax_at')
+  let g:SyntaxOf = function('vader#helper#syntax_of')
+endfunction
+
+function! s:cleanup()
+  let s:register = {}
+  let s:register_undefined = []
+  delcommand Log
+  delcommand Save
+  delcommand Restore
+  delcommand Assert
+  delcommand AssertEqual
+  delcommand AssertNotEqual
+  delcommand AssertThrows
+  unlet g:SyntaxAt
+  unlet g:SyntaxOf
+endfunction
+
+function! s:comment(case, label)
+  return get(a:case.comment, a:label, '')
+endfunction
+
+function! s:execute(prefix, type, block, lang_if)
+  try
+    call vader#window#execute(a:block, a:lang_if)
+    return 1
+  catch
+    call s:append(a:prefix, a:type, v:exception, 1)
+    call s:print_throwpoint()
+    return 0
+  endtry
+endfunction
+
+function! s:print_throwpoint()
+  if v:throwpoint !~ 'vader#assert'
+    Log v:throwpoint
+  endif
+endfunction
+
+function! s:run(filename, cases, options)
+  let given = []
+  let before = []
+  let after = []
+  let then = []
+  let comment = { 'given': '', 'before': '', 'after': '' }
+  let total = len(a:cases)
+  let just  = len(string(total))
+  let cnt = 0
+  let pending = 0
+  let success = 0
+  let exitfirst = get(a:options, 'exitfirst', 0)
+  let qfl = []
+  let g:vader_file = a:filename
+
+  call vader#window#append("Starting Vader: ". a:filename, 1)
+
+  for case in a:cases
+    let cnt += 1
+    let ok = 1
+    let prefix = printf('(%'.just.'d/%'.just.'d)', cnt, total)
+
+    for label in ['given', 'before', 'after', 'then']
+      if has_key(case, label)
+        execute 'let '.label.' = case[label]'
+        let comment[label] = get(case.comment, label, '')
+      endif
+    endfor
+
+    if !empty(given)
+      call s:append(prefix, 'given', comment.given)
+    endif
+    call vader#window#prepare(given, get(case, 'type', ''))
+
+    if !empty(before)
+      let s:indent = 2
+      let ok = ok && s:execute(prefix, 'before', before, '')
+    endif
+
+    let s:indent = 3
+    if has_key(case, 'execute')
+      call s:append(prefix, 'execute', s:comment(case, 'execute'))
+      let ok = ok && s:execute(prefix, 'execute', case.execute, get(case, 'lang_if', ''))
+    elseif has_key(case, 'do')
+      call s:append(prefix, 'do', s:comment(case, 'do'))
+      try
+        call vader#window#replay(case.do)
+      catch
+        call s:append(prefix, 'do', v:exception, 1)
+        call s:print_throwpoint()
+        let ok = 0
+      endtry
+    endif
+
+    if has_key(case, 'then')
+      call s:append(prefix, 'then', s:comment(case, 'then'))
+      let ok = ok && s:execute(prefix, 'then', then, '')
+    endif
+
+    if has_key(case, 'expect')
+      let result = vader#window#result()
+      let match = case.expect ==# result
+      if match
+        call s:append(prefix, 'expect', s:comment(case, 'expect'))
+      else
+        let begin = s:append(prefix, 'expect', s:comment(case, 'expect'), 1)
+        let ok = 0
+        let data = { 'type': get(case, 'type', ''), 'got': result, 'expect': case.expect }
+        call vader#window#append('- Expected:', 3)
+        for line in case.expect
+          call vader#window#append(line, 5, 0)
+        endfor
+        let end = vader#window#append('- Got:', 3)
+        for line in result
+          let end = vader#window#append(line, 5, 0)
+        endfor
+        call vader#window#set_data(begin, end, data)
+      endif
+    endif
+
+    if !empty(after)
+      let s:indent = 2
+      let ok = s:execute(prefix, 'after', after, '') && ok
+    endif
+
+    if ok
+      let success += 1
+    else
+      let pending += case.pending
+      let description = join(filter([
+            \ comment.given,
+            \ get(case.comment, 'do', get(case.comment, 'execute', '')),
+            \ get(case.comment, 'then', ''),
+            \ get(case.comment, 'expect', '')], '!empty(v:val)'), ' / ') .
+            \ ' (#'.s:error_line.')'
+      call add(qfl, { 'type': 'E', 'filename': a:filename, 'lnum': case.lnum, 'text': description })
+      if exitfirst && !case.pending
+        call vader#window#append('Stopping after first failure.', 2)
+        break
+      endif
+    endif
+  endfor
+
+  unlet g:vader_file
+  return [success, pending, total, qfl]
+endfunction
+
+function! s:append(prefix, type, message, ...)
+  let error = get(a:, 1, 0)
+  let message = (error ? '(X) ' : '') . a:message
+  let line = vader#window#append(printf("%s [%7s] %s", a:prefix, toupper(a:type), message), 2)
+  if error
+    let s:error_line = line
+  endif
+  return line
+endfunction
+

data/spec/integration/runtime/vader.vim/autoload/vader/assert.vim

@@ -0,0 +1,116 @@
+" Copyright (c) 2013 Junegunn Choi
+"
+" MIT License
+"
+" Permission is hereby granted, free of charge, to any person obtaining
+" a copy of this software and associated documentation files (the
+" "Software"), to deal in the Software without restriction, including
+" without limitation the rights to use, copy, modify, merge, publish,
+" distribute, sublicense, and/or sell copies of the Software, and to
+" permit persons to whom the Software is furnished to do so, subject to
+" the following conditions:
+"
+" The above copyright notice and this permission notice shall be
+" included in all copies or substantial portions of the Software.
+"
+" THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+" NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+" LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+" OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+" WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+
+
+let s:assertions = [0, 0]
+
+let s:type_names = {
+      \ 0: 'Number',
+      \ 1: 'String',
+      \ 2: 'Funcref',
+      \ 3: 'List',
+      \ 4: 'Dictionary',
+      \ 5: 'Float',
+      \ 6: 'Boolean',
+      \ 7: 'Null' }
+
+function! vader#assert#reset()
+  let s:assertions = [0, 0]
+endfunction
+
+function! vader#assert#stat()
+  return s:assertions
+endfunction
+
+function! vader#assert#true(...)
+  let s:assertions[1] += 1
+
+  if a:0 == 1
+    let [expr, message] = [a:1, "Assertion failure"]
+  elseif a:0 == 2
+    let [expr, message] = a:000
+  else
+    throw 'Invalid number of arguments'
+  endif
+
+  if !expr
+    throw message
+  endif
+  let s:assertions[0] += 1
+  return 1
+endfunction
+
+function! s:check_types(...)
+  let [Exp, Got] = a:000[0:1]
+  if type(Exp) !=# type(Got)
+    throw get(a:000, 2, printf("type mismatch: %s (%s) should be equal to %s (%s)",
+          \ string(Got), get(s:type_names, type(Got), type(Got)),
+          \ string(Exp), get(s:type_names, type(Exp), type(Exp))))
+  endif
+endfunction
+
+function! vader#assert#equal(...)
+  let [Exp, Got] = a:000[0:1]
+  let s:assertions[1] += 1
+
+  call s:check_types(Exp, Got)
+  if Exp !=# Got
+    let type = type(Exp)
+    let msg = (type == type({}) || type == type([]))
+          \ ? printf("Unequal %ss\n      %%s should be equal to \n      %%s", get(s:type_names, type))
+          \ : "%s should be equal to %s"
+    throw get(a:000, 2, printf(msg, string(Got), string(Exp)))
+  endif
+  let s:assertions[0] += 1
+  return 1
+endfunction
+
+function! vader#assert#not_equal(...)
+  let [Exp, Got] = a:000[0:1]
+  let s:assertions[1] += 1
+
+  call s:check_types(Exp, Got)
+  if Exp ==# Got
+    throw get(a:000, 2, printf("%s should not be equal to %s", string(Got), string(Exp)))
+  endif
+  let s:assertions[0] += 1
+  return 1
+endfunction
+
+function! vader#assert#throws(exp)
+  let s:assertions[1] += 1
+
+  let ok = 0
+  try
+    execute a:exp
+  catch
+    let g:vader_exception = v:exception
+    let g:vader_throwpoint = v:throwpoint
+    let ok = 1
+  endtry
+
+  let s:assertions[0] += ok
+  if ok | return 1
+  else  | throw 'Exception expected but not raised: '.a:exp
+  endif
+endfunction

data/spec/integration/runtime/vader.vim/autoload/vader/helper.vim

@@ -0,0 +1,43 @@
+function! vader#helper#syntax_at(...)
+  if a:0 < 2
+    let l:pos = getpos('.')
+    let l:cur_lnum = pos[1]
+    let l:cur_col = pos[2]
+    if a:0 == 0
+      let l:lnum = l:cur_lnum
+      let l:col = l:cur_col
+    else
+      let l:lnum = l:cur_lnum
+      let l:col = a:1
+    endif
+  else
+    let l:lnum = a:1
+    let l:col = a:2
+  endif
+  return synIDattr(synID(l:lnum, l:col, 1), 'name')
+endfunction
+
+function! vader#helper#syntax_of(pattern, ...)
+  if a:0 < 1
+    let l:nth = 1
+  else
+    let l:nth = a:1
+  endif
+
+  let l:pos_init = getpos('.')
+  call cursor(1, 1)
+  let found = search(a:pattern, 'cW')
+  while found != 0 && nth > 1
+    let found = search(a:pattern, 'W')
+    let nth -= 1
+  endwhile
+
+  if found
+    let l:pos = getpos('.')
+    let l:output = vader#helper#syntax_at(l:pos[1], l:pos[2])
+  else
+    let l:output = ''
+  endif
+  call setpos('.', l:pos_init)
+  return l:output
+endfunction

data/spec/integration/runtime/vader.vim/autoload/vader/parser.vim

@@ -0,0 +1,179 @@
+" Copyright (c) 2013 Junegunn Choi
+"
+" MIT License
+"
+" Permission is hereby granted, free of charge, to any person obtaining
+" a copy of this software and associated documentation files (the
+" "Software"), to deal in the Software without restriction, including
+" without limitation the rights to use, copy, modify, merge, publish,
+" distribute, sublicense, and/or sell copies of the Software, and to
+" permit persons to whom the Software is furnished to do so, subject to
+" the following conditions:
+"
+" The above copyright notice and this permission notice shall be
+" included in all copies or substantial portions of the Software.
+"
+" THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+" NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+" LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+" OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+" WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+
+function! vader#parser#parse(fn, line1, line2)
+  return s:parse_vader(s:read_vader(a:fn, a:line1, a:line2), a:line1)
+endfunction
+
+function! s:flush_buffer(cases, case, fn, lnum, raw, label, newlabel, buffer, final)
+  let is_validation = index(['then', 'expect'], a:newlabel) >= 0
+  let fpos = a:fn.':'.a:lnum
+
+  if empty(a:label)
+    if is_validation
+      echoerr 'Expect/Then should not appear before Do/Execute ('.fpos.')'
+    endif
+  else
+    let rev = reverse(copy(a:buffer))
+    while len(rev) > 0 && empty(rev[0])
+      call remove(rev, 0)
+    endwhile
+
+    let data = map(reverse(rev), (a:case.raw ? 'v:val' : 'strpart(v:val, 2)'))
+    let a:case[a:label] = data
+    if !empty(a:buffer)
+      call remove(a:buffer, 0, -1)
+    endif
+
+    let fulfilled = has_key(a:case, 'do') || has_key(a:case, 'execute')
+    if is_validation
+      if !fulfilled
+        echoerr 'Expect/Then should not appear before Do/Execute ('.fpos.')'
+      endif
+      if has_key(a:case, a:newlabel)
+        echoerr 'Expect/Then should appear only once for each Do/Execute ('.fpos.')'
+      endif
+    endif
+
+    if a:final ||
+     \ a:newlabel == 'given' ||
+     \ index(['before', 'after', 'do', 'execute'], a:newlabel) >= 0 && fulfilled
+      call add(a:cases, deepcopy(a:case))
+      let new = { 'comment': {}, 'lnum': a:lnum, 'pending': 0 }
+      if !empty(get(a:case, 'type', ''))
+        let new.type = a:case.type " To reuse Given block with type
+      endif
+      call extend(filter(a:case, '0'), new)
+    endif
+  endif
+  let a:case.raw = a:raw
+endfunction
+
+function! s:read_vader(fn, line1, line2)
+  let remains   = readfile(a:fn)[a:line1 - 1 : a:line2 - 1]
+  let lnum      = a:line1
+  let lines     = []
+  let reserved  = 0
+  let depth     = 0 " Not a strict depth
+  let max_depth = 10
+
+  while len(remains) > 0
+    let line = remove(remains, 0)
+    let m = matchlist(line, '^Include\(\s*(.*)\s*\)\?:\s*\(.\{-}\)\s*$')
+    if !empty(m)
+      let file = findfile(m[2], fnamemodify(a:fn, ':h'))
+      if empty(file)
+        echoerr "Cannot find ".m[2]
+      endif
+      if reserved > 0
+        let depth += 1
+        if depth >= max_depth
+          echoerr 'Recursive inclusion limit exceeded'
+        endif
+        let reserved -= 1
+      endif
+      let included = readfile(file)
+      let reserved += len(included)
+      call extend(remains, included, 0)
+      continue
+    end
+
+    call add(lines, [a:fn, lnum, line])
+    if reserved > 0
+      let reserved -= 1
+    end
+    if reserved == 0
+      let depth = 0
+      let lnum += 1
+    endif
+  endwhile
+
+  return lines
+endfunction
+
+function! s:parse_vader(lines, line1)
+  let label    = ''
+  let newlabel = ''
+  let buffer   = []
+  let cases    = []
+  let case     = { 'lnum': a:line1, 'comment': {}, 'pending': 0, 'raw': 0 }
+
+  for [fn, lnum, line] in a:lines
+    " Comment / separators
+    if !case.raw && line =~ '^[#"=~*^-]'
+      continue
+    endif
+
+    let matched = 0
+    for l in ['Before', 'After', 'Given', 'Execute', 'Expect', 'Do', 'Then']
+      let m = matchlist(line, '^'.l.'\%(\s\+\([^:;(]\+\)\)\?\s*\%((\(.*\))\)\?\s*\([:;]\)\s*$')
+      if !empty(m)
+        let newlabel = tolower(l)
+        call s:flush_buffer(cases, case, fn, lnum, m[3] == ';', label, newlabel, buffer, 0)
+
+        let label   = newlabel
+        let arg     = m[1]
+        let comment = m[2]
+        if !empty(arg)
+          if     l == 'Given'   | let case.type    = arg
+          elseif l == 'Execute' | let case.lang_if = arg
+          end
+        elseif l == 'Given'
+          let case.type = ''
+        endif
+        if !empty(comment)
+          let case.comment[tolower(l)] = comment
+          if index(['do', 'execute'], label) >= 0 &&
+                \ comment =~# '\<TODO\>\|\<FIXME\>'
+            let case.pending = 1
+          endif
+        endif
+        let matched = 1
+        break
+      endif
+    endfor
+    if matched | continue | endif
+
+    " Continuation
+    if !empty(line) && !case.raw && line !~ '^  '
+      throw 'Syntax error (line does not start with two spaces): ' . line
+    endif
+    if !empty(label)
+      call add(buffer, line)
+    endif
+  endfor
+  call s:flush_buffer(cases, case, fn, lnum, case.raw, label, '', buffer, 1)
+
+  let ret = []
+  let prev = {}
+  for case in cases
+    if has_key(case, "do") || has_key(case, "execute")
+      call add(ret, extend(prev, case))
+      let prev = {}
+    else
+      let prev = case
+    endif
+  endfor
+  return ret
+endfunction
+

data/spec/integration/runtime/vader.vim/autoload/vader/syntax.vim

@@ -0,0 +1,73 @@
+" Copyright (c) 2014 Junegunn Choi
+"
+" MIT License
+"
+" Permission is hereby granted, free of charge, to any person obtaining
+" a copy of this software and associated documentation files (the
+" "Software"), to deal in the Software without restriction, including
+" without limitation the rights to use, copy, modify, merge, publish,
+" distribute, sublicense, and/or sell copies of the Software, and to
+" permit persons to whom the Software is furnished to do so, subject to
+" the following conditions:
+"
+" The above copyright notice and this permission notice shall be
+" included in all copies or substantial portions of the Software.
+"
+" THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+" NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+" LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+" OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+" WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+
+let s:ifs = ['lua', 'perl', 'ruby', 'python']
+
+function! vader#syntax#reset()
+  let b:vader_types = {}
+endfunction
+
+function! vader#syntax#include(l1, l2)
+  let lines = filter(getline(a:l1, a:l2), '!empty(v:val) && v:val[0] != " "')
+  for line in lines
+    let match = matchlist(line, '^\(Given\|Expect\|Execute\)\s\+\([^:; (]\+\)')
+    if len(match) >= 3
+      silent! call s:load(match[2])
+    endif
+  endfor
+endfunction
+
+function! vader#syntax#_head()
+  return '\(\(^\(Given\|Expect\|Do\|Execute\|Then\|Before\|After\)\(\s\+[^:;(]\+\)\?\s*\((.*)\)\?\s*[:;]\s*$\)\|\(^Include\(\s*(.*)\)\?\s*:\)\)\@='
+endfunction
+
+function! s:load(type)
+  let b:vader_types = get(b:, 'vader_types', {})
+  if has_key(b:vader_types, a:type)
+    return
+  endif
+
+  if empty(globpath(&rtp, "syntax/".a:type.".vim", 1))
+    return
+  endif
+
+  let b:vader_types[a:type] = 1
+
+  unlet! b:current_syntax
+  execute printf('syn include @%sSnippet syntax/%s.vim', a:type, a:type)
+  execute printf('syn region vader_%s start=/^\s\{2,}/ end=/^\S\@=/ contains=@%sSnippet contained', a:type, a:type)
+  execute printf('syn region vader_raw_%s start=/\(;\s*$\)\@<=/ end=/%s/ contains=@%sSnippet contained', a:type, vader#syntax#_head(), a:type)
+
+  call s:define_syntax_region('Given', a:type)
+  call s:define_syntax_region('Expect', a:type)
+  if index(s:ifs, a:type) >= 0
+    call s:define_syntax_region('Execute', a:type)
+  endif
+  let b:current_syntax = 'vader'
+endfunction
+
+function! s:define_syntax_region(block, lang)
+  execute printf('syn region vader%s start=/^%s\s\+%s\s*\((.*)\)\?\s*:\s*$/ end=/\(^[^ ^#~=*-]\)\@=/ contains=vader%sType,vaderMessage,@vaderIgnored,vader_%s nextgroup=@vaderTopLevel skipempty keepend', a:block, a:block, a:lang, a:block, a:lang)
+  execute printf('syn region vader%sRaw start=/^%s\s\+%s\s*\((.*)\)\?\s*;\s*$/ end=/%s/ contains=vader%sType,vaderMessage,@vaderIgnored,vader_raw_%s nextgroup=@vaderTopLevel skipempty keepend', a:block, a:block, a:lang, vader#syntax#_head(), a:block, a:lang)
+endfunction
+

data/spec/integration/runtime/vader.vim/autoload/vader/window.vim

@@ -0,0 +1,205 @@
+" Copyright (c) 2013 Junegunn Choi
+"
+" MIT License
+"
+" Permission is hereby granted, free of charge, to any person obtaining
+" a copy of this software and associated documentation files (the
+" "Software"), to deal in the Software without restriction, including
+" without limitation the rights to use, copy, modify, merge, publish,
+" distribute, sublicense, and/or sell copies of the Software, and to
+" permit persons to whom the Software is furnished to do so, subject to
+" the following conditions:
+"
+" The above copyright notice and this permission notice shall be
+" included in all copies or substantial portions of the Software.
+"
+" THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+" NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+" LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+" OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+" WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+
+let s:quickfix_bfr  = 0
+let s:console_bfr   = 0
+let s:console_tab   = 0
+let s:workbench_tab = 0
+let s:workbench_bfr = 0
+
+function! s:switch_to_console()
+  execute 'normal! '.s:console_tab.'gt'
+  call append(line('$') - 1, s:console_buffered)
+  let s:console_buffered = []
+endfunction
+
+function! s:switch_to_workbench()
+  execute 'normal! '.s:workbench_tab.'gt'
+  execute 'b!' s:workbench_bfr
+endfunction
+
+function! vader#window#open()
+  execute 'silent! bd' s:console_bfr
+  execute 'silent! bd' s:workbench_bfr
+  if bufexists(s:quickfix_bfr)
+    execute "silent! bd ".s:quickfix_bfr
+  endif
+
+  let s:prev_winid = exists('*win_getid') ? win_getid() : 0
+  tabnew
+  setlocal buftype=nofile noswapfile nospell
+  setf vader-result
+  silent f \[Vader\]
+  let s:console_tab = tabpagenr()
+  let s:console_bfr = bufnr('')
+  let s:console_buffered = []
+  let b:vader_data = {}
+  nnoremap <silent> <buffer> <CR> :call <SID>action(line('.'))<CR>
+
+  tabnew
+  setlocal buftype=nofile
+  setlocal noswapfile
+  silent f \[Vader-workbench\]
+  let s:workbench_tab = tabpagenr()
+  let s:workbench_bfr = bufnr('')
+endfunction
+
+function! vader#window#execute(lines, lang_if)
+  let temp = tempname()
+  try
+    if empty(a:lang_if)
+      let lines = a:lines
+    else
+      let lines = copy(a:lines)
+      call insert(lines, a:lang_if . ' << __VADER__LANG__IF__')
+      call add(lines, '__VADER__LANG__IF__')
+    endif
+    call writefile(lines, temp)
+    execute 'source '.temp
+  finally
+    call delete(temp)
+  endtry
+endfunction
+
+function! vader#window#replay(lines)
+  call setreg('x', substitute(join(a:lines, ''), '\\<[^>]\+>', '\=eval("\"".submatch(0)."\"")', 'g'), 'c')
+  normal! @x
+endfunction
+
+function! vader#window#result()
+  return getline(1, line('$'))
+endfunction
+
+function! vader#window#append(message, indent, ...)
+  let message = repeat('  ', a:indent) . a:message
+  if get(a:, 1, 1)
+    let message = substitute(message, '\s*$', '', '')
+  endif
+  if !exists('s:console_buffered')
+    echom 'Vader:' message
+    return 0
+  endif
+  call add(s:console_buffered, message)
+  return len(s:console_buffered)
+endfunction
+
+function! vader#window#prepare(lines, type)
+  call s:switch_to_workbench()
+  execute 'setlocal modifiable filetype='.a:type
+
+  silent %d _
+  for line in a:lines
+    call append(line('$') - 1, line)
+  endfor
+  silent d _
+  execute "normal! \<c-\>\<c-n>gg0"
+
+  let &undolevels = &undolevels " Break undo block
+endfunction
+
+function! vader#window#cleanup()
+  execute 'silent! bd' s:workbench_bfr
+  call s:switch_to_console()
+  setlocal nomodifiable
+  nnoremap <silent> <buffer> q :call <SID>quit()<CR><CR>
+  normal! Gzb
+endfunction
+
+function! vader#window#copen()
+  copen
+  let s:quickfix_bfr = bufnr('')
+  1wincmd w
+  normal! Gzb
+  2wincmd w
+  nnoremap <silent> <buffer> q :call <SID>quit()<CR><CR>
+  nnoremap <silent> <buffer> <CR> :call <SID>move()<CR><CR>
+endfunction
+
+function! vader#window#set_data(l1, l2, data)
+  try
+    let var = getbufvar(s:console_bfr, 'vader_data', {})
+    for l in range(a:l1, a:l2)
+      let var[l] = a:data
+    endfor
+    call setbufvar(s:console_bfr, 'vader_data', var)
+  catch
+  endtry
+endfunction
+
+function! s:scratch(type, data, title)
+  setlocal buftype=nofile bufhidden=wipe nobuflisted noswapfile nowrap modifiable
+  silent! execute 'setf '.a:type
+  call append(0, a:data)
+  nnoremap <silent> <buffer> q :tabclose<cr>
+  autocmd TabLeave <buffer> tabclose
+
+  execute 'silent f '.escape(a:title, '[]')
+  normal! G"_ddgg
+  diffthis
+  setlocal nomodifiable
+endfunction
+
+function! s:action(line)
+  if has_key(b:vader_data, a:line)
+    let data = b:vader_data[a:line]
+    if has_key(data, 'expect')
+      tabnew
+      call s:scratch(data.type, data.expect, '[Vader-expected]')
+
+      vertical botright new
+      call s:scratch(data.type, data.got, '[Vader-got]')
+
+      redraw
+      echo "Press 'q' to close"
+    endif
+  else
+    execute "normal! \<CR>"
+  endif
+endfunction
+
+function! s:move()
+  let lno = matchstr(getline('.'), '(#[0-9]\+)')[2:-2]
+  let wq = winnr()
+  let wc = bufwinnr(s:console_bfr)
+  if wc >= 0
+    execute wc . 'wincmd w'
+    let scrolloff = &scrolloff
+    set scrolloff=0
+    execute lno
+    normal! zt
+    redraw
+    let &scrolloff = scrolloff
+    execute wq . 'wincmd w'
+  endif
+endfunction
+
+function! s:quit()
+  if s:prev_winid
+    let [s:t, s:w] = win_id2tabwin(s:prev_winid)
+    if s:t
+      execute printf('tabnext %d | %dwincmd w | %dtabclose', s:t, s:w, s:console_tab)
+      return
+    endif
+  endif
+  tabclose
+endfunction

data/spec/integration/runtime/vader.vim/plugin/vader.vim

@@ -0,0 +1,37 @@
+" Copyright (c) 2015 Junegunn Choi
+"
+" MIT License
+"
+" Permission is hereby granted, free of charge, to any person obtaining
+" a copy of this software and associated documentation files (the
+" "Software"), to deal in the Software without restriction, including
+" without limitation the rights to use, copy, modify, merge, publish,
+" distribute, sublicense, and/or sell copies of the Software, and to
+" permit persons to whom the Software is furnished to do so, subject to
+" the following conditions:
+"
+" The above copyright notice and this permission notice shall be
+" included in all copies or substantial portions of the Software.
+"
+" THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+" NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+" LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+" OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+" WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+
+if exists('g:loaded_vader') || &compatible
+  finish
+endif
+let g:loaded_vader = 1
+
+function! s:vader(...) range
+  if a:lastline - a:firstline > 0 && a:0 > 1
+    echoerr 'Range and file arguments are mutually exclusive'
+    return
+  endif
+  execute printf("%d,%dcall vader#run(%s)", a:firstline, a:lastline, string(a:000)[1:-2])
+endfunction
+
+command! -bang -nargs=* -range -complete=file Vader <line1>,<line2>call s:vader(<bang>0, <f-args>)

metadata

@@ -1,14 +1,14 @@
 --- !ruby/object:Gem::Specification
 name: neovim
 version: !ruby/object:Gem::Version
-  version: 0.5.0
+  version: 0.5.1
 platform: ruby
 authors:
 - Alex Genco
 autorequire: 
 bindir: bin
 cert_chain: []
-date: 2017-07-11 00:00:00.000000000 Z
+date: 2017-07-16 00:00:00.000000000 Z
 dependencies:
 - !ruby/object:Gem::Dependency
   name: msgpack
@@ -154,6 +154,13 @@ files:
 - spec/integration/runtime/rplugin/ruby/autocmds.rb
 - spec/integration/runtime/rplugin/ruby/commands.rb
 - spec/integration/runtime/rplugin/ruby/functions.rb
+- spec/integration/runtime/vader.vim/autoload/vader.vim
+- spec/integration/runtime/vader.vim/autoload/vader/assert.vim
+- spec/integration/runtime/vader.vim/autoload/vader/helper.vim
+- spec/integration/runtime/vader.vim/autoload/vader/parser.vim
+- spec/integration/runtime/vader.vim/autoload/vader/syntax.vim
+- spec/integration/runtime/vader.vim/autoload/vader/window.vim
+- spec/integration/runtime/vader.vim/plugin/vader.vim
 - spec/integration_spec.rb
 - spec/neovim/buffer_spec.rb
 - spec/neovim/client_spec.rb
@@ -225,6 +232,13 @@ test_files:
 - spec/integration/runtime/rplugin/ruby/autocmds.rb
 - spec/integration/runtime/rplugin/ruby/commands.rb
 - spec/integration/runtime/rplugin/ruby/functions.rb
+- spec/integration/runtime/vader.vim/autoload/vader.vim
+- spec/integration/runtime/vader.vim/autoload/vader/assert.vim
+- spec/integration/runtime/vader.vim/autoload/vader/helper.vim
+- spec/integration/runtime/vader.vim/autoload/vader/parser.vim
+- spec/integration/runtime/vader.vim/autoload/vader/syntax.vim
+- spec/integration/runtime/vader.vim/autoload/vader/window.vim
+- spec/integration/runtime/vader.vim/plugin/vader.vim
 - spec/integration_spec.rb
 - spec/neovim/buffer_spec.rb
 - spec/neovim/client_spec.rb