card-mod-format 0.14.2 → 0.15.0

checksums.yaml

@@ -1,7 +1,7 @@
 ---
 SHA256:
-  metadata.gz: 033c1838261484c659a9c3508ec505e77adf55e7c86e44aa7634d6b5a516f4f4
-  data.tar.gz: 95976aff533ba8d7a7f05f719e5a5322e5ddc1948f9af2bfc829451bad50112c
+  metadata.gz: a4831b05c3fabaa2fe6df1b4a0a7d4a548a89344fc174322e6afc98cdbed3c39
+  data.tar.gz: defeae8ec613a2044f7c1af895607f8f2718e5f5ed37972283f2eaa6f1f7eed0
 SHA512:
-  metadata.gz: 4a2b0fc9f5bc4283b178165c44a0f0a4764ecd70f77eca605e2a50912e2d219bf9d1f02b84e1557b86c629979c80ead223ee1950af30f048facd583c08711194
-  data.tar.gz: 4cf2c9bc444e64980a035c14bcd414ee3718fa39b4c075687d488dccea7c28e17e81ee862c7528b0a31df32d2151bd0b54b290de6c7827efe3f9738002e6381c
+  metadata.gz: 35cb14e6738063019f3dda1925be996524b966de600a418f09d0685a4c067b94aba1e1d03dc320fe6c77c389acee0d6bc469c6a2ceb3d5a68caad50790726d0e
+  data.tar.gz: 950d8600fb84f203b40252d1481306733f8112c96b06a281d31d5fa45f1aa00fda5f5646a72f201085e13b781db59b0f5011801fb569863a4bd5ee0e62e2e1d6

data/assets/script/decko/clicks_and_hovers.js.coffee

@@ -0,0 +1,49 @@
+$(window).ready ->
+  $('body').on 'click', '.submitter', ->
+    $(this).closest('form').submit()
+
+  $('body').on 'click', 'button.redirecter', ->
+    window.location = $(this).attr('href')
+
+  $('body').on 'click', '.render-error-link', (event) ->
+    msg = $(this).closest('.render-error').find '.render-error-message'
+    msg.show()
+    #    msg.dialog()
+    event.preventDefault()
+
+  $(document).on 'click', '._stop_propagation', (event)->
+    event.stopPropagation()
+
+  $("body").on 'click', '._prevent_default', (event)->
+    event.preventDefault()
+
+  $('body').on 'mouseenter', 'a[data-hover-text]', ->
+    text = $(this).text()
+    $(this).data("original-text", text)
+    $(this).text($(this).data("hover-text"))
+
+  $('body').on 'mouseleave', 'a[data-hover-text]', ->
+    $(this).text($(this).data("original-text"))
+
+  $('body').on 'mouseenter', '[hover_content]', ->
+    $(this).attr 'hover_restore', $(this).html()
+    $(this).html $(this).attr( 'hover_content' )
+
+  $('body').on 'mouseleave', '[hover_content]', ->
+    $(this).html $(this).attr( 'hover_restore' )
+
+decko.slot.ready (slot) ->
+  if isTouchDevice()
+    slot.find('._show-on-hover').removeClass('_show-on-hover')
+
+isTouchDevice = ->
+  if 'ontouchstart' of window or window.DocumentTouch and
+      document instanceof DocumentTouch
+    true
+  else
+    detectMobileBrowser()
+
+# source for this method: detectmobilebrowsers.com
+detectMobileBrowser = (userAgent) ->
+  userAgent = navigator.userAgent or navigator.vendor or window.opera
+  /(android|bb\d+|meego).+mobile|avantgo|bada\/|blackberry|blazer|compal|elaine|fennec|hiptop|iemobile|ip(hone|od)|iris|kindle|lge |maemo|midp|mmp|mobile.+firefox|netfront|opera m(ob|in)i|palm( os)?|phone|p(ixi|re)\/|plucker|pocket|psp|series(4|6)0|symbian|treo|up\.(browser|link)|vodafone|wap|windows ce|xda|xiino/i.test(userAgent) or /1207|6310|6590|3gso|4thp|50[1-6]i|770s|802s|a wa|abac|ac(er|oo|s\-)|ai(ko|rn)|al(av|ca|co)|amoi|an(ex|ny|yw)|aptu|ar(ch|go)|as(te|us)|attw|au(di|\-m|r |s )|avan|be(ck|ll|nq)|bi(lb|rd)|bl(ac|az)|br(e|v)w|bumb|bw\-(n|u)|c55\/|capi|ccwa|cdm\-|cell|chtm|cldc|cmd\-|co(mp|nd)|craw|da(it|ll|ng)|dbte|dc\-s|devi|dica|dmob|do(c|p)o|ds(12|\-d)|el(49|ai)|em(l2|ul)|er(ic|k0)|esl8|ez([4-7]0|os|wa|ze)|fetc|fly(\-|_)|g1 u|g560|gene|gf\-5|g\-mo|go(\.w|od)|gr(ad|un)|haie|hcit|hd\-(m|p|t)|hei\-|hi(pt|ta)|hp( i|ip)|hs\-c|ht(c(\-| |_|a|g|p|s|t)|tp)|hu(aw|tc)|i\-(20|go|ma)|i230|iac( |\-|\/)|ibro|idea|ig01|ikom|im1k|inno|ipaq|iris|ja(t|v)a|jbro|jemu|jigs|kddi|keji|kgt( |\/)|klon|kpt |kwc\-|kyo(c|k)|le(no|xi)|lg( g|\/(k|l|u)|50|54|\-[a-w])|libw|lynx|m1\-w|m3ga|m50\/|ma(te|ui|xo)|mc(01|21|ca)|m\-cr|me(rc|ri)|mi(o8|oa|ts)|mmef|mo(01|02|bi|de|do|t(\-| |o|v)|zz)|mt(50|p1|v )|mwbp|mywa|n10[0-2]|n20[2-3]|n30(0|2)|n50(0|2|5)|n7(0(0|1)|10)|ne((c|m)\-|on|tf|wf|wg|wt)|nok(6|i)|nzph|o2im|op(ti|wv)|oran|owg1|p800|pan(a|d|t)|pdxg|pg(13|\-([1-8]|c))|phil|pire|pl(ay|uc)|pn\-2|po(ck|rt|se)|prox|psio|pt\-g|qa\-a|qc(07|12|21|32|60|\-[2-7]|i\-)|qtek|r380|r600|raks|rim9|ro(ve|zo)|s55\/|sa(ge|ma|mm|ms|ny|va)|sc(01|h\-|oo|p\-)|sdk\/|se(c(\-|0|1)|47|mc|nd|ri)|sgh\-|shar|sie(\-|m)|sk\-0|sl(45|id)|sm(al|ar|b3|it|t5)|so(ft|ny)|sp(01|h\-|v\-|v )|sy(01|mb)|t2(18|50)|t6(00|10|18)|ta(gt|lk)|tcl\-|tdg\-|tel(i|m)|tim\-|t\-mo|to(pl|sh)|ts(70|m\-|m3|m5)|tx\-9|up(\.b|g1|si)|utst|v400|v750|veri|vi(rg|te)|vk(40|5[0-3]|\-v)|vm40|voda|vulc|vx(52|53|60|61|70|80|81|83|85|98)|w3c(\-| )|webc|whit|wi(g |nc|nw)|wmlb|wonu|x700|yas\-|your|zeto|zte\-/i.test(userAgent.substr(0, 4))

data/assets/script/decko/decko.js.coffee

@@ -0,0 +1,32 @@
+window.decko =
+  rootUrl: "" # overwritten in inline script in head
+
+  # returns absolute path (starting with a slash)
+  # if rawPath is complete url, this returns the complete url
+  # if rawPath is relative (no slash), this adds relative root
+  path: (rawPath) ->
+    if rawPath.match /^\/|:\/\//
+      rawPath
+    else
+      decko.rootUrl + rawPath
+
+  editors:
+    init: {}
+    content: {}
+    add: (selector, initf, contentf)->
+      decko.editors.init[selector] = initf
+      decko.editors.content[selector] = contentf
+
+  warn: (stuff) -> console.log stuff if console?
+
+  snakeCase: (str)->
+    str.replace /([a-z])([A-Z])/g, (match) -> match[0] + '_' +
+      match[1].toLowerCase()
+
+
+#~~~~~ ( EVENTS )
+
+$(window).ready ->
+  $.ajaxSetup cache: false
+
+

data/assets/script/decko/decko_jquery.js.coffee

@@ -0,0 +1,25 @@
+jQuery.fn.extend
+  findCard: (id) -> @find("[data-card-id='" + id + "']")
+
+  isMain: -> @slot().parent('#main')[0]
+
+  cardMark: ->
+    if @data('cardId') then "~#{@data('cardId')}" else @data("cardName")
+
+  isMainOrMainModal: ->
+    el = $(this)
+    el = el.slotOrigin("modal") if el.closest(".modal")[0]
+    el && el.isMain()
+
+  notify: (message, status) ->
+    slot = @slot(status)
+    notice = slot.find '.card-notice'
+    unless notice[0]
+      notice = $('<div class="card-notice"></div>')
+      form = slot.find('.card-form')
+      if form[0]
+        $(form[0]).append notice
+      else
+        slot.append notice
+    notice.html message
+    notice.show 'blind'

data/assets/script/decko/slot.js.coffee

@@ -0,0 +1,150 @@
+decko.slot =
+  # returns full path with slot parameters
+  path: (path, slot)->
+    params = slotPathParams slot
+    decko.path(path) + ( (if path.match /\?/ then '&' else '?') + $.param(params) )
+
+  ready: (func)->
+    $('document').ready ->
+      $('body').on 'decko.slot.ready', '.card-slot', (e, slotter) ->
+        e.stopPropagation()
+        if slotter?
+          func.call this, $(this), $(slotter)
+        else
+          func.call this, $(this)
+
+  destroy: (func)->
+    $('document').ready ->
+      $('body').on 'decko.slot.destroy', '.card-slot, ._modal-slot', (e) ->
+        e.stopPropagation()
+        func.call this, $(this)
+
+
+jQuery.fn.extend
+  isSlot: -> $(this).hasClass "card-slot"
+
+  triggerSlotReady: (slotter) ->
+    @trigger "decko.slot.ready", slotter if @isSlot()
+    @find(".card-slot").trigger "decko.slot.ready", slotter
+
+  slot: (status="success", mode="replace") ->
+    return @modalSlot() if mode == "modal"
+
+    @_slotSelect("slot-#{status}-selector") ||
+      @_slotSelect("slot-selector") ||
+      @closest(".card-slot")
+
+  slotUrl: ->
+    slot = $(this)
+    decko.slot.path "#{slot.cardMark()}/#{slot.data("slot")["view"]}"
+
+  slotFind: (selector) ->
+    switch selector
+      when "modal-origin"   then @slotOrigin "modal"
+      when "overlay-origin" then @slotOrigin "overlay"
+      else slotScour @closest(selector), @closest(".card-slot"), selector
+
+  slotClear: () ->
+    @trigger "decko.slot.destroy"
+    @empty()
+
+  # type can be "modal" or "overlay"
+  slotOrigin: (type) ->
+    overlaySlot = @closest("[data-#{type}-origin-slot-id]")
+    origin_slot_id = overlaySlot.data("#{type}-origin-slot-id")
+    origin_slot = $("[data-slot-id=#{origin_slot_id}]")
+    if origin_slot[0]?
+      origin_slot
+    else
+      decko.warn "couldn't find origin with slot id #{origin_slot_id}"
+
+  slotReload: (url) ->
+    @each -> $(this)._slotReloadSingle url
+
+  slotUpdate: (newContent, mode) ->
+    mode ||= "replace"
+    @slotContent newContent, mode, $(this)
+
+  slotContent: (newContent, mode, $slotter) ->
+    v = $(newContent)[0] && $(newContent) || newContent
+
+    if typeof(v) == "string"
+      # Needed to support "TEXT: result" pattern in success (eg deleting nested cards)
+      @slot("success", mode)._slotFillOrReplace v, $slotter
+    else
+      if v.hasClass("_overlay")
+        mode = "overlay"
+      else if v.hasClass("_modal")
+        mode = "modal"
+      @slot("success", mode)._slotContentFromElement v, mode, $slotter
+    v
+
+  _slotContentFromElement: (el, mode, $slotter) ->
+    if mode == "overlay"
+      @addOverlay(el, $slotter)
+    else if el.hasClass("_modal-slot") or mode == "modal"
+      el.showAsModal($slotter)
+    else
+      slot_id = @data("slot-id")
+      el.attr("data-slot-id", slot_id) if slot_id
+      @trigger "decko.slot.destroy"
+      @_slotFillOrReplace el, $slotter
+      decko.contentLoaded(el, $slotter)
+
+  _slotFillOrReplace: (content, $slotter) ->
+    if @hasClass("_fixed-slot")
+      @html content
+    else
+      @replaceWith content
+    decko.contentLoaded(this, $slotter)
+
+  _slotSelect: (selectorName) ->
+    if selector = @data(selectorName)
+      slot = @slotFind selector
+      slot && slot[0] && slot
+
+  _slotReloadSingle: (url) ->
+    $slot = $(this)
+    url = $slot.slotUrl() unless url?
+    $slot.addClass 'slotter'
+    $slot.data "url", url
+    $slot.data "remote", true
+    $slot.attr 'href', url
+    this[0].href = url
+    # that's where handleRemote gets the url from
+    # .attr(href, url) only works for anchors
+    $.rails.handleRemote $slot
+
+# ~~~~~~~~~~~~~~~~~~~~~~~~
+# "private" helper methods
+
+slotPathParams = (slot) ->
+  params = {}
+  main = $('#main').children('.card-slot').data 'cardName'
+  params['main'] = main if main?
+
+  if slot
+    params['is_main'] = true if slot.isMain()
+    slotdata = slot.data 'slot'
+    if slotdata?
+      slotParams slotdata, params, 'slot'
+      params['type'] = slotdata['type'] if slotdata['type']
+  params
+
+slotParams = (raw, processed, prefix)->
+  $.each raw, (key, value)->
+    cgiKey = prefix + '[' + decko.snakeCase(key) + ']'
+    if key == 'items'
+      slotParams value, processed, cgiKey
+    else
+      processed[cgiKey] = value
+
+slotScour = (target_slot, parent_slot, selector) ->
+  # if slot-selector doesn't apply to a child, search in all parent slots and finally in the body
+  while target_slot.length == 0 and parent_slot.length > 0
+    target_slot = $(parent_slot).find(selector)
+    parent_slot = $(parent_slot).parent().closest '.card-slot'
+  if target_slot.length == 0
+    $(selector)
+  else
+    target_slot

data/assets/script/decko/slot_ready.js.coffee

@@ -0,0 +1,11 @@
+decko.slot.ready (slot) ->
+  slot.find('card-view-placeholder').each ->
+    $place = $(this)
+    return if $place.data("loading")
+
+    $place.data "loading", true
+    $.get $place.data("url"), (data, _status) ->
+      $place.replaceWith data
+
+  slot.find('._disappear').delay(5000).animate(
+    height: 0, 1000, -> $(this).hide())

data/assets/script/decko/slotter.js.coffee

@@ -0,0 +1,208 @@
+# There are three places that can control what happens after an ajax request
+#  1. the element that triggered the request (eg. a link or a button)
+#  2. the closest ".slotter" element
+#      (if the trigger itself isn't a slotter,
+#       a common example is that a form is a slotter but the form buttons aren't)
+#  3. the slot returned by the request
+#
+# A slot is an element marked with "card-slot" class, a slotter has a "slotter" class.
+# By the default, the closest slot of the slotter is replaced with the new slot that the
+# request returned. The behavior can be changed with css classes and data attributes.
+#
+#  To 1. The trigger element has only a few options to override the slotter.
+#    classes:
+#    "_close-modal-on-success"
+#    "_close-overlay-on-success"
+#    "_update-origin"
+#
+#  To 2. The slotter is the standard way to define what happens with request result
+#    data:
+#    slot-selector
+#        a css selector that defines which slot will be replaced.
+#        You can also use "modal-origin" and "overlay-origin" to refer to the origin slots.
+#    slot-success-selector/slot-error-selector
+#        the same as slot-selector but only used
+#        for success case or error case, respectively
+#    update-foreign-slot
+#        a css selector to specify an additional slot that will be
+#        updated after the request.
+#    update-foreign-slot-url
+#        a url to fetch the new content for the additional slot
+#        if not given the slot is updated with the same card and view that was used before
+#    update-origin
+#        if present then the slot from where the current modal or overlay slot was opened
+#        will be updated
+#    slotter-mode
+#        possible values are
+#          replace (default)
+#             replace the closest slot with new slot
+#          modal
+#             show new slot in modal; if there is already a modal then put it on top
+#          modal-replace
+#             replace existing modal
+#          overlay
+#             show new slot in overlay
+#          update-origin
+#             update closest slot of the slotter that opened the modal or overlay
+#             (assumes that the request was triggered from a modal or overlay)
+#             If you need the update-origin mode together with another mode then use
+#             data-update-origin="true".
+#          silent-success
+#             do nothing
+#
+#    classes:
+#    _close-overlay
+#    _close-modal
+#
+#   To 3. Similar as 1, the slot has only overlay and modal options.
+#     classes:
+#     _modal
+#        show slot in modal
+#     _overlay
+#        show slot in overlay
+#
+#
+$(window).ready ->
+  $('body').on 'ajax:success', '.slotter', (event, data) ->
+    $(this).slotterSuccess event, data
+
+  $('body').on 'ajax:error', '.slotter', (event, xhr) ->
+    $(this).showErrorResponse xhr.status, xhr.responseText
+
+  $('body').on 'click', 'button.slotter', ->
+    return false if !$.rails.allowAction $(this)
+    $.rails.handleRemote $(this)
+
+#  $('body').on 'click', '._clickable.slotter', (event)->
+#    $(this)[0].href = $(this).attr("href") # that's where rails.handleRemote
+#                                           # expects the url
+#    $.rails.handleRemote $(this)
+
+  $('body').on 'click', '[data-bs-dismiss="overlay"]', ->
+    $(this).slotFind(".card-slot._overlay").removeOverlay()
+
+  $('body').on 'click', '._close-overlay-on-success', ->
+    $(this).closeOnSuccess("overlay")
+
+  $('body').on 'click', '._close-modal-on-success', ->
+    $(this).closeOnSuccess("modal")
+
+  $('body').on 'click', '._close-on-success', ->
+    $(this).closeOnSuccess()
+
+  $('body').on 'click', '._update-origin', ->
+    $(this).closest('.slotter').data("slotter-mode", "update-origin")
+
+  $('body').on 'submit', 'form.slotter', ->
+    form = $(this)
+    if form.data("main-success") and form.isMainOrMainModal()
+      form.mainSuccess()
+
+  $('body').on 'ajax:beforeSend', '.slotter', (event, xhr, opt)->
+    $(this).slotterBeforeSend opt
+
+jQuery.fn.extend
+  mainSuccess: ()->
+    form = $(this)
+    $.each form.data("main-success"), (key, value)->
+      inputSelector = "[name=success\\[" + key + "\\]]"
+      input = form.find inputSelector
+      unless input[0]
+        input = $('<input type="hidden" name="success[' + key + ']"/>')
+        form.append input
+      input.val value
+
+  slotterSuccess: (event, responseData) ->
+    unless @hasClass("slotter")
+      console.log "warning: slotterSuccess called on non-slotter element #{this}"
+      return
+
+    return if event.slotSuccessful
+
+    @showSuccessResponse responseData, @data("slotter-mode")
+
+    if @hasClass "_close-overlay"
+      @removeOverlay()
+    if @hasClass "_close-modal"
+      @closest('.modal').modal "hide"
+
+    # should scroll to top after clicking on new page
+    if @hasClass "card-paging-link"
+      slot_top_pos = @slot().offset().top
+      $("body").scrollTop slot_top_pos
+    if @data("update-foreign-slot")
+      $slot = @slotFind @data("update-foreign-slot")
+      reload_url = @data("update-foreign-slot-url")
+      $slot.slotReload reload_url
+
+    if @data('original-slotter-mode')
+      @attr 'data-slotter-mode', @data('original-slotter-mode')
+    if @data('original-slot-selector')
+      @attr 'data-slot-selector', @data('original-slot-selector')
+
+    event.slotSuccessful = true
+
+  showSuccessResponse: (responseData, mode) ->
+    if responseData.redirect
+      window.location = responseData.redirect
+    else if responseData.reload
+      window.location.reload(true)
+    else
+      switch mode
+        when "silent-success" then return
+        when "update-modal-origin" then @updateModalOrigin()
+        when "update-origin" then @updateOrigin()
+        else @slotUpdate responseData, mode
+
+  showErrorResponse: (status, result) ->
+    if status == 403 #permission denied
+      $(result).showAsModal $(this)
+    else if status == 900
+      $(result).showAsModal $(this)
+    else
+      @notify result, "error"
+
+      if status == 409 #edit conflict
+        @slot().find('.current_revision_id').val(
+          @slot().find('.new-current-revision-id').text()
+        )
+
+  updateModalOrigin: () ->
+    if @overlaySlot()
+      overlayOrigin = @slotOrigin("overlay")
+      overlayOrigin.updateOrigin()
+    else if @closest("#modal-container")[0]
+      @updateOrigin()
+
+  updateOrigin: () ->
+    type = if @overlaySlot()
+      "overlay"
+    else if @closest("#modal-container")[0]
+      "modal"
+
+    return unless type?
+
+    origin = @slotOrigin(type)
+    if origin && origin[0]?
+      origin.slotReload()
+
+  registerAsOrigin: (type, slot) ->
+    if slot.hasClass("_modal-slot")
+      slot = slot.find(".modal-body")  # put the origin slot id on the modal-body instead
+                                        # of on the slot, so that it survives slot reloads
+    slot.attr("data-#{type}-origin-slot-id", @slot().data("slot-id"))
+
+
+  # close modal or overlay
+  closeOnSuccess: (type) ->
+    slotter = @closest('.slotter')
+    if !type?
+      type = if @isInOverlay() then "overlay" else "modal"
+    slotter.addClass "_close-#{type}"
+
+  slotterBeforeSend: (opt) ->
+    return if opt.noSlotParams
+
+    # avoiding duplication. could be better test?
+    unless (opt.url.match(/home_view/) or @data("slotter-mode") == "modal")
+      opt.url = decko.slot.path opt.url, @slot()