iso8601-js 0.2.0

data/.gitignore

@@ -0,0 +1,5 @@
+node_modules
+npm-debug.log
+out/
+Gemfile.lock
+pkg/

data/CHANGELOG.md

@@ -0,0 +1,23 @@
+## 0.2.0 (2011-12-27)
+
+* API changed to match [ECMAScript 5.1][ecmascript] ISO 8601 support for the
+  Date object.
+  * `Date.prototype.toISO8601UTCString` is now `Date.prototype.toISOString`.
+  * `Date.prototype.toISO8601LocaleString` has been removed. Similar formatting
+    is available by passing *true* to `Date.prototype.toISO8601String` which
+    allows other customizations as well.
+* ISO 8601 UTC formatting falls back to native support if available. Performance
+  improvement on modern browsers for common usages.
+* Stricter browser test for native ISO 8601 parsing. Ensures timezone offsets
+  are correctly handled. Fixes Firefox issues.
+* Unit tests. Suite runs via node or browser harness.
+
+## 0.1.0 (2011-12-23)
+
+* First release. Extracted from the Do web client, based on Paul Gallagher's
+  [rfc3339date.js library][rfc3339date.js].
+
+
+
+[ecmascript]:     http://www.ecma-international.org/publications/files/ECMA-ST/Ecma-262.pdf
+[rfc3339date.js]: https://github.com/tardate/rfc3339date.js

data/Gemfile

@@ -0,0 +1,3 @@
+source 'http://rubygems.org'
+
+gemspec

data/LICENSE

@@ -0,0 +1,21 @@
+Copyright (c) 2010 Paul GALLAGHER (http://tardate.com)
+Copyright (c) 2011 Do (http://do.com)
+
+Permission is hereby granted, free of charge, to any person obtaining
+a copy of this software and associated documentation files (the
+"Software"), to deal in the Software without restriction, including
+without limitation the rights to use, copy, modify, merge, publish,
+distribute, sublicense, and/or sell copies of the Software, and to
+permit persons to whom the Software is furnished to do so, subject to
+the following conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

data/Makefile

@@ -0,0 +1,16 @@
+all:
+	mkdir -p ./out
+	./node_modules/.bin/coffee -o out -c lib/iso8601.coffee
+	./node_modules/.bin/uglifyjs -o out/iso8601.js.min out/iso8601.js
+
+clean:
+	rm out/*
+
+test:
+	TZ='PST+8' ./node_modules/.bin/mocha --reporter spec
+
+testbrowser:
+	echo "Browse to http://localhost:8000/test/browser/index.html"
+	python -m SimpleHTTPServer
+
+.PHONY: all clean test testbrowser

data/README.md

@@ -0,0 +1,124 @@
+iso8601.js
+==========
+
+Partial ECMAScript 5.1 Date object cross-browser polyfill to add
+a [ISO 8601][iso8601] support to **Date.parse** and
+**Date.prototype.toISOString**. Originally based on Paul Gallagher's
+a [rfc3339date.js library][rfc3339date.js].
+
+Supports only the subset of ISO 8601 described in
+a [ECMAScript 5.1 section 15.9.4.2][ecmascript], [RFC 3339][rfc3339], and the
+a [Date and Time Formats W3C NOTE][w3c-note].
+
+
+## Usage
+
+Download [iso8601.js][downloads] and include as usual before other scripts:
+
+```html
+<script src="iso8601.min.js"></script>
+```
+
+If you're using [Sprockets 2][sprockets], you can use the gem version of the
+library. Add to your Gemfile:
+
+```ruby
+gem 'iso8601-js'
+```
+
+If using Rails 3.1+, the library is automatically added to your asset paths.
+Otherwise add `ISO8601JS.assets_path` to your Sprockets environment:
+
+```ruby
+env = Sprockets::Environment.new  # or however you initialize Sprockets
+env.append_path ISO8601JS.assets_path
+```
+
+Then require it from the appropriate JavaScript or CoffeeScript files with the
+`= require` Sprockets directive:
+
+JavaScript:
+
+```javascript
+//= require iso8601-js
+```
+
+CoffeeScript:
+
+```coffee-script
+#= require iso8601-js
+```
+
+
+## Parsing
+
+Parse ISO 8601 date/time strings two ways:
+
+* **Date.parseISO8601("...")** builds a Date instance from a string containing
+  an ISO 8610 date.
+* **Date.parse("...")** is polyfilled to attempt ISO 8601 parsing on the string
+  before using the browser's native `Date.parse`. Returns the number of
+  milliseconds between the Unix epoch and the date.
+
+Examples:
+
+```js
+console.log(Date.parseISO8601("2010-07-20T15:00:00Z"))
+// => Tue Jul 20 2010 08:00:00 GMT-0700 (PDT)
+
+console.log(Date.parse("2010-07-20T15:00:00Z"));
+// => 1307834445456
+```
+
+
+## Formatting
+
+Format ISO 8601 date strings directly from Date instances:
+
+* **Date.prototype.toISOString** generates an ISO 8601 string in UTC.
+* **Date.prototype.toISO8601String** generates an ISO 8601 string with
+  formatting options:
+  * *localTimezone*: Use local timezone with offset or UTC? Defaults to *false*.
+  * *separators*: Include date/time separator? Defaults to *true*.
+  * *milliseconds*: Include milliseconds? Defaults to *true*.
+
+Examples:
+
+```js
+var date = Date.parseISO8601("2010-07-20T15:00:00Z");
+
+console.log(date.toISOString());
+// => "2010-07-20T15:00:00.000Z"
+
+console.log(date.toISO8601String(true, true, false));
+// => "2010-07-20T08:00:00-07:00"
+```
+
+
+## Caveats
+
+The Date constructor is not polyfilled to support ISO 8601. Avoid using `new
+Date("...")` to parse strings.
+
+
+## Contributing
+
+iso8601.js is written in [CoffeeScript][coffeescript]. Use `npm install` to
+install required development packages. Compile minified JavaScript output with
+`make`. Run the test suite via `make test`.
+
+Patches and bug reports are always welcome. Just send a
+[pull request][pullrequests] or file an [issue][issues].
+
+
+
+[iso8601]:        http://en.wikipedia.org/wiki/ISO_8601
+[rfc3339date.js]: https://github.com/tardate/rfc3339date.js
+[ecmascript]:     http://www.ecma-international.org/publications/files/ECMA-ST/Ecma-262.pdf
+[rfc3339]:        http://www.ietf.org/rfc/rfc3339.txt
+[w3c-note]:       http://www.w3.org/TR/NOTE-datetime
+[downloads]:      https://github.com/Do/iso8601.js/downloads
+[sprockets]:      https://github.com/sstephenson/sprockets
+[coffeescript]:   http://coffeescript.org/
+[pullrequests]:   https://github.com/Do/iso8601.js/pulls
+[issues]:         https://github.com/Do/iso8601.js/issues

data/Rakefile

@@ -0,0 +1,3 @@
+#!/usr/bin/env rake
+
+require 'bundler/gem_tasks'

data/iso8601-js.gemspec

@@ -0,0 +1,24 @@
+# -*- encoding: utf-8 -*-
+
+require File.expand_path('../lib/iso8601-js/version', __FILE__)
+
+Gem::Specification.new do |gem|
+  gem.name          = 'iso8601-js'
+  gem.version       = ISO8601JS::VERSION
+  gem.authors       = ['Gopal Patel', 'David Yung', 'Sai Tun']
+  gem.email         = ['nixme@stillhope.com', 'azethoth@do.com', 'sai@do.com']
+  gem.license       = 'MIT'
+  gem.homepage      = 'https://github.com/Do/iso8601.js'
+  gem.summary       = 'Sprockets asset gem for the iso8601.js EC5.1 polyfill library'
+  gem.description   = 'Adds cross-browser ISO 8601 support to the JavaScript Date object based on EC5.1. This is a Sprockets gem to simplify inclusion of the client-side library.'
+
+  gem.executables   = `git ls-files -- bin/*`.split("\n").map{ |f| File.basename(f) }
+  gem.files         = `git ls-files`.split("\n")
+  gem.test_files    = `git ls-files -- {test,spec,features}/*`.split("\n")
+  gem.require_paths = ['lib']
+
+  # Dependencies
+  gem.add_dependency 'sprockets', '~> 2.0'
+  gem.add_dependency 'coffee-script', '~> 2.2'
+  gem.add_development_dependency 'rake'
+end

data/lib/iso8601-js.rb

@@ -0,0 +1,19 @@
+require 'iso8601-js/version'
+
+module ISO8601JS
+  ASSETS_PATH = File.expand_path('..', __FILE__).freeze
+
+  def self.assets_path
+    ASSETS_PATH
+  end
+
+
+  # Automatic initialization if used with Rails 3.1+
+  if defined? ::Rails::Railtie
+    class Railtie < ::Rails::Railtie
+      initializer 'iso8601-js', :after => 'sprockets.environment' do |app|
+        app.assets.append_path(ISO8601JS.assets_path) if app.assets
+      end
+    end
+  end
+end

data/lib/iso8601-js/version.rb

@@ -0,0 +1,3 @@
+module ISO8601JS
+  VERSION = '0.2.0'
+end

data/lib/iso8601.coffee

@@ -0,0 +1,236 @@
+# iso8601.js
+#
+# Partial ECMAScript 5.1 Date object polyfill to support the ISO 8601 format
+# specified in section 15.9.1.15 in Date.parse (section 15.9.4.2) and
+# Date.prototype.toISOString (section 15.9.5.43). ISO 8601 formats from RFC 3339
+# and the W3C Date and Time Formats NOTE (http://www.w3.org/TR/NOTE-datetime)
+# are also supported.
+#
+# Adds string parsing and formatting functions directly to the native Date
+# object and prototype. Uses native functionality where available.
+#
+# Examples
+#
+#   Date.parse("2010-07-20T15:00:00Z")
+#   // => 1307834445456
+#
+#   date = Date.parseISO8601("2010-07-20T15:00:00Z")
+#   // => Tue Jul 20 2010 08:00:00 GMT-0700 (PDT)
+#
+#   date.toISOString()
+#   // => "2010-07-20T15:00:00.000Z"
+#
+#   date.toISO8601String(true)
+#   // => "2010-07-20T08:00:00.000-07:00"
+#
+# Note: Avoid using "new Date(...)" to parse ISO 8601 strings since this library
+# does not polyfill the Date constructor.
+#
+#
+# Originally based on Paul Gallagher's rfc3339date.js library
+#   https://github.com/tardate/rfc3339date.js
+# Copyright (c) 2010 Paul GALLAGHER  http://tardate.com
+#
+# Additional modifications by the Do team
+# Copyright (c) 2011 Do  http://do.com
+#
+# Licensed under the MIT license
+#   http://www.opensource.org/licenses/mit-license.php
+#
+
+
+
+# Helper function to left-pad numbers to the specified length
+pad = (number, length = 2) ->
+  result = number.toString()
+  while result.length < length
+    result = '0' + result
+  result
+
+# Unit tests to check native ISO 8601 support
+supportsISOParsing = Date.parse?('2011-06-11T23:20:45.456-0700') is 1307859645456
+supportsISOFormatting = Date::toISOString?
+
+
+
+# Date.prototype.toISO8601String
+#
+# Format the date in ISO 8601 / RFC 3339 with custom rules. With no parameters,
+# output is equivalent to the ECMAScript 5.1 defined Date.prototype.toISOString.
+#
+# localTimezone - Use local timezone or UTC offset? (default: false, i.e. UTC)
+# separators    - Include date/time separators? (default: true)
+# milliseconds  - Include milliseconds? (default: true)
+#
+# Examples
+#
+#   new Date().toISO8601String(true)
+#   // => "2010-07-25T19:51:31.427+08:00"
+#
+#   new Date().toISO8601String(true)
+#   // => "2010-07-25T19:51:31.427+08:00"
+#
+#   new Date().toISO8601String(true)
+#   // => "2010-07-25T19:51:31.427+08:00"
+#
+Date::toISO8601String = (localTimezone = false, separators = true, milliseconds = true) ->
+  # Raise RangeError for invalid dates
+  timet = @getTime()
+  if timet != timet  # isNaN
+    throw new RangeError 'Invalid date'
+
+  dateSeparator = if separators then '-' else ''
+  timeSeparator = if separators then ':' else ''
+
+  result =
+    if localTimezone
+      @getFullYear().toString() + dateSeparator +
+      pad(@getMonth() + 1)      + dateSeparator +
+      pad(@getDate())           + 'T'           +
+      pad(@getHours())          + timeSeparator +
+      pad(@getMinutes())        + timeSeparator +
+      pad(@getSeconds())
+    else
+      @getUTCFullYear().toString() + dateSeparator +
+      pad(@getUTCMonth() + 1)      + dateSeparator +
+      pad(@getUTCDate())           + 'T' +
+      pad(@getUTCHours())          + timeSeparator +
+      pad(@getUTCMinutes())        + timeSeparator +
+      pad(@getUTCSeconds())
+
+  if milliseconds
+    result += '.' +
+      pad (if localTimezone then @getMilliseconds() else @getUTCMilliseconds()), 3
+
+  if localTimezone
+    tzOffset = @getTimezoneOffset()
+    if tzOffset >= 0
+      result += '-'
+    else
+      result += '+'
+      tzOffset *= -1
+    result + pad(tzOffset / 60) + timeSeparator + pad(tzOffset % 60)
+  else
+    result + 'Z'
+
+
+
+# Date.prototype.toISOString
+#
+# Format the date in UTC ISO 8601 / RFC 3339.
+#
+# Defined in ECMAScript 5.1 section 15.9.5.43. An implementation is set only if
+# the browser lacks native support.
+#
+# Examples
+#
+#   new Date().toISOString()
+#   // => "2010-07-25T11:51:31.427Z"
+#
+unless supportsISOFormatting
+  Date::toISOString = Date::toISO8601String
+
+
+
+# Date.parseISO8601
+#
+# Parses ISO8601 / RFC 3339 date strings to a Date object. Uses native browser
+# parsing if available.
+#
+# input     - The String to parse.
+# useNative - Use browser native parsing if available? (default: true)
+#
+# Examples
+#
+#   Date.parseISO8601("2010-07-20T15:00:00Z")
+#   // => ....
+#
+ISO8601_PATTERN = ///
+  (\d\d\d\d)       # year
+  (-)?
+  (\d\d)           # month
+  (-)?
+  (\d\d)           # day
+  (T)?
+  (\d\d)           # hour
+  (:)?
+  (\d\d)?          # minute
+  (:)?
+  (\d\d)?          # seconds
+  ([\.,]\d+)?      # milliseconds
+  (
+    $|             # end of input = no timezone information
+    Z|             # UTC
+      ([+-])       # offset direction
+      (\d\d)       # offset hours
+      (:)?
+      (\d\d)?      # offset minutes
+  )
+///i
+
+DECIMAL_SEPARATOR = String(1.5).charAt(1)
+
+parseISO8601 = (input) ->
+  type = Object::toString.call(input)
+
+  # Return the input if it's already a Date instance
+  return input if type == '[object Date]'
+
+  # Can only parse Strings
+  return undefined unless type == '[object String]'
+
+  if matches = input.match(ISO8601_PATTERN)
+    year    = parseInt(matches[1], 10)
+    month   = parseInt(matches[3], 10) - 1
+    day     = parseInt(matches[5], 10)
+    hour    = parseInt(matches[7], 10)
+    minutes = if matches[9]  then parseInt(matches[9], 10)  else 0
+    seconds = if matches[11] then parseInt(matches[11], 10) else 0
+    milliseconds =
+      if matches[12]
+        parseFloat(DECIMAL_SEPARATOR + matches[12][1..]) * 1000
+      else
+        0
+
+    result = Date.UTC(year, month, day, hour, minutes, seconds, milliseconds)
+    if matches[13] && matches[14]  # Timezone adjustment
+      offset = matches[15] * 60
+      offset += parseInt(matches[17], 10) if (matches[17])
+      offset *= if matches[14] is '-' then -1 else 1
+      result -= offset * 60 * 1000
+    new Date(result)
+
+if supportsISOParsing
+  Date.parseISO8601 = (input, useNative = true) ->
+    if useNative     # Use the default Date constructor, we have native support.
+      new Date(input)
+    else             # Force the polyfill.
+      parseISO8601 input
+else                 # No native support, always use polyfill.
+  Date.parseISO8601 = parseISO8601
+
+
+
+# Date.parse
+#
+# Parses date strings; returns time in milliseconds since the Unix epoch. See
+# http://developer.mozilla.org/en/JavaScript/Reference/Global_Objects/Date/parse
+#
+# This polyfills the standard Date.parse to support ISO 8601 / RFC 3339 date
+# strings only if the browser doesen't have native support.
+#
+# Examples
+#
+#   Date.parse("2010-07-20T15:00:00Z")
+#   // => 1279638000000
+#
+if Object::toString.call(Date.parse) != '[object Function]'
+  # No built-in Date.parse, use our version.
+  Date.parse = (input) -> parseISO8601(input)?.getTime()
+else if not supportsISOParsing
+  # No native ISO 8601 parsing, chain our version
+  oldDateParse = Date.parse
+  Date.parse = (input) ->
+    result = parseISO8601(input)?.getTime()
+    result = oldDateParse(input) if not result and oldDateParse
+    result

data/package.json

@@ -0,0 +1,40 @@
+{
+  "name": "iso8601",
+  "description": "EC5.1 Date polyfill for ISO8601 support",
+  "version": "0.2.0",
+  "keywords": ["date", "time", "iso8601", "polyfill", "shim"],
+  "contributors": [
+    {
+      "name": "Gopal Patel",
+      "email": "nixme@stillhope.com"
+    },
+    {
+      "name": "David Yung",
+      "email": "azethoth@do.com"
+    },
+    {
+      "name": "Sai Tun",
+      "email": "sai@do.com"
+    }
+  ],
+  "homepage": "https://github.com/Do/iso8601.js",
+  "bugs": "https://github.com/Do/iso8601.js/issues",
+  "licenses": [
+    {
+      "type": "MIT",
+      "url": "https://raw.github.com/Do/iso8601.js/master/LICENSE"
+    }
+  ],
+  "repositories": [
+    {
+      "type": "git",
+      "url": "https://github.com/Do/iso8601.js.git"
+    }
+  ],
+  "devDependencies": {
+    "coffee-script": "1.2.0",
+    "uglify-js": "1.2.2",
+    "mocha": "0.7.1",
+    "chai": "0.1.4"
+  }
+}

data/test/browser/index.html

@@ -0,0 +1,151 @@
+<!doctype html>
+<html>
+  <head>
+    <meta charset="utf-8">
+    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8">
+
+    <title>iso8601.js Tests</title>
+
+    <style type="text/css">
+      body {
+        font: 20px/1.5 "Helvetica Neue", Helvetica, Aria;, sans-serif;
+        padding: 60px 50px;
+      }
+
+      #mocha h1, h2 {
+        margin: 0;
+      }
+
+      #mocha h1 {
+        font-size: 1em;
+        font-weight: 200;
+      }
+
+      #mocha .suite .suite h1 {
+        font-size: .8em;
+      }
+
+      #mocha h2 {
+        font-size: 12px;
+        font-weight: normal;
+        cursor: pointer;
+      }
+
+      #mocha .suite {
+        margin-left: 15px;
+      }
+
+      #mocha .test {
+        margin-left: 15px;
+      }
+
+      #mocha .test:hover h2::after {
+        position: relative;
+        top: 0;
+        right: -10px;
+        content: '(view source)';
+        font-size: 12px;
+        color: #888;
+      }
+
+      #mocha .test.pass::before {
+        content: '✓';
+        font-size: 12px;
+        display: block;
+        float: left;
+        margin-right: 5px;
+        color: #00c41c;
+      }
+
+      #mocha .test.pending {
+        color: #0b97c4;
+      }
+
+      #mocha .test.pending::before {
+        content: '◦';
+        color: #0b97c4;
+      }
+
+      #mocha .test.fail {
+        color: #c00;
+      }
+
+      #mocha .test.fail pre {
+        color: black;
+      }
+
+      #mocha .test.fail::before {
+        content: '✖';
+        font-size: 12px;
+        display: block;
+        float: left;
+        margin-right: 5px;
+        color: #c00;
+      }
+
+      #mocha .test pre.error {
+        color: #c00;
+      }
+
+      #mocha .test pre {
+        display: inline-block;
+        font: 12px/1.5 monaco, monospace;
+        margin: 5px;
+        padding: 15px;
+        border: 1px solid #eee;
+        border-bottom-color: #ddd;
+        -webkit-border-radius: 3px;
+        -webkit-box-shadow: 0 1px 3px #eee;
+      }
+
+      #error {
+        color: #c00;
+        font-size: 1.5  em;
+        font-weight: 100;
+        letter-spacing: 1px;
+      }
+
+      #stats {
+        position: fixed;
+        top: 30px;
+        right: 30px;
+        font-size: 12px;
+        margin: 0;
+        color: #888;
+      }
+
+      #stats .progress {
+        margin-bottom: 10px;
+      }
+
+      #stats em {
+        color: black;
+      }
+
+      #stats li {
+        list-style: none;
+      }
+    </style>
+
+    <script src="https://ajax.googleapis.com/ajax/libs/jquery/1.7.1/jquery.min.js" type="text/javascript"></script>
+    <script src="https://raw.github.com/visionmedia/mocha/0.7.1/mocha.js" type="text/javascript"></script>
+    <script src="https://raw.github.com/logicalparadox/chai/0.1.4/chai.js" type="text/javascript"></script>
+    <script src="https://raw.github.com/jashkenas/coffee-script/1.2.0/extras/coffee-script.js" type="text/javascript"></script>
+
+    <!-- Initialize mocha -->
+    <script type="text/coffeescript">mocha.setup('bdd')</script>
+
+    <!-- Load library under test -->
+    <script src="../../lib/iso8601.coffee" type="text/coffeescript"></script>
+
+    <!-- Load test cases -->
+    <script src="../test.date.coffee" type="text/coffeescript"></script>
+
+    <!-- Run the tests! -->
+    <script type="text/coffeescript">$(-> mocha.run())</script>
+  </head>
+
+  <body>
+    <div id="mocha"></div>
+  </body>
+</html>

data/test/test.date.coffee

@@ -0,0 +1,71 @@
+# Tests for the polyfill parsing and formatting functions. Browser native
+# support detection and usage untested.
+#
+# For proper testing of timezone offsets, the suite must be run in the PST (non
+# daylight savings) timezone environment, e.g. TZ='PST+8'.
+#
+
+chai = @chai || require('chai')
+assert = chai.assert
+expect = chai.expect
+require('../lib/iso8601') if require?
+
+describe 'Date', ->
+
+  # Date fixture: Sat Jun 18, 2011 02:20:45.678 PST
+  date = new Date(1308392445678)
+
+  describe 'toISO8601String', ->
+
+    it 'defaults to UTC with date/time separators and milliseconds', ->
+      assert.equal '2011-06-18T10:20:45.678Z', date.toISO8601String()
+
+    it 'produces same output as toISOString', ->
+      assert.equal date.toISO8601String(), date.toISOString()
+
+    it 'can format without date/time separators', ->
+      assert.equal '20110618T102045.678Z', date.toISO8601String(false, false, true)
+
+    it 'can format without milliseconds', ->
+      assert.equal '2011-06-18T10:20:45Z', date.toISO8601String(false, true, false)
+
+    it 'can format without date/time separators and milliseconds', ->
+      assert.equal '20110618T102045Z', date.toISO8601String(false, false, false)
+
+    it 'can format in local timezone and include offset', ->
+      assert.equal '2011-06-18T02:20:45.678-08:00', date.toISO8601String(true, true, true)
+
+    it 'throws RangeError for Invalid Dates', ->
+      fn = -> new Date('not a date').toISO8601String()
+      expect(fn).to.throw RangeError
+
+
+  describe 'parseISO8601', ->
+
+    it 'parses UTC ISO 8601 strings', ->
+      assert.equal date.getTime(), Date.parseISO8601('2011-06-18T10:20:45.678Z', false).getTime()
+
+    it 'parses ISO 8601 strings with timezone offsets', ->
+      assert.equal date.getTime(), Date.parseISO8601('2011-06-18T02:20:45.678-08:00', false).getTime()
+
+    it 'returns the input if given a Date instance', ->
+      assert.equal date, Date.parseISO8601(date, false)
+
+    it 'returns undefined for non-String input', ->
+      assert.isUndefined Date.parseISO8601(2, false)
+      assert.isUndefined Date.parseISO8601((-> 1), false)
+
+    it 'returns undefined for invalid string inputs', ->
+      assert.isUndefined Date.parseISO8601('this is not a date', false)
+
+
+  describe 'parse', ->
+
+    it 'parses UTC ISO 8601 strings to epoch milliseconds', ->
+      assert.equal 1307834445456, Date.parse('2011-06-11T23:20:45.456Z')
+
+    it 'parses ISO 8601 strings with timezone offsets to epoch milliseconds', ->
+      assert.equal 1307859645456, Date.parse('2011-06-11T23:20:45.456-0700')
+
+    it 'falls back to native Date.parse for non ISO strings', ->
+      assert.equal 807926400000, Date.parse('Wed, 09 Aug 1995 00:00:00 GMT')

metadata

@@ -0,0 +1,100 @@
+--- !ruby/object:Gem::Specification
+name: iso8601-js
+version: !ruby/object:Gem::Version
+  version: 0.2.0
+  prerelease: 
+platform: ruby
+authors:
+- Gopal Patel
+- David Yung
+- Sai Tun
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2011-12-27 00:00:00.000000000Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: sprockets
+  requirement: &70341578450300 !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '2.0'
+  type: :runtime
+  prerelease: false
+  version_requirements: *70341578450300
+- !ruby/object:Gem::Dependency
+  name: coffee-script
+  requirement: &70341578449500 !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ~>
+      - !ruby/object:Gem::Version
+        version: '2.2'
+  type: :runtime
+  prerelease: false
+  version_requirements: *70341578449500
+- !ruby/object:Gem::Dependency
+  name: rake
+  requirement: &70341578448740 !ruby/object:Gem::Requirement
+    none: false
+    requirements:
+    - - ! '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: *70341578448740
+description: Adds cross-browser ISO 8601 support to the JavaScript Date object based
+  on EC5.1. This is a Sprockets gem to simplify inclusion of the client-side library.
+email:
+- nixme@stillhope.com
+- azethoth@do.com
+- sai@do.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- .gitignore
+- CHANGELOG.md
+- Gemfile
+- LICENSE
+- Makefile
+- README.md
+- Rakefile
+- iso8601-js.gemspec
+- lib/iso8601-js.rb
+- lib/iso8601-js/version.rb
+- lib/iso8601.coffee
+- package.json
+- test/browser/index.html
+- test/test.date.coffee
+homepage: https://github.com/Do/iso8601.js
+licenses:
+- MIT
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  none: false
+  requirements:
+  - - ! '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  none: false
+  requirements:
+  - - ! '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 1.8.10
+signing_key: 
+specification_version: 3
+summary: Sprockets asset gem for the iso8601.js EC5.1 polyfill library
+test_files:
+- test/browser/index.html
+- test/test.date.coffee