evrobone 0.1.0

checksums.yaml

@@ -0,0 +1,7 @@
+---
+SHA1:
+  metadata.gz: 2baf24c64a08d5f463fc312f832fbda17bd01b15
+  data.tar.gz: 9c5702ca5a0ce30b22eef32385f88762589ba5e5
+SHA512:
+  metadata.gz: a5ebdfba039cb37c56a6c5ea3f5f8e7d6b967209045ee1ebd4c2cad5d16ffb7fe2496da01177f922b87246fab18b84a2744f6b7c24b0b463d37b19bdab7a9ae1
+  data.tar.gz: 435af2792b86a3c13f8a9e2704f653226e20fb7778355093a3bb0c9c54775fd546926d9c8c0c596e4e31df64d64517cdd98b7966f9558f98484537219f231785

data/.gitignore

@@ -0,0 +1,3 @@
+*.gem
+/.bundle/
+/Gemfile.lock

data/.rubocop.yml

@@ -0,0 +1,5 @@
+Metrics/LineLength:
+  Max: 120
+
+Style/Documentation:
+  Enabled: false

data/.travis.yml

@@ -0,0 +1,9 @@
+language: ruby
+rvm:
+  - 2.2.2
+before_install: gem install bundler -v 1.10.4
+env:
+  matrix:
+    - BUILD_CMD='rubocop'
+    - BUILD_CMD='rake coffeelint'
+script: bundle exec ${BUILD_CMD}

data/Gemfile

@@ -0,0 +1,4 @@
+source 'https://rubygems.org'
+
+# Specify your gem's dependencies in evrobone.gemspec
+gemspec

data/LICENSE.txt

@@ -0,0 +1,21 @@
+The MIT License (MIT)
+
+Copyright (c) 2015 Dmitry Karpunin (aka KODer) koderfunk@gmail.com
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+THE SOFTWARE.

data/README.md

@@ -0,0 +1,53 @@
+# Evrobone
+
+Light-weight client-side framework based on Backbone.js for Ruby on Rails Front-end
+
+## Installation
+
+Add this line to your application's Gemfile:
+
+```ruby
+gem 'evrobone'
+```
+
+And then execute:
+
+    $ bundle
+
+Or install it yourself as:
+
+    $ gem install evrobone
+
+## Usage
+
+Coming soon...
+
+### `Evrobone.AppClass` и организация приложения
+
+### `Evrobone.AppMixins.ViewsManagement` и `Evrobone.View`
+
+### `Evrobone.AppMixins.CustomElementBinding` и `/initializers`
+
+### `Evrobone.AppMixins.WindowNavigation` и совместимость с Turbolinks
+
+### `Evrobone.AppMixins.WindowRefresh`
+
+### LiveReload plugin for Ruby on Rails
+
+Для более удобного использования LiveReload в Ruby on Rails проекте, можно подключить плагин, добавив в `config/initializers/assets.rb`:
+```ruby
+Rails.application.config.assets.precompile += %w( evrobone/lib/livereload-plugin-rails.js ) if Rails.env.development?
+```
+и подключить скрипт в лэйауте:
+```haml
+- if Rails.env.development?
+  = javascript_include_tag 'evrobone/lib/livereload-plugin-rails'
+```
+
+## Contributing
+
+Bug reports and pull requests are welcome on GitHub at https://github.com/KODerFunk/evrobone.
+
+## License
+
+The gem is available as open source under the terms of the [MIT License](http://opensource.org/licenses/MIT).

data/Rakefile

@@ -0,0 +1,7 @@
+require 'bundler/gem_tasks'
+require 'coffeelint'
+
+desc 'Run CoffeeLint'
+task 'coffeelint' do
+  Coffeelint.run_test_suite 'app/assets/javascripts'
+end

data/app/assets/javascripts/evrobone/app-class.js.coffee

@@ -0,0 +1,80 @@
+#= require ./helpers
+#= require ./jquery-additions
+
+@Evrobone ||= {}
+
+Evrobone.AppMixins ||= {}
+
+class Evrobone.AppClass
+  @App: null
+
+  name: null
+  performanceReport: true
+  performanceMicro: false
+
+  touchDevice: ('ontouchstart' of document.documentElement and not TEST_MODE)
+  # or !!(window.DocumentTouch and document instanceof DocumentTouch)
+  $window: null
+
+  @mixinNames: null
+
+  # Reset mixinNames
+  @mixinable: ->
+    @mixinNames = if @mixinNames then _.clone(@mixinNames) else []
+
+  # Mixins support
+  @include: (mixin, name = null) ->
+    @mixinNames ||= []
+    if name?
+      @mixinNames = _.without(@mixinNames, name)
+      @mixinNames.push(name)
+    unless mixin?
+      cout 'error', "AppMixin #{name or '_no_name_'} is undefined"
+    _.extend @::, mixin
+
+  @include Backbone.Events
+
+  constructor: (name = null) ->
+    if @constructor.App
+      throw new Error('Can\'t create new AppClass instance because the single instance has already been created')
+    else
+      cout 'info', 'Evrobone.AppClass.constructor', name, @
+      @constructor.App = @
+      @name = name
+      for mixinName in @constructor.mixinNames
+        @[mixinName + 'Initialize']?()
+    return
+
+  start: (initial = true) ->
+    @$window = $(window) if initial
+    $('body').addClass('touch-device') if @touchDevice
+    @performanceReport = DEBUG_MODE if @performanceReport
+    @performanceStart() if @performanceReport
+    @trigger 'start', initial
+    return
+
+  stop: ->
+    @trigger 'stop'
+    return
+
+  performanceStartAt: null
+
+  performanceStart: ->
+    if _.isFunction(performance?.now)
+      @performanceStartAt = performance.now()
+    else
+      cout 'warn', 'performance.now() isnt available'
+      @performanceReport = null
+
+  performancePoint: (message, count = null) ->
+    pointAt = performance.now()
+    message = @_plurMessage(message, count) if count?
+    time = if @performanceMicro
+      "#{Math.round((pointAt - @performanceStartAt) * 1000)}\u00B5s"
+    else
+      "#{Math.round(pointAt - @performanceStartAt)}ms"
+    cout 'info', "#{message} in #{time}"
+    @performanceStartAt = pointAt
+
+  _plurMessage: (message, count) ->
+    message.replace('%count%', count).replace('%s%', if count is 1 then '' else 's')

data/app/assets/javascripts/evrobone/app-mixins/custom-element-binding.js.coffee

@@ -0,0 +1,33 @@
+Evrobone.AppMixins.CustomElementBinding =
+
+  customElementBindingInitialize: ->
+    @on 'start', @customElementBindingStart, @
+    return
+
+  customElementBindingStart: (initial) ->
+    @bindCustomElements null, initial
+    @performancePoint('Processed %count% custom element binder%s%', @customElementBinders.length) if @performanceReport
+    return
+
+  customElementBinders: []
+
+  registerCustomElementBinder: (binder) ->
+    @customElementBinders.push binder
+
+  bindCustomElements: ($root = $('body'), initial = false) ->
+    for binder in @customElementBinders
+      binder arguments...
+    return
+
+  registerEasyBinder: (name, handle) ->
+    if _.isArray(name)
+      [name, selector] = name
+    else
+      selector = ".js-#{name}"
+    @registerCustomElementBinder ($root, initial) ->
+      $elements = $root.find("#{selector}:not(.bound-#{name})")
+      $elements.addClass "bound-#{name}"
+      if $elements.length
+        handle $elements, initial
+      return
+    return

data/app/assets/javascripts/evrobone/app-mixins/views-management.js.coffee

@@ -0,0 +1,102 @@
+#= require ../view
+
+Evrobone.AppMixins.ViewsManagement =
+  View: Evrobone.View
+
+  ViewMixins: {}
+  ProtoViews: {}
+  Views: {}
+
+  warnOnMultibind: true
+  preventMultibind: false
+  groupBindingLog: true
+
+  viewInstances: null
+
+  viewsManagementInitialize: ->
+    @viewInstances = []
+    @on 'start', @viewsManagementStart, @
+    @on 'stop', @viewsManagementStop, @
+    return
+
+  viewsManagementStart: (initial) ->
+    boundViews = @bindViews()
+    @performancePoint('Bound %count% view%s%', boundViews.length) if @performanceReport
+    return
+
+  viewsManagementStop: (initial) ->
+    @unbindViews @viewInstances
+    return
+
+  bindViews: ($root = $('html'), checkRoot = true) ->
+    if @groupBindingLog
+      console?.groupCollapsed? 'bindViews on', $root
+    boundViews = []
+    sortedViews = _.sortBy(_.pairs(@Views), (p) -> -p[1].priority or 0)
+    for [viewName, viewClass] in sortedViews when viewClass::el
+      if checkRoot
+        @_bindViews boundViews, $root.filter(viewClass::el), viewClass, viewName
+      @_bindViews boundViews, $root.find(viewClass::el), viewClass, viewName
+    if @groupBindingLog
+      console?.groupEnd?()
+    boundViews
+
+  _bindViews: (boundViews, $elements, viewClass, viewName) ->
+    $elements.each (index, el) =>
+      if view = @bindView(el, viewClass, viewName)
+        boundViews.push view
+    return
+
+  bindView: (element, viewClass, viewName) ->
+    if @canBind(element, viewClass)
+      options = _.defaults( el: element, $(element).data() )
+      view = new viewClass(options)
+      if viewName
+        cout 'info', "Bound view #{viewName}:", view
+      @viewInstances.push view
+      view
+
+  canBind: (element, viewClass) ->
+    if @warnOnMultibind or @preventMultibind
+      views = @getViewsOnElement(element)
+      l = views.length
+      if l > 0
+        if @warnOnMultibind
+          cout 'warn', @_plurMessage('Element already has bound %count% view%s%', l), element, viewClass, views
+        not @preventMultibind
+      else
+        true
+    else
+      true
+
+  unbindViews: (views, context = null) ->
+    return unless views?.length > 0
+    for view in views
+      view.undelegateEvents()
+      view.leave context
+    @viewInstances = _.without(@viewInstances, views...)
+    cout 'info', @_plurMessage('Unbound %count% view%s%:', views.length), views
+    return
+
+  getViewsOnElement: (element) ->
+    element = if element instanceof jQuery then element[0] else element
+    _.where @viewInstances, el: element
+
+  getViewsInContainer: ($container, checkRoot = true) ->
+    _.filter @viewInstances, (view) ->
+      view.$el.closest($container).length > 0 and (checkRoot or view.el isnt $container[0])
+
+  getFirstView: (viewClass) ->
+    for view in @viewInstances
+      if view.constructor is viewClass
+        return view
+    null
+
+  getFirstChildView: (viewClass) ->
+    for view in @viewInstances
+      if view instanceof viewClass
+        return view
+    null
+
+  getAllViews: (viewClass) ->
+    _.filter(@viewInstances, (view) -> view.constructor is viewClass)

data/app/assets/javascripts/evrobone/app-mixins/window-navigation.js.coffee

@@ -0,0 +1,38 @@
+Evrobone.AppMixins.WindowNavigation =
+
+  changeLocation: (url, push = false) ->
+    #cout '!> changeLocation', url
+    historyMethod = window.history[if push then 'pushState' else 'replaceState']
+    if historyMethod
+      historyMethod.call window.history, { turbolinks: Turbolinks?, url: url }, '', url
+    else
+      window.location.hash = url
+    return
+
+  visit: (location) ->
+    #cout '!> visit', location
+    if Turbolinks?
+      Turbolinks.visit location
+    else
+      window.location = location
+    return
+
+  reloadPage: ->
+    #cout '!> reloadPage'
+    @visit window.location
+
+  refreshPage: ->
+    if Turbolinks?
+      $document = $(document)
+      scrollTop = 0
+      $document.once 'page:before-unload.refreshPage', =>
+        scrollTop = @$window.scrollTop()
+        return
+      $document.on 'page:load.refreshPage page:restore.refreshPage', =>
+        @$window.scrollTop scrollTop
+        return
+      Turbolinks.visit window.location
+    else
+      # TODO: сделать возврат scrollTop пробросом через sessionStorage
+      window.location = window.location
+    return

data/app/assets/javascripts/evrobone/app-mixins/window-refresh.js.coffee

@@ -0,0 +1,17 @@
+Evrobone.AppMixins.WindowRefresh =
+
+  windowRefreshEvents: ['DOMContentLoaded', 'load', 'scroll', 'resize', 'orientationchange', 'touchmove']
+  windowRefreshBound: false
+
+  _bindRefresh: ($scrollable, name) ->
+    @windowRefreshBound = true
+    events = _.map(@windowRefreshEvents, (e) -> "#{e}.#{name}-refresh").join(' ')
+    $scrollable.on events, => @trigger "#{name}Refresh", $scrollable.scrollTop(), $scrollable
+    return
+
+  onWindowRefresh: (callback, context) ->
+    @_bindRefresh(@$window, 'window') unless @windowRefreshBound
+    context.listenTo @, 'windowRefresh', callback
+
+  offWindowRefresh: (callback, context) ->
+    context.stopListening @, 'windowRefresh', callback

data/app/assets/javascripts/evrobone/helpers.js.coffee.erb

@@ -0,0 +1,60 @@
+window.DEBUG_MODE ?= <%= Rails.env.development? %>
+window.TEST_MODE ?= <%= Rails.env.test? %>
+window.LOG_TODO ?= DEBUG_MODE
+
+window.cout = =>
+  args = _.toArray(arguments)
+  method = if args[0] in ['log', 'info', 'warn', 'error', 'assert', 'clear'] then args.shift() else 'log'
+  if DEBUG_MODE and console?
+    method = console[method]
+    if method.apply?
+      method.apply(console, args)
+    else
+      method(args)
+  args[0]
+
+window._cout = ->
+  console.log(arguments)  if console?
+  arguments[0]
+
+window.todo = (subject, location = null, numberOrString = null) =>
+  if LOG_TODO
+    cout 'warn', "TODO: #{subject}#{if location then " ### #{location}" else ''}#{if numberOrString then (if _.isNumber(numberOrString) then ":#{numberOrString}" else " > #{numberOrString}") else ''}"
+
+window.getParams = (searchString = location.search) ->
+  q = searchString.replace(/^\?/, '').split('&')
+  r = {}
+  for e in q
+    t = e.split('=')
+    r[decodeURIComponent(t[0])] = decodeURIComponent(t[1])
+  r
+
+window.waitFor = (delay, times, check, success, fail) ->
+  startWaitFor = ->
+    setTimeout ( ->
+      times--
+      if check()
+        success?(times)
+      else if times > 0
+        startWaitFor()
+      else
+        fail?()
+    ), delay
+  startWaitFor()
+
+window.prepareFilterParams = (serializedArray) ->
+  filteredParams = _.filter(serializedArray, (param) -> param.name isnt 'utf8' and param.value isnt '')
+  params = []
+  names = []
+  for param in filteredParams
+    index = if /\[\]$/.test(param.name) then -1 else _.indexOf(names, param.name)
+    if index < 0
+      names.push param.name
+      params.push param
+    else
+      params[index] = param
+  params.sort (a, b) ->
+    if a.name is b.name
+      if a.value >= b.value then 1 else -1
+    else
+      if a.name > b.name then 1 else -1

data/app/assets/javascripts/evrobone/jquery-additions.js.coffee

@@ -0,0 +1,89 @@
+# coffeelint: disable=cyclomatic_complexity
+do ($ = jQuery) =>
+
+  $.fn.nearestFind = (selector, extremeEdgeSelector = 'form, body') ->
+    $edge = @
+    $result = $edge.find(selector)
+    until $result.length or $edge.is(extremeEdgeSelector)
+      $edge = $edge.parent()
+      $result = $edge.find(selector)
+    $result
+
+  # [showOrHide[, duration[, callback]]]
+  $.fn.slideToggleByState = ->
+    if @length
+      if arguments.length > 0
+        a = _.toArray(arguments)
+        if a.shift()
+          @slideDown.apply @, a
+        else
+          @slideUp.apply @, a
+      else
+        @slideToggle()
+    @
+
+  # http://css-tricks.com/snippets/jquery/mover-cursor-to-end-of-textarea/
+  $.fn.focusToEnd = ->
+    @each ->
+      $this = $(@)
+      val = $this.val()
+      $this.focus().val('').val val
+      return
+
+  $.regexp ||= {}
+
+  $.regexp.rorId ||= /(\w+)_(\d+)$/
+
+  @ror_id = ($elementOrString) ->
+    if $elementOrString instanceof jQuery
+      id = $elementOrString.data('rorId')
+      unless id?
+        id = ror_id($elementOrString.attr('id'))
+        $elementOrString.data('rorId', id)  if id?
+      id
+    else if _.isString($elementOrString)
+      matchResult = $elementOrString.match($.regexp.rorId)
+      if matchResult then parseInt(matchResult[2]) else null
+    else
+      null
+
+  $.fn.rorId = (id = null, prefix = null) ->
+    if arguments.length
+      $element = @first()
+      elementId = @attr('id')
+      if not prefix? and _.isString(elementId)
+        prefix = matchResult[1]  if matchResult = elementId.match($.regexp.rorId)
+      @data('rorId', id)
+      if prefix?
+        $element.attr 'id', "#{prefix}_#{id}"
+      $element
+    else
+      ror_id @
+
+  $.fn.getFileName = ->
+    fileName = @val()
+    if matches = fileName.match(/(.+\\)?(.+)$/)
+      fileName = matches[2] or fileName
+    fileName
+
+  $.fn.$each = (callback) ->
+    @each (index, element) ->
+      callback $(element)
+
+  $.fn.closestScrollable = ->
+    $(_.find(@parents().get(), (p) -> $(p).css('overflowY') is 'auto') or window)
+
+# RESEARCH
+#  $.fn.blockHide = ->
+#    @each -> jQuery._data @, 'olddisplay', 'block'
+#    @css 'display', 'none'
+#    @
+
+  $.getCachedScript = (url, callback) ->
+    $.ajax
+      type: 'GET'
+      url: url
+      success: callback
+      dataType: 'script'
+      cache: true
+# coffeelint: enable=cyclomatic_complexity

data/app/assets/javascripts/evrobone/lib/jquery.ui.effect-stacked-drop.js.coffee

@@ -0,0 +1,50 @@
+# jQuery UI Effects Stacked Drop   based on   jQuery UI Effects Drop 1.10.0
+#= require jquery-ui/effect
+
+# coffeelint: disable=cyclomatic_complexity
+do ($ = jQuery) ->
+
+  $.effects.effect.stackedDrop = (o, done) ->
+    el = $(@)
+    props = ['position', 'top', 'bottom', 'left', 'right', 'opacity', 'height', 'width']
+    mode = $.effects.setMode(el, o.mode or 'hide')
+    show = mode is 'show'
+    direction = o.direction or 'left'
+    ref = if (direction is 'up' or direction is 'down') then 'top' else 'left'
+    motion = if (direction is 'up' or direction is 'left') then 'pos' else 'neg'
+    animation = opacity: (if show then 1 else 0)
+
+    # Adjust
+    $.effects.save el, props
+    el.show()
+    $.effects.createWrapper el
+    distance = o.distance or el[(if ref is 'top' then 'outerHeight' else 'outerWidth')](true) / 2
+    el.css('opacity', 0).css ref, (if motion is 'pos' then -distance else distance)  if show
+
+    # Animation
+    animationValue = if show then (if motion is 'pos' then '+=' else '-=') else (if motion is 'pos' then '-=' else '+=')
+    animation[ref] = animationValue + distance
+
+    _complete = ->
+      $.effects.restore el, props
+      $.effects.removeWrapper el
+      done()
+
+    # Animate
+    el.animate animation,
+      queue: false
+      duration: o.duration
+      easing: o.easing
+      complete: ->
+        if mode is 'hide'
+          el.hide()
+          wrapper = el.parent('.ui-effects-wrapper')
+          if wrapper.length
+            wrapper.slideUp
+              duration: o.duration
+              easing: o.easing
+              complete: _complete
+        else
+          _complete()
+  undefined
+# coffeelint: enable=cyclomatic_complexity

data/app/assets/javascripts/evrobone/lib/livereload-plugin-rails.js.coffee

@@ -0,0 +1,75 @@
+class @LiveReloadPluginRails
+  @identifier = 'rails'
+  @version = '1.0'
+
+  window: null
+  host: null
+  document: null
+  console: null
+
+  constructor: (@window, @host) ->
+    @document = @host._reloader.document
+    @console = @host._reloader.console
+    return
+
+  debounced: null
+
+  reload: (path, options) ->
+    # в path бывает полный путь до руби файла или имя файла последнего звена пайплайна
+    # в options.originalPath же бывает бывает полный путь до файла первого звена пайплайна
+    #cout 'reload', path, options
+    if /\.css_scsslint_tmp\d+\.css$/.test(path)
+      true
+    else if /\.css$/i.test(path)
+      @reloadStylesheet(path)
+    else if App?.refreshPage? and ( /\.(rb|html)$/i.test(path) or /\.haml$/i.test(options.originalPath) )
+      @debounced ||= _.debounce(( -> App.refreshPage() ), 300)
+      @debounced()
+      true
+    else
+      false
+
+  reloadStylesheet: (path) ->
+    # has to be a real array, because DOMNodeList will be modified
+    # coffeelint: disable=max_line_length
+    links = (link for link in @document.getElementsByTagName('link') when link.rel.match(/^stylesheet$/i) and not link.__LiveReload_pendingRemoval)
+    # coffeelint: enable=max_line_length
+    # handle prefixfree
+    if @window.StyleFix and @document.querySelectorAll
+      for style in @document.querySelectorAll('style[data-href]')
+        links.push style
+    @console.log "!!! LiveReload found #{links.length} LINKed stylesheets"
+    pathRX = new RegExp(path.replace(/\.css$/, '(\\.self)?(-[\\da-f]{32,64})?\\.css$'))
+    links = (link for link in links when pathRX.test(pathFromUrl(@host._reloader.linkHref(link))))
+    @console.log "!!! Detected #{links.length} LINKed stylesheets for path: #{path}"
+    if links.length
+      for link in links
+        @host._reloader.reattachStylesheetLink(link)
+      true
+    else
+      false
+
+
+
+splitUrl = (url) ->
+  if (index = url.indexOf('#')) >= 0
+    hash = url.slice(index)
+    url = url.slice(0, index)
+  else
+    hash = ''
+  if (index = url.indexOf('?')) >= 0
+    params = url.slice(index)
+    url = url.slice(0, index)
+  else
+    params = ''
+  return { url, params, hash }
+
+pathFromUrl = (url) ->
+  url = splitUrl(url).url
+  if url.indexOf('file://') is 0
+    path = url.replace ///^ file:// (localhost)? ///, ''
+  else
+    #                        http  :   // hostname  :8080  /
+    path = url.replace ///^ ([^:]+ :)? // ([^:/]+) (:\d*)? / ///, '/'
+  # decodeURI has special handling of stuff like semicolons, so use decodeURIComponent
+  return decodeURIComponent(path)

data/app/assets/javascripts/evrobone/view.js.coffee

@@ -0,0 +1,63 @@
+@Evrobone ||= {}
+
+delegateEventSplitter = /^(\S+)\s*(.*)$/
+
+class Evrobone.View extends Backbone.View
+
+  @mixinNames: null
+
+  constructor: (options) ->
+    @reflectOptions options
+    super
+
+  reflectOptions: (options = @$el.data()) ->
+    @[attr] = value  for attr, value of options  when not _.isUndefined(@[attr])
+    @
+
+  # Rest mixinNames
+  @mixinable: ->
+    @mixinNames = if @mixinNames then _.clone(@mixinNames) else []
+
+  # Mixins support
+  @include: (mixin, name = null) ->
+    @mixinNames ||= []
+    if name?
+      @mixinNames = _.without(@mixinNames, name)
+      @mixinNames.push(name)
+    unless mixin?
+      cout 'error', "ViewMixin #{name or '_no_name_'} is undefined"
+    _.extend @::, mixin
+
+  mixinsEvents: (events = {}) ->
+    _.reduce( @constructor.mixinNames, ( (memo, name) -> _.extend(memo, _.result(@, name + 'Events')) ), events, @ )
+
+  mixinsInitialize: ->
+    for name in @constructor.mixinNames
+      @[name + 'Initialize']? arguments...
+    return
+
+  mixinsLeave: ->
+    if @constructor.mixinNames
+      for name in @constructor.mixinNames
+        @[name + 'Leave']? arguments...
+    return
+
+  leave: ->
+    @mixinsLeave()
+    @stopListening()
+    return
+
+  destroy: (destroyDOM = true) =>
+    App.unbindViews [@]
+    @$el.remove() if destroyDOM
+    return
+
+  # TODO: see https://github.com/jashkenas/backbone/pull/3003/files
+  delegateEvents: (events) ->
+    return super unless App.touchDevice
+    return @ unless events or events = _.result(@, 'events')
+    patchedEvents = {}
+    for key, method of events
+      [[], eventName, selector] = key.match(delegateEventSplitter)
+      patchedEvents[if eventName is 'click' then "touchend #{selector}" else key] = method
+    super patchedEvents

data/bin/console

@@ -0,0 +1,14 @@
+#!/usr/bin/env ruby
+
+require 'bundler/setup'
+require 'evrobone'
+
+# You can add fixtures and/or initialization code here to make experimenting
+# with your gem easier. You can also use a different console, if you like.
+
+# (If you use this, don't forget to add pry to your Gemfile!)
+# require 'pry'
+# Pry.start
+
+require 'irb'
+IRB.start

data/bin/setup

@@ -0,0 +1,7 @@
+#!/bin/bash
+set -euo pipefail
+IFS=$'\n\t'
+
+bundle install
+
+# Do any other automated setup that you need to do here

data/coffeelint.json

@@ -0,0 +1,129 @@
+{
+  "arrow_spacing": {
+    "level": "error"
+  },
+  "braces_spacing": {
+    "level": "warn",
+    "spaces": 1,
+    "empty_object_spaces": 0
+  },
+  "camel_case_classes": {
+    "level": "error"
+  },
+  "coffeescript_error": {
+    "level": "error"
+  },
+  "colon_assignment_spacing": {
+    "level": "ignore",
+    "spacing": {
+      "left": 0,
+      "right": 1
+    }
+  },
+  "cyclomatic_complexity": {
+    "value": 10,
+    "level": "warn"
+  },
+  "duplicate_key": {
+    "level": "error"
+  },
+  "empty_constructor_needs_parens": {
+    "level": "warn"
+  },
+  "ensure_comprehensions": {
+    "level": "warn"
+  },
+  "eol_last": {
+    "level": "warn"
+  },
+  "indentation": {
+    "value": 2,
+    "level": "error"
+  },
+  "line_endings": {
+    "level": "warn",
+    "value": "unix"
+  },
+  "max_line_length": {
+    "value": 120,
+    "level": "error",
+    "limitComments": true
+  },
+  "missing_fat_arrows": {
+    "level": "ignore",
+    "is_strict": false
+  },
+  "newlines_after_classes": {
+    "value": 3,
+    "level": "warn"
+  },
+  "no_backticks": {
+    "level": "error"
+  },
+  "no_debugger": {
+    "level": "warn",
+    "console": false
+  },
+  "no_empty_functions": {
+    "level": "warn"
+  },
+  "no_empty_param_list": {
+    "level": "warn"
+  },
+  "no_implicit_braces": {
+    "level": "ignore",
+    "strict": true
+  },
+  "no_implicit_parens": {
+    "strict": true,
+    "level": "ignore"
+  },
+  "no_interpolation_in_single_quotes": {
+    "level": "warn"
+  },
+  "no_plusplus": {
+    "level": "warn"
+  },
+  "no_stand_alone_at": {
+    "level": "ignore"
+  },
+  "no_tabs": {
+    "level": "error"
+  },
+  "no_this": {
+    "level": "warn"
+  },
+  "no_throwing_strings": {
+    "level": "error"
+  },
+  "no_trailing_semicolons": {
+    "level": "error"
+  },
+  "no_trailing_whitespace": {
+    "level": "error",
+    "allowed_in_comments": false,
+    "allowed_in_empty_lines": true
+  },
+  "no_unnecessary_double_quotes": {
+    "level": "warn"
+  },
+  "no_unnecessary_fat_arrows": {
+    "level": "warn"
+  },
+  "non_empty_constructor_needs_parens": {
+    "level": "warn"
+  },
+  "prefer_english_operator": {
+    "level": "warn",
+    "doubleNotLevel": "warn"
+  },
+  "space_operators": {
+    "level": "warn"
+  },
+  "spacing_after_comma": {
+    "level": "warn"
+  },
+  "transform_messes_up_line_numbers": {
+    "level": "warn"
+  }
+}

data/evrobone.gemspec

@@ -0,0 +1,25 @@
+lib = File.expand_path('../lib', __FILE__)
+$LOAD_PATH.unshift(lib) unless $LOAD_PATH.include?(lib)
+require 'evrobone/version'
+
+Gem::Specification.new do |spec|
+  spec.name          = 'evrobone'
+  spec.version       = Evrobone::VERSION
+  spec.authors       = ['Dmitry KODer Karpunin']
+  spec.email         = ['koderfunk@gmail.com']
+
+  spec.summary       = 'Light-weight client-side framework based on Backbone.js for Ruby on Rails Front-end'
+  spec.description   = 'Light-weight client-side framework based on Backbone.js for Ruby on Rails Front-end'
+  spec.homepage      = 'http://github.com/KODerFunk/evrobone'
+  spec.license       = 'MIT'
+
+  spec.files         = `git ls-files -z`.split("\x0").reject { |f| f.match(%r{^(test|spec|features)/}) }
+  spec.bindir        = 'exe'
+  spec.executables   = spec.files.grep(%r{^exe/}) { |f| File.basename(f) }
+  spec.require_paths = ['lib']
+
+  spec.add_development_dependency 'bundler', '~> 1.10'
+  spec.add_development_dependency 'rake', '~> 10.0'
+  spec.add_development_dependency 'rubocop'
+  spec.add_development_dependency 'coffeelint'
+end

data/lib/evrobone.rb

@@ -0,0 +1,9 @@
+require 'evrobone/version'
+
+module Evrobone
+  if defined?(Rails)
+    class Engine < ::Rails::Engine
+      # Rails -> use app/assets directory.
+    end
+  end
+end

data/lib/evrobone/version.rb

@@ -0,0 +1,3 @@
+module Evrobone
+  VERSION = '0.1.0'
+end

metadata

@@ -0,0 +1,127 @@
+--- !ruby/object:Gem::Specification
+name: evrobone
+version: !ruby/object:Gem::Version
+  version: 0.1.0
+platform: ruby
+authors:
+- Dmitry KODer Karpunin
+autorequire: 
+bindir: exe
+cert_chain: []
+date: 2015-09-10 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: bundler
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - "~>"
+      - !ruby/object:Gem::Version
+        version: '1.10'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - "~>"
+      - !ruby/object:Gem::Version
+        version: '1.10'
+- !ruby/object:Gem::Dependency
+  name: rake
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - "~>"
+      - !ruby/object:Gem::Version
+        version: '10.0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - "~>"
+      - !ruby/object:Gem::Version
+        version: '10.0'
+- !ruby/object:Gem::Dependency
+  name: rubocop
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - ">="
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - ">="
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: coffeelint
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - ">="
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - ">="
+      - !ruby/object:Gem::Version
+        version: '0'
+description: Light-weight client-side framework based on Backbone.js for Ruby on Rails
+  Front-end
+email:
+- koderfunk@gmail.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- ".gitignore"
+- ".rubocop.yml"
+- ".travis.yml"
+- Gemfile
+- LICENSE.txt
+- README.md
+- Rakefile
+- app/assets/javascripts/evrobone/app-class.js.coffee
+- app/assets/javascripts/evrobone/app-mixins/custom-element-binding.js.coffee
+- app/assets/javascripts/evrobone/app-mixins/views-management.js.coffee
+- app/assets/javascripts/evrobone/app-mixins/window-navigation.js.coffee
+- app/assets/javascripts/evrobone/app-mixins/window-refresh.js.coffee
+- app/assets/javascripts/evrobone/helpers.js.coffee.erb
+- app/assets/javascripts/evrobone/initializers/.keep
+- app/assets/javascripts/evrobone/jquery-additions.js.coffee
+- app/assets/javascripts/evrobone/lib/jquery.ui.effect-stacked-drop.js.coffee
+- app/assets/javascripts/evrobone/lib/livereload-plugin-rails.js.coffee
+- app/assets/javascripts/evrobone/view.js.coffee
+- app/assets/javascripts/evrobone/views/.keep
+- bin/console
+- bin/setup
+- coffeelint.json
+- evrobone.gemspec
+- lib/evrobone.rb
+- lib/evrobone/version.rb
+homepage: http://github.com/KODerFunk/evrobone
+licenses:
+- MIT
+metadata: {}
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - ">="
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - ">="
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 2.4.8
+signing_key: 
+specification_version: 4
+summary: Light-weight client-side framework based on Backbone.js for Ruby on Rails
+  Front-end
+test_files: []