local_time 0.1.0

checksums.yaml

@@ -0,0 +1,7 @@
+---
+SHA1:
+  metadata.gz: d0bfe22e485d89d3b8b8ef64db29d82d4d4f518c
+  data.tar.gz: 7d662d650e07542e16b13b98315ce589992bf397
+SHA512:
+  metadata.gz: 840814649a2e4c03f7b8b9592ff696c7d5b7516a088a270fe2bdb4fb96e1a29221d455c31bbc31fdaa2a2dc0a38fe3718144c4c2dfe8ced9cbbc1d7ee76f425b
+  data.tar.gz: 2ed6f4bd924c469c23fd1134a53e4818ac1f5de1fd9cf9060859726bb47429176a8e5421f07c48d18303502c288ea38ccf74fff70ce55134f2e6b8fc110d23a4

data/MIT-LICENSE

@@ -0,0 +1,20 @@
+Copyright 2013 Javan Makhmali
+
+Permission is hereby granted, free of charge, to any person obtaining
+a copy of this software and associated documentation files (the
+"Software"), to deal in the Software without restriction, including
+without limitation the rights to use, copy, modify, merge, publish,
+distribute, sublicense, and/or sell copies of the Software, and to
+permit persons to whom the Software is furnished to do so, subject to
+the following conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

data/README.md

@@ -0,0 +1,72 @@
+Local Time is a Rails engine with helpers and JavaScript for displaying times and dates to users in their local time. The helpers render a `<time>` element in UTC and the JavaScript swoops in to convert and format. Because the `<time>` element is only rendered in one timezone, it is ideal for caching.
+
+---
+
+####Example
+
+Assuming the time zone is EST and `Time.now` is `2013-11-27 18:43:22 -0500`:
+
+```erb
+<%= local_time(Time.now) # index.html.erb %>
+```
+
+Renders in UTC time:
+
+```html
+<time data-format="%B %e, %Y %l:%M%P"
+      data-local="time"
+      datetime="2013-11-27T23:43:22Z">November 27, 2013 11:43pm</time>
+```
+
+Then immediately converts to local time and strftime formats with JavaScript:
+
+```html
+<time data-format="%B %e, %Y %l:%M%P"
+      data-local="time"
+      datetime="2013-11-27T23:43:22Z"
+      data-localized="true">November 27, 2013 6:43pm</time>
+```
+
+*(Line breaks added for readability)*
+
+#### Time and date helpers
+
+```erb
+Pass a time and an optional strftime format (default format shown here)
+<%= local_time(time, format: '%B %e, %Y %l:%M%P') %>
+
+Alias for local_time with a month-formatted default
+<%= local_date(time, format: '%B %e, %Y') %>
+```
+
+Note: The included strftime JavaScript implementation is not 100% complete. It supports the following directives: `%a %A %b %B %c %d %e %H %I %l %m %M %p %P %S %w %y %Y`
+
+#### Time ago helper
+
+```erb
+<%= local_time_ago(time) %>
+```
+
+Displays the relative amount of time passed. With age, the descriptions transition from specific quantities to general dates. The `<time>` elements are updated every 60 seconds. Examples (in quotes):
+
+* Recent: "a second ago", "32 seconds ago", "an hour ago", "14 hours ago"
+* Yesterday: "yesterday at 5:22pm"
+* This week: "Tuesday at 12:48am"
+* This year: "on Nov 17"
+* Last year: "on Jan 31, 2012"
+
+#### Installation
+
+1. Add `gem 'local_time'` to your Gemfile.
+2. Run `bundle install`.
+3. Add `//= require local_time` to your JavaScript manifest file (usually found at app/assets/javascripts/application.js).
+
+#### JavaScript events and library compatibility
+
+The included JavaScript does not depend on any frameworks or libraries, and listens for a `DOMContentLoaded` event to run initially. It also listens on `document` for `page:update` if you're using Turbolinks and `ajaxSuccess` if you're using jQuery. This should catch most cases where new `<time>` elements have been added to the DOM and process them automatically. If you're adding new elements in another context, trigger `time:elapse` to process them.
+
+#### Version History
+
+**0.1.0** (November 29, 2013)
+
+* Initial release.

data/app/assets/javascripts/local_time.js.coffee

@@ -0,0 +1,195 @@
+browserIsCompatible = ->
+  document.querySelectorAll and document.addEventListener
+
+return unless browserIsCompatible()
+
+# Older browsers do not support ISO8601 (JSON) timestamps in Date.parse
+if isNaN Date.parse "2011-01-01T12:00:00-05:00"
+  parse = Date.parse
+  iso8601 = /^(\d{4})-(\d{2})-(\d{2})T(\d{2}):(\d{2}):(\d{2})(Z|[-+]?[\d:]+)$/
+
+  Date.parse = (dateString) ->
+    dateString = dateString.toString()
+    if matches = dateString.match iso8601
+      [_, year, month, day, hour, minute, second, zone] = matches
+      offset = zone.replace(":", "") if zone isnt "Z"
+      dateString = "#{year}/#{month}/#{day} #{hour}:#{minute}:#{second} GMT#{[offset]}"
+    parse dateString
+
+weekdays = "Sunday Monday Tuesday Wednesday Thursday Friday Saturday".split " "
+months   = "January February March April May June July August September October November December".split " "
+
+pad = (num) -> ('0' + num).slice -2
+
+strftime = (time, formatString) ->
+  day    = time.getDay()
+  date   = time.getDate()
+  month  = time.getMonth()
+  year   = time.getFullYear()
+  hour   = time.getHours()
+  minute = time.getMinutes()
+  second = time.getSeconds()
+
+  formatString.replace /%([%aAbBcdeHIlmMpPSwyY])/g, ([match, modifier]) ->
+    switch modifier
+      when '%' then '%'
+      when 'a' then weekdays[day].slice 0, 3
+      when 'A' then weekdays[day]
+      when 'b' then months[month].slice 0, 3
+      when 'B' then months[month]
+      when 'c' then time.toString()
+      when 'd' then pad date
+      when 'e' then date
+      when 'H' then pad hour
+      when 'I' then pad strftime time, '%l'
+      when 'l' then (if hour is 0 or hour is 12 then 12 else (hour + 12) % 12)
+      when 'm' then pad month + 1
+      when 'M' then pad minute
+      when 'p' then (if hour > 11 then 'PM' else 'AM')
+      when 'P' then (if hour > 11 then 'pm' else 'am')
+      when 'S' then pad second
+      when 'w' then day
+      when 'y' then pad year % 100
+      when 'Y' then year
+
+
+class CalendarDate
+  @fromDate: (date) ->
+    new this date.getFullYear(), date.getMonth() + 1, date.getDate()
+
+  @today: ->
+    @fromDate new Date
+
+  constructor: (year, month, day) ->
+    @date = new Date Date.UTC year, month - 1
+    @date.setUTCDate day
+
+    @year = @date.getUTCFullYear()
+    @month = @date.getUTCMonth() + 1
+    @day = @date.getUTCDate()
+
+  occursOnSameYearAs: (date) ->
+    @year is date?.year
+
+  occursThisYear: ->
+    @occursOnSameYearAs @constructor.today()
+
+  daysSince: (date) ->
+    if date
+      (@date - date.date) / (1000 * 60 * 60 * 24)
+
+  daysPassed: ->
+    @constructor.today().daysSince @
+
+
+class RelativeTimeAgo
+  @generate: (date) ->
+    new this(date).toString()
+
+  constructor: (@date) ->
+    @calendarDate = CalendarDate.fromDate @date
+
+  toString: ->
+    # Today: "Saved 5 hours ago"
+    if ago = @timeElapsed()
+      "#{ago} ago"
+
+    # Yesterday: "Saved yesterday at 8:15am"
+    # This week: "Saved Thursday at 8:15am"
+    else if day = @relativeWeekday()
+      "#{day} at #{@formatTime()}"
+
+    # Older: "Saved on Dec 15"
+    else
+      "on #{@formatDate()}"
+
+  timeElapsed: ->
+    ms  = new Date().getTime() - @date.getTime()
+    sec = Math.round ms  / 1000
+    min = Math.round sec / 60
+    hr  = Math.round min / 60
+
+    if ms < 0
+      null
+    else if sec < 10
+      "a second"
+    else if sec < 45
+      "#{sec} seconds"
+    else if sec < 90
+      "a minute"
+    else if min < 45
+      "#{min} minutes"
+    else if min < 90
+      "an hour"
+    else if hr < 24
+      "#{hr} hours"
+    else
+      null
+
+  relativeWeekday: ->
+    daysPassed = @calendarDate.daysPassed()
+
+    if daysPassed > 6
+      null
+    else if daysPassed is 0
+      "today"
+    else if daysPassed is 1
+      "yesterday"
+    else
+      strftime @date, "%A"
+
+  formatDate: ->
+    format = "%b %e"
+    format += ", %Y" unless @calendarDate.occursThisYear()
+    strftime @date, format
+
+  formatTime: ->
+    strftime @date, '%l:%M%P'
+
+
+domLoaded = false
+
+update = (callback) ->
+  callback() if domLoaded
+
+  document.addEventListener "time:elapse", callback
+
+  if Turbolinks?.supported
+    document.addEventListener "page:update", callback
+  else
+    setTimeout ->
+      window.addEventListener "popstate", callback
+    , 1
+
+    jQuery?(document).on "ajaxSuccess", (event, xhr) ->
+      callback() if jQuery.trim xhr.responseText
+
+process = (selector, callback) ->
+  update ->
+    for element in document.querySelectorAll selector
+      callback element
+
+document.addEventListener "DOMContentLoaded", ->
+  domLoaded = true
+
+  process "time[data-local]:not([data-localized])", (element) ->
+    datetime = element.getAttribute "datetime"
+    format   = element.getAttribute "data-format"
+    local    = element.getAttribute "data-local"
+
+    time = new Date Date.parse datetime
+    return if isNaN time
+
+    element.innerText =
+      switch local
+        when "time"
+          element.setAttribute "data-localized", true
+          strftime time, format
+        when "time-ago"
+          RelativeTimeAgo.generate time
+
+  setInterval ->
+    event = document.createEvent "Events"
+    event.initEvent "time:elapse", true, true
+    document.dispatchEvent event
+  , 60 * 1000

data/app/helpers/local_time_helper.rb

@@ -0,0 +1,29 @@
+module LocalTimeHelper
+  def local_time(time, options = {})
+    time   = utc_time(time)
+    format = options.delete(:format).presence || '%B %e, %Y %l:%M%P'
+
+    options[:data] ||= {}
+    options[:data].merge! local: :time, format: format
+
+    time_tag time, time.strftime(format), options
+  end
+
+  def local_date(time, options = {})
+    options.reverse_merge! format: '%B %e, %Y'
+    local_time time, options
+  end
+
+  def local_time_ago(time)
+    time = utc_time(time)
+    time_tag time, time.strftime('%B %e, %Y %l:%M%P'), data: { local: 'time-ago' }
+  end
+
+  def utc_time(time_or_date)
+    if time_or_date.respond_to?(:in_time_zone)
+      time_or_date.in_time_zone.utc
+    else
+      time_or_date.to_time.utc
+    end
+  end
+end

data/lib/local_time.rb

@@ -0,0 +1,4 @@
+module LocalTime
+  class Engine < ::Rails::Engine
+  end
+end

data/test/helpers/local_time_helper_test.rb

@@ -0,0 +1,68 @@
+require_relative '../../app/helpers/local_time_helper'
+require 'active_support/all'
+require 'action_view'
+require 'minitest/autorun'
+
+
+class LocalTimeHelperTest < Minitest::Test
+  include ActionView::Helpers::DateHelper, ActionView::Helpers::TagHelper
+  include LocalTimeHelper
+
+  def setup
+    @original_zone = Time.zone
+    Time.zone = ActiveSupport::TimeZone["Central Time (US & Canada)"]
+
+    @date = "2013-11-21"
+    @time = Time.zone.parse(@date)
+    @time_utc = "2013-11-21 06:00:00 UTC"
+    @time_js = "2013-11-21T06:00:00Z"
+  end
+
+  def teardown
+    Time.zone = @original_zone
+  end
+
+  def test_utc_time_with_a_date
+    date = Date.parse(@date)
+    assert_equal @time_utc, utc_time(date).to_s
+  end
+
+  def test_utc_time_with_a_local_time
+    assert_equal @time_utc, utc_time(@time).to_s
+  end
+
+  def test_utc_time_with_a_utc_time
+    assert_equal @time_utc, utc_time(@time.utc).to_s
+  end
+
+  def test_local_time
+    expected = %Q(<time data-format="%B %e, %Y %l:%M%P" data-local="time" datetime="#{@time_js}">November 21, 2013  6:00am</time>)
+    assert_equal expected, local_time(@time)
+  end
+
+  def test_local_time_with_format
+    expected = %Q(<time data-format="%b %e" data-local="time" datetime="#{@time_js}">Nov 21</time>)
+    assert_equal expected, local_time(@time, format: '%b %e')
+  end
+
+  def test_local_time_with_options
+    expected = %Q(<time data-format="%b %e" data-local="time" datetime="#{@time_js}" style="display:none">Nov 21</time>)
+    assert_equal expected, local_time(@time, format: '%b %e', style: 'display:none')
+  end
+
+  def test_local_date
+    expected = %Q(<time data-format="%B %e, %Y" data-local="time" datetime="#{@time_js}">November 21, 2013</time>)
+    assert_equal expected, local_date(@time)
+    assert_equal expected, local_date(@time.to_date)
+  end
+
+  def test_local_date_with_format
+    expected = %Q(<time data-format="%b %e" data-local="time" datetime="#{@time_js}">Nov 21</time>)
+    assert_equal expected, local_date(@time, format: '%b %e')
+  end
+
+  def test_local_time_ago
+    expected = %Q(<time data-local="time-ago" datetime="#{@time_js}">November 21, 2013  6:00am</time>)
+    assert_equal expected, local_time_ago(@time)
+  end
+end

data/test/javascripts/config.ru

@@ -0,0 +1,20 @@
+require 'sprockets'
+require 'coffee-rails'
+
+Root = File.expand_path("../../..", __FILE__)
+
+Assets = Sprockets::Environment.new(Root) do |env|
+  env.append_path "app/assets/javascripts"
+  env.append_path "test/javascripts"
+  env.append_path "vendor"
+end
+
+map "/css" do
+  run Assets
+end
+
+map "/js" do
+  run Assets
+end
+
+map("/") { run Rack::File.new("#{Root}/test/javascripts/index.html") }

data/test/javascripts/index.html

@@ -0,0 +1,20 @@
+<!DOCTYPE html>
+<html>
+<head>
+  <meta charset="utf-8">
+  <link rel="stylesheet" href="/css/qunit.css">
+  <script type="text/javascript" src="/js/index.js"></script>
+</head>
+<body>
+  <div id="qunit"></div>
+  <div id="qunit-fixture"></div>
+
+  <time id="one" data-format="%B %e, %Y %l:%M%P" data-local="time" datetime="2013-11-12T12:13:00Z"></time>
+  <time id="two" data-format="%B %e, %Y %l:%M%P" data-local="time" datetime="2013-01-02T02:04:00Z"></time>
+  <time id="past" data-format="%B %e, %Y %l:%M%P" data-local="time" datetime="1805-05-15T01:01:00Z"></time>
+  <time id="future" data-format="%B %e, %Y %l:%M%P" data-local="time" datetime="3333-02-14T23:55:00Z"></time>
+
+  <time id="date" data-format="%B %e, %Y" data-local="time" datetime="2013-11-12T12:13:00Z"></time>
+
+  <time id="ago"></time>
+</html>

data/test/javascripts/index.js.coffee

@@ -0,0 +1,21 @@
+#= require qunit
+#= require moment
+#= require local_time
+#= require_directory ./unit
+#= require_self
+
+@addTimeEl = (format = "%Y", datetime = "2013-11-12T12:13:00Z") ->
+  el = document.createElement "time"
+  el.setAttribute "data-local", "time"
+  el.setAttribute "data-format", format
+  el.setAttribute "datetime", datetime
+  document.body.appendChild el
+  el
+
+@triggerEvent = (name, el = document) ->
+  event = document.createEvent "Events"
+  event.initEvent name, true, true
+  el.dispatchEvent event
+
+@run = ->
+  triggerEvent "time:elapse"

data/test/javascripts/unit/local_time_test.js.coffee

@@ -0,0 +1,36 @@
+module "localized"
+
+for id in ["one", "two", "past", "future"]
+  test id, ->
+    assertLocalized id
+
+test "date", ->
+  assertLocalized "date", "date"
+
+test "unparseable time", ->
+  el = addTimeEl "%Y", ":("
+  el.innerText = "2013"
+  run()
+  equal el.innerText, "2013"
+
+
+assertLocalized = (id, type = "time") ->
+  switch type
+    when "time"
+      momentFormat = "MMMM D, YYYY h:mma"
+      compare = "toString"
+    when "date"
+      momentFormat = "MMMM D, YYYY"
+      compare = "dayOfYear"
+
+  el = document.getElementById id
+
+  ok datetime = el.getAttribute "datetime"
+  ok local = el.innerText
+
+  datetimeParsed = moment datetime
+  localParsed = moment local, momentFormat
+
+  ok datetimeParsed.isValid()
+  ok localParsed.isValid()
+  equal datetimeParsed[compare](), localParsed[compare]()

data/test/javascripts/unit/page_events_test.js.coffee

@@ -0,0 +1,30 @@
+module "page events"
+
+test "document DOMContentLoaded", ->
+  el = addTimeEl()
+  triggerEvent "DOMContentLoaded"
+  ok el.innerText
+
+test "document time:elapse", ->
+  el = addTimeEl()
+  triggerEvent "time:elapse"
+  ok el.innerText
+
+test "window popstate", ->
+  el = addTimeEl()
+  triggerEvent "popstate", window
+  ok el.innerText
+
+test "document page:update with Turbolinks on", ->
+  el = addTimeEl()
+  triggerEvent "page:update"
+  ok not el.innerText
+
+  original = window.Turbolinks
+  window.Turbolinks = { supported: true }
+
+  triggerEvent "DOMContentLoaded"
+  triggerEvent "page:update"
+  ok el.innerText
+
+  window.Turbolinks = original

data/test/javascripts/unit/strftime_test.js.coffee

@@ -0,0 +1,40 @@
+module "strftime"
+
+momentMap =
+  "%a": "ddd"
+  "%A": "dddd"
+  "%b": "MMM"
+  "%B": "MMMM"
+  "%c": "toString()"
+  "%d": "DD"
+  "%e": "D"
+  "%H": "HH"
+  "%I": "hh"
+  "%l": "h"
+  "%m": "MM"
+  "%M": "mm"
+  "%p": "A"
+  "%P": "a"
+  "%S": "ss"
+  "%w": "e"
+  "%y": "YY"
+  "%Y": "YYYY"
+
+for day in [0..30] by 6
+  do (day) ->
+    for hour in [0..24] by 6
+      do (hour) ->
+        for format, momentFormat of momentMap
+          do (format, momentFormat) ->
+
+            test "#{format} (+#{day} days, #{hour} hours)", ->
+              now = moment().add("days", day).add("hours", hour)
+              el  = addTimeEl format, now.toISOString()
+              run()
+
+              equal el.innerText,
+                if func = momentFormat.match(/(\w+)\(\)/)?[1]
+                  now.toDate()[func]()
+                else
+                  now.format momentFormat
+

data/test/javascripts/unit/time_ago_test.js.coffee

@@ -0,0 +1,49 @@
+module "time ago"
+
+test "a second ago", ->
+  assertTimeAgo "a second ago", "seconds", 9
+
+test "seconds ago", ->
+  assertTimeAgo "44 seconds ago", "seconds", 44
+
+test "a minute ago", ->
+  assertTimeAgo "a minute ago", "seconds", 89
+
+test "minutes ago", ->
+  assertTimeAgo "44 minutes ago", "minutes", 44
+
+test "an hour ago", ->
+  assertTimeAgo "an hour ago", "minutes", 89
+
+test "hours ago", ->
+  assertTimeAgo "23 hours ago", "hours", 23
+
+test "yesterday", ->
+  time = moment().subtract("days", 1).format "h:mma"
+  assertTimeAgo "yesterday at #{time}", "days", 1
+
+test "last week", ->
+  ago  = moment().subtract "days", 5
+  day  = ago.format "dddd"
+  time = ago.format "h:mma"
+
+  assertTimeAgo "#{day} at #{time}", "days", 5
+
+test "this year", ->
+  # This will fail on the first 7 days of the year.
+  # Not sure how to test without somehow stubbing Date.
+  if moment().dayOfYear() > 7
+    date = moment().subtract("days", 7).format "MMM D"
+    assertTimeAgo "on #{date}", "days", 7
+
+test "last year", ->
+  date = moment().subtract("days", 366).format "MMM D, YYYY"
+  assertTimeAgo "on #{date}", "days", 366
+
+
+assertTimeAgo = (string, unit, amount) ->
+  el = document.getElementById "ago"
+  el.setAttribute "data-local", "time-ago"
+  el.setAttribute "datetime", moment().subtract(unit, amount).utc().toISOString()
+  run()
+  equal el.innerText, string

metadata

@@ -0,0 +1,79 @@
+--- !ruby/object:Gem::Specification
+name: local_time
+version: !ruby/object:Gem::Version
+  version: 0.1.0
+platform: ruby
+authors:
+- Javan Makhmali
+- Sam Stephenson
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2013-11-29 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: coffee-rails
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :runtime
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+description: 
+email: javan@37signals.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- app/assets/javascripts/local_time.js.coffee
+- app/helpers/local_time_helper.rb
+- lib/local_time.rb
+- MIT-LICENSE
+- README.md
+- test/helpers/local_time_helper_test.rb
+- test/javascripts/config.ru
+- test/javascripts/index.html
+- test/javascripts/index.js.coffee
+- test/javascripts/unit/local_time_test.js.coffee
+- test/javascripts/unit/page_events_test.js.coffee
+- test/javascripts/unit/strftime_test.js.coffee
+- test/javascripts/unit/time_ago_test.js.coffee
+homepage: 
+licenses:
+- MIT
+metadata: {}
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 2.1.11
+signing_key: 
+specification_version: 4
+summary: Rails engine for displaying local times using JavaScript
+test_files:
+- test/helpers/local_time_helper_test.rb
+- test/javascripts/config.ru
+- test/javascripts/index.html
+- test/javascripts/index.js.coffee
+- test/javascripts/unit/local_time_test.js.coffee
+- test/javascripts/unit/page_events_test.js.coffee
+- test/javascripts/unit/strftime_test.js.coffee
+- test/javascripts/unit/time_ago_test.js.coffee